Unify XP Pen tablet drivers

pkgs/os-specific/linux/xp-pen-drivers/default.nix

@@ -0,0 +1,77 @@
+{ lib, stdenv, fetchzip, libusb1, glibc, libGL, xorg, makeWrapper
+, makeDesktopItem, qtx11extras, wrapQtAppsHook, autoPatchelfHook
+, libX11, libXtst, libXi, libXrandr, libXinerama, copyDesktopItems }:
+
+let
+  pname = "xp-pentablet-unwrapped";
+  version = "3.4.9-231023";
+in stdenv.mkDerivation rec {
+  inherit pname version;
+  src = fetchzip {
+    url =
+      "https://download01.xp-pen.com/file/2023/11/XPPenLinux${version}.tar.gz";
+    name = "XPPenLinux${version}.tar.gz";
+    sha256 = "sha256-A/dv6DpelH0NHjlGj32tKv37S+9q3F8cYByiYlMuqLg=";
+  };
+
+  nativeBuildInputs =
+    [ wrapQtAppsHook autoPatchelfHook makeWrapper copyDesktopItems ];
+
+  dontBuild = true;
+  dontWrapQtApps = true; # this is done manually
+
+  buildInputs = [
+    libusb1
+    libX11
+    libXtst
+    libXi
+    libXrandr
+    libXinerama
+    glibc
+    libGL
+    stdenv.cc.cc.lib
+    qtx11extras
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/usr/lib
+    cp -r App/usr/lib/pentablet $out/usr/lib
+    chmod +x $out/usr/lib/pentablet/PenTablet*
+
+    mkdir -p $out/share/icons
+    cp -r App/usr/share/icons/* $out/share/icons
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    makeWrapper $out/usr/lib/pentablet/PenTablet $out/bin/xp-pentablet \
+       "''${qtWrapperArgs[@]}" \
+       --set QT_QPA_PLATFORM xcb \
+       --set QT_XKB_CONFIG_ROOT "${xorg.xkeyboardconfig}/share/X11/xkb"
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "xppentablet";
+      desktopName = "XP Pen Tablet Drivers";
+      genericName = "Graphic Tablet Drivers";
+      exec = "xp-pentablet";
+      icon = "xppentablet";
+      comment = "XPPen graphical tablet drivers";
+      categories = [ "Utility" "Graphics" ];
+    })
+  ];
+
+  meta = with lib; {
+    mainProgram = "xp-pentablet";
+    homepage = "https://www.xp-pen.com/";
+    description = "Drivers for the XP-PEN drawing tablets";
+    platforms = [ "x86_64-linux" ];
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+    maintainers = with maintainers; [ virchau13 ivar sochotnicky ];
+    license = licenses.unfree;
+  };
+}

pkgs/os-specific/linux/xp-pen-drivers/fhsenv.nix

@@ -0,0 +1,23 @@
+{ config, lib, pkgs, xp-pentablet-unwrapped, buildFHSEnv }:
+
+buildFHSEnv {
+  name = "xp-pentablet";
+
+  extraInstallCommands = ''
+    mkdir -p "$out/share"
+    ln -s ${xp-pentablet-unwrapped}/share/applications "$out/share"
+    ln -s ${xp-pentablet-unwrapped}/share/icons "$out/share"
+  '';
+
+  runScript = "${xp-pentablet-unwrapped}/bin/xp-pentablet";
+
+  # We have to add /usr/lib/pentablet but we can't mount into /usr because it's RO-mounted by default
+  extraBwrapArgs = [ "--bind ${xp-pentablet-unwrapped}/usr /usr" ];
+
+  #  runScript = "/usr/lib/pentablet/PenTablet";
+  targetPkgs = pkgs: [
+    xp-pentablet-unwrapped
+  ];
+
+  meta = xp-pentablet-unwrapped.meta;
+}

pkgs/top-level/all-packages.nix

@@ -41830,9 +41830,12 @@ with pkgs;
 
   bcompare = libsForQt5.callPackage ../applications/version-management/bcompare { };
 
-  xp-pen-deco-01-v2-driver = libsForQt5.xp-pen-deco-01-v2-driver;
+  xp-pentablet-unwrapped = libsForQt5.xp-pentablet-unwrapped;
+  xp-pentablet = libsForQt5.xp-pentablet;
 
-  xp-pen-g430-driver = libsForQt5.xp-pen-g430-driver;
+  xp-pen-deco-01-v2-driver = xp-pentablet;
+
+  xp-pen-g430-driver = xp-pentablet;
 
   new-session-manager = callPackage ../applications/audio/new-session-manager { };
 

pkgs/top-level/qt5-packages.nix

@@ -266,9 +266,12 @@ in (noExtraAttrs (kdeFrameworks // plasmaMobileGear // plasma5 // plasma5.thirdP
 
   soundkonverter = callPackage ../applications/audio/soundkonverter {};
 
-  xp-pen-deco-01-v2-driver = callPackage ../os-specific/linux/xp-pen-drivers/deco-01-v2 { };
+  xp-pentablet-unwrapped = callPackage ../os-specific/linux/xp-pen-drivers { };
+  xp-pentablet = callPackage ../os-specific/linux/xp-pen-drivers/fhsenv.nix {};
 
-  xp-pen-g430-driver = callPackage ../os-specific/linux/xp-pen-drivers/g430 { };
+  # See https://github.com/NixOS/nixpkgs/issues/213263
+  xp-pen-deco-01-v2-driver = pkgs.xp-pentablet;
+  xp-pen-g430-driver = pkgs.xp-pentablet;
 
   yuview = callPackage ../applications/video/yuview { };
 }) // lib.optionalAttrs pkgs.config.allowAliases {