[Backport release-24.11] libxmp: 4.6.0 -> 4.6.3; cleanup

maintainers/maintainer-list.nix

@@ -13593,6 +13593,13 @@
     githubId = 34819524;
     name = "Marcel";
   };
+  marcin-serwin = {
+    name = "Marcin Serwin";
+    github = "marcin-serwin";
+    githubId = 12128106;
+    email = "marcin@serwin.dev";
+    keys = [ { fingerprint = "F311 FA15 1A66 1875 0C4D  A88D 82F5 C70C DC49 FD1D"; } ];
+  };
   marcovergueira = {
     email = "vergueira.marco@gmail.com";
     github = "marcovergueira";

pkgs/by-name/li/libxmp/package.nix

@@ -1,27 +1,62 @@
 {
   lib,
   stdenv,
-  fetchurl,
+  docutils,
+  fetchFromGitHub,
+  cmake,
+  ninja,
+  nix-update-script,
 }:
 
-stdenv.mkDerivation rec {
+stdenv.mkDerivation (finalAttrs: {
   pname = "libxmp";
-  version = "4.6.0";
+  version = "4.6.3";
 
-  meta = with lib; {
+  src = fetchFromGitHub {
+    owner = "libxmp";
+    repo = "libxmp";
+    tag = "libxmp-${finalAttrs.version}";
+    hash = "sha256-VTjS5bVu+jiswP4GCTxcAdhtVdtopy4A3hxlzIQlZVU=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+    "man"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+    docutils
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_SHARED" (!stdenv.hostPlatform.isStatic))
+    (lib.cmakeBool "BUILD_STATIC" stdenv.hostPlatform.isStatic)
+    (lib.cmakeBool "WITH_UNIT_TESTS" finalAttrs.doCheck)
+  ];
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--version-regex"
+      "libxmp-(.*)"
+    ];
+  };
+
+  meta = {
     description = "Extended module player library";
     homepage = "https://xmp.sourceforge.net/";
+    changelog = "https://github.com/libxmp/libxmp/releases/tag/${finalAttrs.src.tag}";
     longDescription = ''
       Libxmp is a library that renders module files to PCM data. It supports
       over 90 mainstream and obscure module formats including Protracker (MOD),
       Scream Tracker 3 (S3M), Fast Tracker II (XM), and Impulse Tracker (IT).
     '';
-    license = licenses.lgpl21Plus;
-    platforms = platforms.all;
-  };
-
-  src = fetchurl {
-    url = "mirror://sourceforge/xmp/libxmp/${pname}-${version}.tar.gz";
-    sha256 = "sha256-LTxF/lI7UJB+ieYPmjt/TMmquD7J27p3Q+r/vNyzXqY=";
+    maintainers = with lib.maintainers; [ marcin-serwin ];
+    license = lib.licenses.mit;
+    platforms = lib.platforms.all;
   };
-}
+})