T14733 Data Mapper PDO Connection

CHANGELOG-4.1.md

@@ -15,6 +15,13 @@
 - Added `Phalcon\Helper\Arr::blackList()` to exclude elements of an array by the keys obtained from the elements of a blacklist [#14801](https://github.com/phalcon/cphalcon/issues/14801) [@TimurFlush](https://github.com/TimurFlush)
 - Added `Phalcon\Debug::renderHtml()` to get a HTML representation of the exception [#14794](https://github.com/phalcon/cphalcon/issues/14794) [@TimurFlush](https://github.com/TimurFlush)
 - Added `Phalcon\Mvc\Router\Annotations->setActionPreformatCallback($callback)` to set a callback which pre-formats actions to custom pattern [#14819](https://github.com/phalcon/cphalcon/pull/14819)
+- Added new PDO wrapper for the Data Mapper implementation, with decorated instance, locator and profiler
+  - `DM\Connection`
+  - `DM\Connection\Decorated`
+  - `DM\Profiler\Profiler`
+  - `DM\Profiler\MemoryLogger`
+  - `DM\ConnectionLocator`
+This component will be used in the Data Mapper implementation but can be used as a stand alone component for PDO connections. [#14733](https://github.com/phalcon/cphalcon/issues/14733)
 
 ## Changed
 - Added service checks for the session. Now cookies will be saved in the session only when the `session` service is defined [#11770](https://github.com/phalcon/cphalcon/issues/11770), [#14649](https://github.com/phalcon/cphalcon/pull/14649)

phalcon/DM/Pdo/Connection.zep

@@ -0,0 +1,154 @@
+/**
+ * This file is part of the Phalcon Framework.
+ *
+ * (c) Phalcon Team <[email protected]>
+ *
+ * For the full copyright and license information, please view the LICENSE.txt
+ * file that was distributed with this source code.
+ *
+ * Implementation of this file has been influenced by AtlasPHP
+ *
+ * @link    https://github.com/atlasphp/Atlas.Pdo
+ * @license https://github.com/atlasphp/Atlas.Pdo/blob/1.x/LICENSE.md
+ */
+
+namespace Phalcon\DM\Pdo;
+
+use InvalidArgumentException;
+use Phalcon\DM\Pdo\Connection\AbstractConnection;
+use Phalcon\DM\Pdo\Profiler\Profiler;
+use Phalcon\DM\Pdo\Profiler\ProfilerInterface;
+
+/**
+ * Provides array quoting, profiling, a new `perform()` method, new `fetch*()`
+ * methods
+ *
+ * @property array             $arguments
+ * @property PDO               $pdo
+ * @property ProfilerInterface $profiler
+ */
+class Connection extends AbstractConnection
+{
+    /**
+     * @var array
+     */
+    protected arguments = [];
+
+    /**
+     * Constructor.
+     *
+     * This overrides the parent so that it can take connection attributes as a
+     * constructor parameter, and set them after connection.
+     *
+     * @param string            $dsn
+     * @param string            $username
+     * @param string            $password
+     * @param array             $options
+     * @param array             $queries
+     * @param ProfilerInterface $profiler
+     */
+    public function __construct(
+        string dsn,
+        string username = null,
+        string password = null,
+        array options = [],
+        array queries = [],
+        <ProfilerInterface> profiler = null
+    ) {
+        var parts;
+        array available;
+
+        let parts     = explode(":", dsn),
+            available = [
+                "mysql"  : true,
+                "pgsql"  : true,
+                "sqlite" : true,
+                "mssql"  : true
+            ];
+
+        if !isset available[parts[0]] {
+            throw new InvalidArgumentException(
+                "Driver not supported [" . parts[0] . "]"
+            );
+        }
+
+
+        // if no error mode is specified, use exceptions
+        if !isset options[\PDO::ATTR_ERRMODE] {
+            let options[\PDO::ATTR_ERRMODE] = \PDO::ERRMODE_EXCEPTION;
+        }
+
+        // Arguments store
+        let this->arguments = [
+            dsn,
+            username,
+            password,
+            options,
+            queries
+        ];
+
+        // Create a new profiler if none has been passed
+        if profiler === null {
+            let profiler = new Profiler();
+        }
+        this->setProfiler(profiler);
+    }
+
+    /**
+     * The purpose of this method is to hide sensitive data from stack traces.
+     *
+     * @return array
+     */
+    public function __debugInfo() -> array
+    {
+        return [
+            "arguments" : [
+                this->arguments[0],
+                "****",
+                "****",
+                this->arguments[3],
+                this->arguments[4]
+            ]
+        ];
+    }
+
+    /**
+     * Connects to the database.
+     */
+    public function connect() -> void
+    {
+        var dsn, options, password, query, queries, username;
+
+        if !this->pdo {
+            // connect
+            this->profiler->start(__FUNCTION__);
+
+            let dsn      = this->arguments[0],
+                username = this->arguments[1],
+                password = this->arguments[2],
+                options  = this->arguments[3],
+                queries  = this->arguments[4];
+
+            let this->pdo = new \PDO(dsn, username, password, options);
+
+            this->profiler->finish();
+
+            // connection-time queries
+            for query in queries {
+                this->exec(query);
+            }
+        }
+    }
+
+    /**
+     * Disconnects from the database.
+     */
+    public function disconnect() -> void
+    {
+        this->profiler->start(__FUNCTION__);
+
+        let this->pdo = null;
+
+        this->profiler->finish();
+    }
+}