fix(ssa_gen): Generate code for index before the collection

[aakoshh]

Description

Problem*

Resolves #9329

Summary*

Swaps the order in codegen_index to generate the index first and then the collection, so that if the collection is mutable and the index modifies it, the loading of the reference happens after the index is calculated.

Additional Context

This is what the initial SSA looked like originally:

acir(inline) fn main f0 {
  b0(v0: [i8; 2]):
    v2 = allocate -> &mut [i8; 2]
    store v0 at v2
    v3 = load v2 -> [i8; 2]
    jmp b1(u32 0)
  b1(v1: u32):
    ...          
    jmpif v6 then: b2, else: b3
  b2():
    ...                          	
    v13 = load v2 -> [i8; 2]                      	
    v14 = array_set v13, index u32 0, value v12   	
    store v14 at v2                               	
    ...
    jmp b1(v15)
  b3():
    v7 = array_get v3, index u32 0 -> i8          	
    return v7
}

Notice how we allocate a reference v2 to store the input array v0, which is immediately loaded into v3. Then we go into the loop where we load v2, modify it as v14 and store the new value. However in the final block b3, we get the return value v7 from the array v3 which we loaded in b0.

The reason it worked in Brillig was that Brillig modified the array in place, so even though we used v3, it reflected the effects of array_set v13. In ACIR we modified a copy instead, and then never loaded it again from the reference.

After the change in the PR, the new SSA moves the load into b3:

After Initial SSA:
acir(inline) fn main f0 {
  b0(v0: [i8; 2]):
    v2 = allocate -> &mut [i8; 2]
    store v0 at v2
    jmp b1(u32 0)
  b1(v1: u32):
    v5 = lt v1, u32 2                             	
    jmpif v5 then: b2, else: b3
  b2():
    v8 = load v2 -> [i8; 2]                       	
    v10 = array_get v8, index u32 1 -> i8         	
    v12 = add v10, i8 1                           	
    v13 = load v2 -> [i8; 2]                      	
    v14 = array_set v13, index u32 0, value v12   	
    store v14 at v2                               	
    v15 = unchecked_add v1, u32 1                 	
    jmp b1(v15)
  b3():
    v6 = load v2 -> [i8; 2]                       	
    v7 = array_get v6, index u32 0 -> i8          	
    return v7
}

Documentation*

Check one:

• No documentation needed.
• Documentation included in this PR.
• [For Experimental Features] Documentation to be submitted in a separate PR.

PR Checklist*

• I have tested the changes locally.
• I have formatted the changes with Prettier and/or cargo fmt on default settings.

[github-actions]

⚠️ Performance Alert ⚠️

Possible performance regression was detected for benchmark 'Test Suite Duration'.
Benchmark result of this commit is worse than the previous benchmark result exceeding threshold 1.20.

Benchmark suite	Current: 5a69cbf	Previous: 2282832	Ratio
test_report_AztecProtocol_aztec-packages_noir-projects_noir-protocol-circuits_crates_private-kernel-lib	2 s	1 s	2
test_report_zkpassport_noir-ecdsa_	3 s	1 s	3

This comment was automatically generated by workflow using github-action-benchmark.

CC: @TomAFrench

[asterite]

Nice find!

[github-actions]

⚠️ Performance Alert ⚠️

Possible performance regression was detected for benchmark 'Execution Time'.
Benchmark result of this commit is worse than the previous benchmark result exceeding threshold 1.20.

Benchmark suite	Current: 41067ab	Previous: 9b1b10f	Ratio
sha512-100-bytes	0.134 s	0.104 s	1.29

This comment was automatically generated by workflow using github-action-benchmark.

CC: @TomAFrench