K.7 Query Get Data

Get Data with Cloud Firestore

There are two ways to retrieve data stored in Cloud Firestore. Either of these methods can be used with documents, collections of documents, or the results of queries:

• Call a method to get the data.
• Set a listener to receive data-change events.

When you set a listener, Cloud Firestore sends your listener an initial snapshot of the data, and then another snapshot each time the document changes.

To get started, write some data about cities so we can look at different ways to read it back:

var cities:CollectionReference = Firestore.collection("cities");

var data1:Object = {};
data1.name = "San Francisco";
data1.state = "CA";
data1.country = "USA";
data1.capital = false;
data1.population = 860000;
cities.document("SF").write(data1);

var data2:Object = {};
data2.name = "Los Angeles";
data2.state = "CA";
data2.country = "USA";
data2.capital = false;
data2.population = 3900000;
cities.document("LA").write(data2);

var data3:Object = {};
data3.name = "Washington D.C.";
data3.state = null;
data3.country = "USA";
data3.capital = true;
data3.population = 680000;
cities.document("DC").write(data3);

var data4:Object = {};
data4.name = "Tokyo";
data4.state = null;
data4.country = "Japan";
data4.capital = true;
data4.population = 9000000;
cities.document("TOK").write(data4);

var data5:Object = {};
data5.name = "Beijing";
data5.state = null;
data5.country = "China";
data5.capital = true;
data5.population = 21500000;
cities.document("BJ").write(data5);

Get a document

The following example shows how to retrieve the contents of a single document using read():

var document:DocumentReference = Firestore.collection("cities").document("SF");
document.addEventListener(FirestoreEvents.DOCUMENT_GET_FAILURE, onReadFailure);
document.addEventListener(FirestoreEvents.DOCUMENT_GET_SUCCESS, onReadSuccess);
document.read();

function onReadFailure(e:FirestoreEvents):void
{
	trace("Read Failure: " + e.msg);
}

function onReadSuccess(e:FirestoreEvents):void
{
	if(e.documentSnapshot)
	{
		trace("DocumentSnapshot data: " + JSON.stringify(e.documentSnapshot.data));
	}
	else
	{
		trace("No such document");
	}
}

Note: If there is no document at the location referenced by docRef, the resulting document will be null.

Get multiple documents from a collection

You can also retrieve multiple documents with one request by querying documents in a collection. For example, you can use whereEqualTo() to query for all of the documents that meet a certain condition, then use read() to retrieve the results:

var query:Query = Firestore.collection("cities").whereEqualTo("capital", true);
query.addEventListener(FirestoreEvents.QUERY_GET_SUCCESS, onQueryReadSuccess);
query.addEventListener(FirestoreEvents.QUERY_GET_FAILURE, onQueryReadFailure);
query.read();

function onQueryReadSuccess(e:FirestoreEvents):void
{
	var q:Query = e.target as Query;
	query.removeEventListener(FirestoreEvents.QUERY_GET_SUCCESS, onQueryReadSuccess);
	query.removeEventListener(FirestoreEvents.QUERY_GET_FAILURE, onQueryReadFailure);
	
	for(var i:int=0; i < e.querySnapshot.documents.length; i++)
	{
		var snapshot:DocumentSnapshot = e.querySnapshot.documents[i];
		trace(JSON.stringify(snapshot.data));
	}
}

function onQueryReadFailure(e:FirestoreEvents):void
{
	var q:Query = e.target as Query;
	query.removeEventListener(FirestoreEvents.QUERY_GET_SUCCESS, onQueryReadSuccess);
	query.removeEventListener(FirestoreEvents.QUERY_GET_FAILURE, onQueryReadFailure);
	
	trace("Error getting documents: " + e.msg);
}

you can retrieve all documents in a collection by omitting the whereEqualTo() filter entirely

var collection:CollectionReference = Firestore.collection("cities");