fetchFromGitProvider: init (optional dynamically switchable after <pkg>.overrideAttrs)

lib/customisation.nix

@@ -156,8 +156,25 @@ rec {
     let
       # Creates a functor with the same arguments as f
       mirrorArgs = mirrorFunctionArgs f;
+      # Recover overrider and additional attributes for f
+      # When f is a callable attribute set,
+      # it may contain its own `f.override` and additional attributes.
+      # This helper function recovers those attributes and decorate the overrider.
+      recoverMetadata =
+        if isAttrs f then
+          fDecorated:
+          # Preserve additional attributes for f
+          f
+          // fDecorated
+          # Decorate f.override if presented
+          // lib.optionalAttrs (f ? override) {
+            override = fdrv: makeOverridable (f.override fdrv);
+          }
+        else
+          id;
+      decorate = f': recoverMetadata (mirrorArgs f');
     in
-    mirrorArgs (
+    decorate (
       origArgs:
       let
         result = f origArgs;

lib/fetchers.nix

@@ -117,24 +117,31 @@ rec {
           # All hashes passed in arguments (possibly 0 or >1) as a list of {name, value} pairs
           let
             hashesAsNVPairs = attrsToList (intersectAttrs hashSet args);
+            unspecifiedHash = hashesAsNVPairs == [ ];
+            multipleHash = tail hashesAsNVPairs != [ ];
           in
-          if hashesAsNVPairs == [ ] then
-            throwIf required "fetcher called without `hash`" null
-          else if tail hashesAsNVPairs != [ ] then
-            throw "fetcher called with mutually-incompatible arguments: ${
-              concatMapStringsSep ", " (a: a.name) hashesAsNVPairs
-            }"
-          else
-            head hashesAsNVPairs;
+          {
+            errorMessage =
+              if unspecifiedHash && required then
+                "fetcher called without `hash`"
+              else if multipleHash then
+                "fetcher called with mutually-incompatible arguments: ${
+                  concatMapStringsSep ", " (a: a.name) hashesAsNVPairs
+                }"
+              else
+                null;
+            inherit (head hashesAsNVPairs) name value;
+            inherit unspecifiedHash;
+          };
       in
       removeAttrs args hashNames
-      // (optionalAttrs (h != null) {
-        outputHashAlgo = if h.name == "hash" then null else h.name;
-        outputHash =
-          if h.value == "" then
-            fakeH.${h.name} or (throw "no “fake hash” defined for ${h.name}")
-          else
-            h.value;
+      // (optionalAttrs (required || !h.unspecifiedHash) {
+        outputHashAlgo = lib.throwIf (h.errorMessage != null) h.errorMessage (
+          if h.name == "hash" then null else h.name
+        );
+        outputHash = lib.throwIf (h.errorMessage != null) h.errorMessage (
+          if h.value == "" then fakeH.${h.name} or (throw "no “fake hash” defined for ${h.name}") else h.value
+        );
       });
 
   /**

lib/tests/misc.nix

@@ -202,6 +202,85 @@ runTests {
     };
   };
 
+  testOverridePreserveFunctionMetadata =
+    let
+      toCallableAttrs = f: setFunctionArgs f (functionArgs f);
+      constructDefinition =
+        {
+          a ? 3,
+        }:
+        toCallableAttrs (
+          {
+            b ? 5,
+          }:
+          {
+            inherit a b;
+          }
+        )
+        // {
+          inherit a;
+          c = 7;
+        };
+      construct0 = makeOverridable constructDefinition { };
+      construct1 = makeOverridable construct0;
+      construct0p = construct0.override { a = 11; };
+      construct1p = construct1.override { a = 11; };
+    in
+    {
+      expr = {
+        construct-metadata = {
+          inherit (construct1) a c;
+        };
+        construct-overridden-metadata = {
+          v = construct0p.a;
+          inherit (construct1p) a c;
+        };
+        construct-overridden-result-overrider = {
+          result-overriders-exist = mapAttrs (_: f: (f { }) ? override) {
+            inherit construct1 construct1p;
+          };
+          result-overrider-functionality = {
+            overridden = {
+              inherit ((construct1p { }).override { b = 13; }) a b;
+            };
+            direct = {
+              inherit (construct1p { b = 13; }) a b;
+            };
+            v = {
+              inherit (construct0p { b = 13; }) a b;
+            };
+          };
+        };
+      };
+      expected = {
+        construct-metadata = {
+          inherit (construct0) a c;
+        };
+        construct-overridden-metadata = {
+          v = 11;
+          inherit (construct0p) a c;
+        };
+        construct-overridden-result-overrider = {
+          result-overriders-exist = {
+            construct1 = true;
+            construct1p = true;
+          };
+          result-overrider-functionality = {
+            overridden = {
+              inherit (construct0p { b = 13; }) a b;
+            };
+            direct = {
+              inherit (construct0p { b = 13; }) a b;
+            };
+            v = {
+              a = 11;
+              b = 13;
+            };
+          };
+        };
+      };
+    };
+
   testCallPackageWithOverridePreservesArguments =
     let
       f =

pkgs/build-support/fetchgit/builder.sh

@@ -19,7 +19,7 @@ $SHELL $fetcher --builder --url "$url" --out "$out" --rev "$rev" --name "$name"
   ${deepClone:+--deepClone} \
   ${fetchSubmodules:+--fetch-submodules} \
   ${fetchTags:+--fetch-tags} \
-  ${sparseCheckout:+--sparse-checkout "$sparseCheckout"} \
+  ${sparseCheckoutText:+--sparse-checkout "$sparseCheckoutText"} \
   ${nonConeMode:+--non-cone-mode} \
   ${branchName:+--branch-name "$branchName"} \
   ${rootDir:+--root-dir "$rootDir"}