Libervia-backend: Extract from old Libervia, add to new project structure

projects/Libervia/default.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  pkgs,
+  sources,
+}@args:
+{
+  metadata = {
+    summary = ''
+      Libervia is a multi-frontend, multi-purpose XMPP client. It doesn't just
+      focus on instant messaging, and uses the open standard to provide features
+      such as blogging/microblogging, calendar events, file sharing, end-to-end
+      encryption, etc.
+    '';
+    subgrants = [
+      "Libervia"
+    ];
+  };
+  nixos = {
+    modules.programs.libervia = {
+      links = {
+        config = {
+          text = "libervia.conf file reference";
+          url = "https://libervia.org/__b/doc/backend/configuration.html";
+        };
+        backend = {
+          text = "Documentation on how to manually start the backend";
+          url = "https://libervia.org/__b/doc/backend/installation.html#usage";
+        };
+        cli = {
+          text = "Command-line interface documentation";
+          url = "https://libervia.org/__b/doc/backend/libervia-cli/index.html";
+        };
+        kivy = {
+          text = "Kivy desktop client documentation";
+          url = "https://libervia.org/documentation/desktop-mobile";
+        };
+      };
+      module = ./module.nix;
+      examples = {
+        backend = {
+          description = "Enables manually starting Libervia's backend and the use of its CLI and TUI clients.";
+          module = ./examples/backend.nix;
+          tests.backend = import ./tests/backend.nix args;
+        };
+        desktop = {
+          description = "Enables the use of the Kivy desktop client for Libervia.";
+          module = ./examples/desktop.nix;
+          tests.desktop = import ./tests/desktop.nix args;
+        };
+      };
+    };
+  };
+}

projects/Libervia/examples/backend.nix

@@ -0,0 +1,4 @@
+{ ... }:
+{
+  programs.libervia.backend.enable = true;
+}

projects/Libervia/examples/desktop.nix

@@ -0,0 +1,4 @@
+{ ... }:
+{
+  programs.libervia.kivy.enable = true;
+}

projects/Libervia/module.nix

@@ -0,0 +1,36 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.programs.libervia;
+in
+{
+  options.programs.libervia = {
+    backend.enable = lib.mkEnableOption "Libervia backend and CLI/TUI clients";
+    kivy.enable = lib.mkEnableOption "Libervia Kivy desktop client";
+  };
+
+  config = lib.mkMerge [
+    # Backend
+    (lib.mkIf cfg.backend.enable {
+      environment.systemPackages = with pkgs; [
+        libervia-backend
+      ];
+
+      services.dbus.packages = with pkgs; [ libervia-backend ];
+    })
+
+    # Kivy client
+    (lib.mkIf cfg.kivy.enable {
+      # Also needs the backend
+      programs.libervia.backend.enable = true;
+
+      environment.systemPackages = with pkgs; [
+        libervia-desktop-kivy
+      ];
+    })
+  ];
+}

projects-old/Libervia/test.nix → projects/Libervia/tests/backend.nix

@@ -21,7 +21,9 @@ let
   };
 in
 {
-  name = "libervia";
+  name = "Libervia-backend";
+
+  passthru.xmppMessage = xmppMessage;
 
   nodes = {
     server =
@@ -94,8 +96,7 @@ in
         imports = [
           sources.modules.ngipkgs
           sources.modules.programs.libervia
-          sources.examples.Libervia.base
-          # can't test Libervia/unfree, enabling unfree derivations breaks nixosTests eval
+          sources.examples.Libervia.backend
         ];
 
         # Need an actual logged-in user to test with
@@ -166,8 +167,6 @@ in
           # Small script to register our test user in prosody
           systemPackages = [
             setup-initial-libervia-user
-            pkgs.firefox
-            pkgs.xdotool
           ];
         };
       };
@@ -243,28 +242,5 @@ in
           machine.send_chars("libervia-cli message mam | tee -a ~/frontend.log\n")
           machine.wait_for_console_text("${xmppUser}> ${xmppMessage}") # first log, us sending the message to ourself
           machine.wait_for_console_text("${xmppUser}> ${xmppMessage}") # second log, us receicing the message from ourself
-
-      next_workspace()
-
-      with subtest("libervia-desktop-kivy works"):
-          # Start it
-          spawn_terminal()
-          machine.send_chars("libervia-desktop-kivy 2>&1 | tee -a ~/desktop.log\n")
-          machine.wait_for_text("Select a profile")
-          machine.send_key("alt-f10")
-
-          # Log in as alice
-          machine.succeed("sudo -su alice xdotool mousemove 518 163 click 1")
-          machine.sleep(2)
-          machine.succeed("sudo -su alice xdotool mousemove 509 721 click 1")
-          machine.wait_for_text("chat")
-
-          # Enter chat
-          machine.succeed("sudo -su alice xdotool mousemove 493 199 click 1")
-          machine.wait_for_text("Your contacts")
-
-          # Open conversation with ourselves
-          machine.succeed("sudo -su alice xdotool mousemove 80 148 click 1")
-          machine.wait_for_text("${xmppMessage}")
     '';
 }

projects/Libervia/tests/desktop.nix

@@ -0,0 +1,68 @@
+{
+  sources,
+  lib,
+  pkgs,
+  ...
+}@args:
+
+# We need all the same setup as the libervia-backend test, so just extend that one with desktop things
+let
+  backendTest = import ./backend.nix args;
+in
+backendTest
+// {
+  name = "Libervia-desktop-kivy";
+
+  nodes.server =
+    {
+      config,
+      lib,
+      pkgs,
+      ...
+    }@args2:
+    let
+      backendTestConfig = backendTest.nodes.server args2;
+    in
+    backendTestConfig
+    // {
+      imports = backendTestConfig.imports ++ [
+        sources.examples.Libervia.desktop
+      ];
+
+      environment = backendTestConfig.environment // {
+        systemPackages =
+          backendTestConfig.environment.systemPackages
+          ++ (with pkgs; [
+            xdotool # Control the mouse
+          ]);
+      };
+    };
+
+  testScript =
+    { nodes, ... }@args3:
+    (backendTest.testScript args3)
+    + ''
+      next_workspace()
+
+      with subtest("libervia-desktop-kivy works"):
+          # Start it
+          spawn_terminal()
+          machine.send_chars("libervia-desktop-kivy 2>&1 | tee -a ~/desktop.log\n")
+          machine.wait_for_text("Select a profile")
+          machine.send_key("alt-f10")
+
+          # Log in as alice
+          machine.succeed("sudo -su alice xdotool mousemove 518 163 click 1")
+          machine.sleep(2)
+          machine.succeed("sudo -su alice xdotool mousemove 509 721 click 1")
+          machine.wait_for_text("chat")
+
+          # Enter chat
+          machine.succeed("sudo -su alice xdotool mousemove 493 199 click 1")
+          machine.wait_for_text("Your contacts")
+
+          # Open conversation with ourselves
+          machine.succeed("sudo -su alice xdotool mousemove 80 148 click 1")
+          machine.wait_for_text("${backendTest.passthru.xmppMessage}")
+    '';
+}