[Windows] Add wxWidgets custom port with fixed release build

3rdParty/vcpkg_ports/ports/wxwidgets/example/CMakeLists.txt

@@ -0,0 +1,26 @@
+cmake_minimum_required(VERSION 3.7)
+
+project(wxwidgets-example)
+
+add_executable(main WIN32 popup.cpp)
+
+find_package(wxWidgets REQUIRED)
+target_compile_definitions(main PRIVATE ${wxWidgets_DEFINITIONS} "$<$<CONFIG:DEBUG>:${wxWidgets_DEFINITIONS_DEBUG}>")
+target_include_directories(main PRIVATE ${wxWidgets_INCLUDE_DIRS})
+target_link_libraries(main PRIVATE ${wxWidgets_LIBRARIES})
+
+option(USE_WXRC "Use the wxrc resource compiler" ON)
+if(USE_WXRC)
+    execute_process(
+        COMMAND "${wxWidgets_wxrc_EXECUTABLE}" --help
+        RESULTS_VARIABLE error_result
+    )
+    if(error_result)
+        message(FATAL_ERROR "Failed to run wxWidgets_wxrc_EXECUTABLE (${wxWidgets_wxrc_EXECUTABLE})")
+    endif()
+endif()
+
+set(PRINT_VARS "" CACHE STRING "Variables to print at the end of configuration")
+foreach(var IN LISTS PRINT_VARS)
+    message(STATUS "${var}:=${${var}}")
+endforeach()

3rdParty/vcpkg_ports/ports/wxwidgets/fix-libs-export.patch

@@ -0,0 +1,21 @@
+diff --git a/build/cmake/config.cmake b/build/cmake/config.cmake
+index 52ae69d3f6..f261d5d262 100644
+--- a/build/cmake/config.cmake
++++ b/build/cmake/config.cmake
+@@ -39,8 +39,14 @@ macro(wx_get_dependencies var lib)
+             else()
+                 # For the value like $<$<CONFIG:DEBUG>:LIB_PATH>
+                 # Or $<$<NOT:$<CONFIG:DEBUG>>:LIB_PATH>
+-                string(REGEX REPLACE "^.+>:(.+)>$" "\\1" dep_name ${dep})
+-                if (NOT dep_name)
++                if(dep MATCHES "^(.+>):(.+)>$")
++                    if(CMAKE_BUILD_TYPE STREQUAL "Debug" AND CMAKE_MATCH_1 STREQUAL [[$<$<NOT:$<CONFIG:DEBUG>>]])
++                        continue()
++                    elseif(CMAKE_BUILD_TYPE STREQUAL "Release" AND CMAKE_MATCH_1 STREQUAL [[$<$<CONFIG:DEBUG>]])
++                        continue()
++                    endif()
++                    set(dep_name "${CMAKE_MATCH_2}")
++                else()
+                     set(dep_name ${dep})
+                 endif()
+             endif()

3rdParty/vcpkg_ports/ports/wxwidgets/fix-pcre2.patch

@@ -0,0 +1,23 @@
+diff --git a/build/cmake/modules/FindPCRE2.cmake b/build/cmake/modules/FindPCRE2.cmake
+index a27693a..455675a 100644
+--- a/build/cmake/modules/FindPCRE2.cmake
++++ b/build/cmake/modules/FindPCRE2.cmake
+@@ -24,7 +24,10 @@ set(PCRE2_CODE_UNIT_WIDTH_USED "${PCRE2_CODE_UNIT_WIDTH}" CACHE INTERNAL "")
+
+ find_package(PkgConfig QUIET)
+ pkg_check_modules(PC_PCRE2 QUIET libpcre2-${PCRE2_CODE_UNIT_WIDTH})
++set(PCRE2_LIBRARIES ${PC_PCRE2_LINK_LIBRARIES})
++set(PCRE2_INCLUDE_DIRS ${PC_PCRE2_INCLUDE_DIRS})
+
++if (0)
+ find_path(PCRE2_INCLUDE_DIRS
+     NAMES pcre2.h
+     HINTS ${PC_PCRE2_INCLUDEDIR}
+@@ -36,6 +39,7 @@ find_library(PCRE2_LIBRARIES
+     HINTS ${PC_PCRE2_LIBDIR}
+           ${PC_PCRE2_LIBRARY_DIRS}
+ )
++endif()
+
+ include(FindPackageHandleStandardArgs)
+ FIND_PACKAGE_HANDLE_STANDARD_ARGS(PCRE2 REQUIRED_VARS PCRE2_LIBRARIES PCRE2_INCLUDE_DIRS VERSION_VAR PC_PCRE2_VERSION)

3rdParty/vcpkg_ports/ports/wxwidgets/install-layout.patch

@@ -0,0 +1,51 @@
+diff --git a/build/cmake/functions.cmake b/build/cmake/functions.cmake
+index b5175236e2..8c9275974f 100644
+--- a/build/cmake/init.cmake
++++ b/build/cmake/init.cmake
+@@ -146,7 +146,7 @@ if(WIN32)
+     endif()
+ endif()
+
+-if(WIN32_MSVC_NAMING)
++if(WIN32_MSVC_NAMING AND NOT wxBUILD_DISABLE_PLATFORM_LIB_DIR)
+     if(wxBUILD_SHARED)
+         set(lib_suffix "_dll")
+     else()
+index 9e6aafa900..defd196d2e 100644
+--- a/build/cmake/functions.cmake
++++ b/build/cmake/functions.cmake
+@@ -417,7 +417,7 @@ macro(wx_add_library name)
+
+         # Setup install
+         set(runtime_dir "lib")
+-        if(WIN32 AND NOT WIN32_MSVC_NAMING)
++        if(VCPKG_TOOLCHAIN OR (WIN32 AND NOT WIN32_MSVC_NAMING))
+             # configure puts the .dll in the bin directory
+             set(runtime_dir "bin")
+         endif()
+diff --git a/build/cmake/install.cmake b/build/cmake/install.cmake
+index 7902646ef4..04ccd1aba7 100644
+--- a/build/cmake/install.cmake
++++ b/build/cmake/install.cmake
+@@ -48,7 +48,7 @@ else()
+
+     install(DIRECTORY DESTINATION "bin")
+     install(CODE "execute_process( \
+-        COMMAND ${CMAKE_COMMAND} -E create_symlink \
++        COMMAND ${CMAKE_COMMAND} -E copy \
+         ${CMAKE_INSTALL_PREFIX}/lib/wx/config/${wxBUILD_FILE_ID} \
+         ${CMAKE_INSTALL_PREFIX}/bin/wx-config \
+         )"
+diff --git a/build/cmake/utils/CMakeLists.txt b/build/cmake/utils/CMakeLists.txt
+index 2b3a22834d..e0e964db9d 100644
+--- a/build/cmake/utils/CMakeLists.txt
++++ b/build/cmake/utils/CMakeLists.txt
+@@ -41,7 +41,7 @@ if(wxUSE_XRC)
+         endif()
+
+         install(CODE "execute_process( \
+-            COMMAND ${CMAKE_COMMAND} -E create_symlink \
++            COMMAND ${CMAKE_COMMAND} -E copy \
+             ${CMAKE_INSTALL_PREFIX}/bin/${wxrc_output_name}${EXE_SUFFIX} \
+             ${CMAKE_INSTALL_PREFIX}/bin/wxrc${EXE_SUFFIX} \
+             )"

3rdParty/vcpkg_ports/ports/wxwidgets/mingw-output-name.patch

@@ -0,0 +1,21 @@
+diff --git a/build/cmake/functions.cmake b/build/cmake/functions.cmake
+index 902b7c5..ad8d1c4 100644
+--- a/build/cmake/functions.cmake
++++ b/build/cmake/functions.cmake
+@@ -184,7 +184,6 @@ function(wx_set_target_properties target_name is_base)
+             set_target_properties(${target_name}
+                 PROPERTIES
+                     OUTPUT_NAME "wx_${lib_toolkit}${lib_unicode}${lib_flavour}${lib_suffix}-${lib_version}"
+-                    OUTPUT_NAME_DEBUG "wx_${lib_toolkit}${lib_unicode}d${lib_flavour}${lib_suffix}-${lib_version}"
+                     PREFIX "lib"
+                 )
+         endif()
+@@ -486,7 +485,7 @@ function(wx_set_builtin_target_properties target_name)
+         PROPERTIES
+             OUTPUT_NAME ${target_name}${lib_unicode}${postfix}
+         )
+-    if(WIN32)
++    if(WIN32 AND NOT MINGW)
+         set_target_properties(${target_name}
+             PROPERTIES
+                 OUTPUT_NAME_DEBUG ${target_name}${lib_unicode}d

3rdParty/vcpkg_ports/ports/wxwidgets/nanosvg-ext-depend.patch

@@ -0,0 +1,35 @@
+diff --git a/build/cmake/init.cmake b/build/cmake/init.cmake
+index 8c9275974f..3758261299 100644
+--- a/build/cmake/init.cmake
++++ b/build/cmake/init.cmake
+@@ -615,3 +615,6 @@ if(wxBUILD_PRECOMP)
+         wx_option_force_value(wxBUILD_PRECOMP OFF)
+     endif()
+ endif(wxBUILD_PRECOMP)
++
++find_package(unofficial-nanosvg CONFIG REQUIRED)
++list(APPEND wxTOOLKIT_LIBRARIES unofficial::nanosvg::nanosvg)
+diff --git a/src/generic/bmpsvg.cpp b/src/generic/bmpsvg.cpp
+index 76f20dce4c..7a7c24b4dd 100644
+--- a/src/generic/bmpsvg.cpp
++++ b/src/generic/bmpsvg.cpp
+@@ -26,7 +26,7 @@
+ // your source tree doesn't contain 3rdparty/nanosvg and you should initialize
+ // and update the corresponding submodule.
+ #ifdef __has_include
+-    #if ! __has_include("../../3rdparty/nanosvg/src/nanosvg.h")
++    #if 0
+         #error You need to run "git submodule update --init 3rdparty/nanosvg".
+         #undef wxHAS_SVG
+     #endif
+@@ -60,8 +60,8 @@
+ #define NANOSVG_IMPLEMENTATION
+ #define NANOSVGRAST_IMPLEMENTATION
+ #define NANOSVG_ALL_COLOR_KEYWORDS
+-#include "../../3rdparty/nanosvg/src/nanosvg.h"
+-#include "../../3rdparty/nanosvg/src/nanosvgrast.h"
++#include <nanosvg.h>
++#include <nanosvgrast.h>
+
+ #ifdef __VISUALC__
+     #pragma warning(pop)

3rdParty/vcpkg_ports/ports/wxwidgets/portfile.cmake

@@ -0,0 +1,192 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO wxWidgets/wxWidgets
+    REF 35a6d7b15fedfdb5198bb6c28b31cda33b2c2a76 #v3.1.6-final
+    SHA512 f42b97a695e037130da9935e3abf117c0720325f194fcdabace95fa16a5ca06d49e35db9616bb0ef16600044397739459551a6276f3c239bd4fc160ecb6cdc16
+    HEAD_REF master
+    PATCHES
+        install-layout.patch
+        relocatable-wx-config.patch
+        nanosvg-ext-depend.patch
+        fix-libs-export.patch
+        fix-pcre2.patch
+)
+
+if(VCPKG_TARGET_IS_LINUX)
+    message(WARNING [[
+Port wxwidgets currently requires the following packages from the system package manager:
+    pkg-config
+    GTK 3
+    libsecret
+    libgcrypt
+    libsystemd
+These development packages can be installed on Ubuntu systems via
+    sudo apt-get install pkg-config libgtk-3-dev libsecret-1-dev libgcrypt20-dev libsystemd-dev
+]])
+    foreach(conflicting_port IN ITEMS freetype glib)
+        if(EXISTS "${CURRENT_INSTALLED_DIR}/share/${conflicting_port}/copyright")
+            message(FATAL_ERROR "Port ${conflicting_port} must not be installed when building ${PORT}:${TARGET_TRIPLET}.")
+        endif()
+    endforeach()
+endif()
+
+vcpkg_check_features(
+    OUT_FEATURE_OPTIONS FEATURE_OPTIONS
+    FEATURES
+        sound   wxUSE_SOUND
+)
+
+vcpkg_find_acquire_program(PKGCONFIG)
+
+set(OPTIONS "")
+if(VCPKG_TARGET_IS_OSX)
+    list(APPEND OPTIONS -DCOTIRE_MINIMUM_NUMBER_OF_TARGET_SOURCES=9999)
+endif()
+
+if(VCPKG_TARGET_IS_WINDOWS AND (VCPKG_TARGET_ARCHITECTURE STREQUAL "arm64" OR VCPKG_TARGET_ARCHITECTURE STREQUAL "arm"))
+    list(APPEND OPTIONS
+        -DwxUSE_OPENGL=OFF
+        -DwxUSE_STACKWALKER=OFF
+    )
+endif()
+
+if(VCPKG_TARGET_IS_WINDOWS OR VCPKG_TARGET_IS_OSX)
+    list(APPEND OPTIONS -DwxUSE_WEBREQUEST_CURL=OFF)
+else()
+    list(APPEND OPTIONS -DwxUSE_WEBREQUEST_CURL=ON)
+endif()
+
+# wxWidgets on Linux currently needs to find the system's `gtk+-3.0.pc`.
+# vcpkg's port pkgconf would prevent this lookup.
+if(VCPKG_TARGET_IS_LINUX AND NOT VCPKG_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG})
+    find_program(system_pkg_config NAMES pkg-config)
+    if(system_pkg_config)
+        set(ENV{PKG_CONFIG} "${system_pkg_config}")
+    endif()
+    if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
+        list(APPEND OPTIONS -DPKG_CONFIG_ARGN=--static)
+    endif()
+endif()
+
+# This may be set to ON by users in a custom triplet.
+# The use of 'wxUSE_STL' and 'WXWIDGETS_USE_STD_CONTAINERS' (ON or OFF) are not API compatible
+# which is why they must be set in a custom triplet rather than a port feature.
+if(NOT DEFINED WXWIDGETS_USE_STL)
+    set(WXWIDGETS_USE_STL OFF)
+endif()
+
+if(NOT DEFINED WXWIDGETS_USE_STD_CONTAINERS)
+    set(WXWIDGETS_USE_STD_CONTAINERS OFF)
+endif()
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        ${FEATURE_OPTIONS}
+        -DwxUSE_REGEX=sys
+        -DwxUSE_ZLIB=sys
+        -DwxUSE_EXPAT=sys
+        -DwxUSE_LIBJPEG=sys
+        -DwxUSE_LIBPNG=sys
+        -DwxUSE_LIBTIFF=sys
+        -DwxUSE_SECRETSTORE=FALSE
+        -DwxBUILD_DISABLE_PLATFORM_LIB_DIR=ON
+        -DwxUSE_STL=${WXWIDGETS_USE_STL}
+        -DwxUSE_STD_CONTAINERS=${WXWIDGETS_USE_STD_CONTAINERS}
+        ${OPTIONS}
+        "-DPKG_CONFIG_EXECUTABLE=${PKGCONFIG}"
+        # The minimum cmake version requirement for Cotire is 2.8.12.
+        # however, we need to declare that the minimum cmake version requirement is at least 3.1 to use CMAKE_PREFIX_PATH as the path to find .pc.
+        -DPKG_CONFIG_USE_CMAKE_PREFIX_PATH=ON
+    OPTIONS_RELEASE
+        -DwxBUILD_DEBUG_LEVEL=0
+)
+
+vcpkg_cmake_install()
+
+set(tools wxrc)
+if(VCPKG_TARGET_IS_MINGW OR NOT VCPKG_TARGET_IS_WINDOWS)
+    list(APPEND tools wxrc-3.1)
+    file(MAKE_DIRECTORY "${CURRENT_PACKAGES_DIR}/tools/${PORT}")
+    file(RENAME "${CURRENT_PACKAGES_DIR}/bin/wx-config" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/wx-config")
+    if(NOT VCPKG_BUILD_TYPE)
+        file(MAKE_DIRECTORY "${CURRENT_PACKAGES_DIR}/tools/${PORT}/debug")
+        file(RENAME "${CURRENT_PACKAGES_DIR}/debug/bin/wx-config" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/debug/wx-config")
+    endif()
+endif()
+vcpkg_copy_tools(TOOL_NAMES ${tools} AUTO_CLEAN)
+
+# do the copy pdbs now after the dlls got moved to the expected /bin folder above
+vcpkg_copy_pdbs()
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/include/msvc")
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+file(GLOB_RECURSE INCLUDES "${CURRENT_PACKAGES_DIR}/include/*.h")
+if(EXISTS "${CURRENT_PACKAGES_DIR}/lib/mswu/wx/setup.h")
+    list(APPEND INCLUDES "${CURRENT_PACKAGES_DIR}/lib/mswu/wx/setup.h")
+endif()
+if(EXISTS "${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h")
+    list(APPEND INCLUDES "${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h")
+endif()
+foreach(INC IN LISTS INCLUDES)
+    file(READ "${INC}" _contents)
+    if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
+        string(REPLACE "defined(WXUSINGDLL)" "0" _contents "${_contents}")
+    else()
+        string(REPLACE "defined(WXUSINGDLL)" "1" _contents "${_contents}")
+    endif()
+    # Remove install prefix from setup.h to ensure package is relocatable
+    string(REGEX REPLACE "\n#define wxINSTALL_PREFIX [^\n]*" "\n#define wxINSTALL_PREFIX \"\"" _contents "${_contents}")
+    file(WRITE "${INC}" "${_contents}")
+endforeach()
+
+if(NOT EXISTS "${CURRENT_PACKAGES_DIR}/include/wx/setup.h")
+    file(GLOB_RECURSE WX_SETUP_H_FILES_DBG "${CURRENT_PACKAGES_DIR}/debug/lib/*.h")
+    file(GLOB_RECURSE WX_SETUP_H_FILES_REL "${CURRENT_PACKAGES_DIR}/lib/*.h")
+
+    if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "release")
+        vcpkg_replace_string("${WX_SETUP_H_FILES_REL}" "${CURRENT_PACKAGES_DIR}" "")
+
+        string(REPLACE "${CURRENT_PACKAGES_DIR}/lib/" "" WX_SETUP_H_FILES_REL "${WX_SETUP_H_FILES_REL}")
+        string(REPLACE "/setup.h" "" WX_SETUP_H_REL_RELATIVE "${WX_SETUP_H_FILES_REL}")
+    endif()
+    if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "debug")
+        vcpkg_replace_string("${WX_SETUP_H_FILES_DBG}" "${CURRENT_PACKAGES_DIR}" "")
+
+        string(REPLACE "${CURRENT_PACKAGES_DIR}/debug/lib/" "" WX_SETUP_H_FILES_DBG "${WX_SETUP_H_FILES_DBG}")
+        string(REPLACE "/setup.h" "" WX_SETUP_H_DBG_RELATIVE "${WX_SETUP_H_FILES_DBG}")
+    endif()
+
+    configure_file("${CMAKE_CURRENT_LIST_DIR}/setup.h.in" "${CURRENT_PACKAGES_DIR}/include/wx/setup.h" @ONLY)
+endif()
+
+file(GLOB configs LIST_DIRECTORIES false "${CURRENT_PACKAGES_DIR}/lib/wx/config/*" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/wx-config")
+foreach(config IN LISTS configs)
+    vcpkg_replace_string("${config}" "${CURRENT_INSTALLED_DIR}" [[${prefix}]])
+endforeach()
+file(GLOB configs LIST_DIRECTORIES false "${CURRENT_PACKAGES_DIR}/debug/lib/wx/config/*" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/debug/wx-config")
+foreach(config IN LISTS configs)
+    vcpkg_replace_string("${config}" "${CURRENT_INSTALLED_DIR}/debug" [[${prefix}]])
+endforeach()
+
+# For CMake multi-config in connection with wrapper
+if(EXISTS "${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h")
+    file(INSTALL "${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h"
+        DESTINATION "${CURRENT_PACKAGES_DIR}/lib/mswud/wx"
+    )
+endif()
+
+if("example" IN_LIST FEATURES)
+    file(INSTALL
+        "${CMAKE_CURRENT_LIST_DIR}/example/CMakeLists.txt"
+        "${SOURCE_PATH}/samples/popup/popup.cpp"
+        "${SOURCE_PATH}/samples/sample.xpm"
+        DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}/example"
+    )
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/share/${PORT}/example/popup.cpp" "../sample.xpm" "sample.xpm")
+endif()
+
+configure_file("${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake" "${CURRENT_PACKAGES_DIR}/share/${PORT}/vcpkg-cmake-wrapper.cmake" @ONLY)
+
+file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
+file(INSTALL "${SOURCE_PATH}/docs/licence.txt" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)