Add Unload Vehicle Cargo keybind and context menu action (#528)

Author: ampersand38

addons/context_actions/CfgContext.hpp

@@ -315,6 +315,12 @@ class EGVAR(context_menu,actions) {
             statement = QUOTE(_objects call FUNC(refuelVehicles));
             icon = "\a3\ui_f\data\igui\cfg\simpleTasks\types\refuel_ca.paa";
         };
+        class UnloadViV {
+            displayName = "$STR_A3_ModuleDepot_Unload";
+            condition = QUOTE(_objects call FUNC(canUnloadViV));
+            statement = QUOTE(_objects call FUNC(unloadViV));
+            icon = "\a3\ui_f\data\IGUI\Cfg\Actions\unloadVehicle_ca.paa";
+        };
     };
     class EditableObjects {
         displayName = CSTRING(EditableObjects);

addons/context_actions/XEH_PREP.hpp

@@ -7,6 +7,7 @@ PREP(canRearmVehicles);
 PREP(canRefuelVehicles);
 PREP(canRepairVehicles);
 PREP(canToggleSurrender);
+PREP(canUnloadViV);
 PREP(copyVehicleAppearance);
 PREP(getArtilleryActions);
 PREP(healUnits);
@@ -25,4 +26,5 @@ PREP(teleportPlayers);
 PREP(teleportZeus);
 PREP(toggleCaptive);
 PREP(toggleSurrender);
+PREP(unloadViV);
 PREP(updateEditableObjects);

addons/context_actions/functions/fnc_canUnloadViV.sqf

@@ -0,0 +1,18 @@
+#include "script_component.hpp"
+/*
+ * Author: Ampersand
+ * Checks if the given objects list contains Vehicle-in-Vehicle cargo or carriers that can be unloaded.
+ *
+ * Arguments:
+ * N: Objects <OBJECT>
+ *
+ * Return Value:
+ * Can Unload Vehicles <BOOL>
+ *
+ * Example:
+ * [_object] call zen_context_actions_fnc_canUnloadViV
+ *
+ * Public: No
+ */
+
+_this findIf {!(getVehicleCargo _x isEqualTo []) || {!isNull isVehicleCargo _x}} != -1

addons/context_actions/functions/fnc_unloadViV.sqf

@@ -0,0 +1,28 @@
+#include "script_component.hpp"
+/*
+ * Author: Ampersand
+ * Unloads Vehicle-in-Vehicle cargo and carriers from the objects list.
+ *
+ * Arguments:
+ * N: Objects <OBJECT>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [_object] call zen_context_actions_fnc_unloadViV
+ *
+ * Public: No
+ */
+
+ {
+     if (isNull isVehicleCargo _x) then {
+         // Not being carried
+         if !(getVehicleCargo _x isEqualTo []) then {
+             _x setVehicleCargo objNull;
+         };
+     } else {
+         // Being carried
+         objNull setVehicleCargo _x;
+     };
+ } forEach _this;

addons/editor/initKeybinds.sqf

@@ -27,6 +27,24 @@
     };
 }, {}, [DIK_G, [false, true, false]]] call CBA_fnc_addKeybind; // Default: CTRL + G
 
+[ELSTRING(main,DisplayName), QGVAR(unloadViV), [localize "STR_A3_ModuleDepot_Unload", LSTRING(UnloadViV_Description)], {
+    if (!isNull curatorCamera && {!GETMVAR(RscDisplayCurator_search,false)}) then {
+        {
+            if (isNull isVehicleCargo _x) then {
+                // Not being carried
+                if !(getVehicleCargo _x isEqualTo []) then {
+                    _x setVehicleCargo objNull;
+                };
+            } else {
+                // Being carried
+                objNull setVehicleCargo _x;
+            };
+        } forEach SELECTED_OBJECTS;
+
+        true // handled, prevents vanilla eject
+    };
+}, {}, [DIK_G, [false, false, true]]] call CBA_fnc_addKeybind; // Default: ALT + G
+
 [ELSTRING(main,DisplayName), QGVAR(deepCopy), [LSTRING(DeepCopy), LSTRING(DeepCopy_Description)], {
     if (!isNull curatorCamera && {!GETMVAR(RscDisplayCurator_search,false)}) then {
         private _position = [nil, false] call EFUNC(common,getPosFromScreen);

addons/editor/stringtable.xml

@@ -159,6 +159,9 @@
             <Polish>Wysadza pasażerów ze wszystkich wybranych pojazdów. Jeżeli pojazd jest w powietrzu, pasażerowie dostaną spadochron.\nJednostki zostaną wysadzone jedna po drugiej (nie wszystkie na raz).</Polish>
             <Japanese>選択された全車両から後部座席のユニットを脱出させます。もし車両が飛行中の場合はパラシュートが与えられます。\nなお脱出は一人づつ降りるようになっています (即時ではなく数秒づつ)。</Japanese>
         </Key>
+        <Key ID="STR_ZEN_Editor_UnloadViV_Description">
+            <English>Unloads all selected vehicle-in-vehicle cargo and carriers. A vehicle that is both cargo and carrying cargo will only be unloaded from its carrier.</English>
+        </Key>
         <Key ID="STR_ZEN_Editor_DeployCountermeasures">
             <English>Deploy Countermeasures</English>
             <French>Déployer des contre-mesures</French>