cmake: Add configuration for Cmake Package

CMakeLists.txt

@@ -86,6 +86,10 @@ if(FIZZY_FUZZING)
     add_link_options(${fuzzing_flags})
 endif()
 
+
+include(CMakePackageConfigHelpers)
+include(GNUInstallDirs)
+
 # Public include directory.
 set(FIZZY_INCLUDE_DIR $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
 
@@ -100,5 +104,12 @@ if(FIZZY_TESTING)
     add_subdirectory(test)
 endif()
 
+set(CMAKE_INSTALL_CMAKEPACKAGEDIR ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
+
+write_basic_package_version_file(fizzyConfigVersion.cmake COMPATIBILITY ExactVersion)
+configure_package_config_file(cmake/Config.cmake.in fizzyConfig.cmake INSTALL_DESTINATION ${CMAKE_INSTALL_CMAKEPACKAGEDIR})
+
 install(TARGETS fizzy EXPORT fizzyTargets)
 install(DIRECTORY include/fizzy TYPE INCLUDE)
+install(EXPORT fizzyTargets NAMESPACE fizzy:: DESTINATION ${CMAKE_INSTALL_CMAKEPACKAGEDIR})
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/fizzyConfig.cmake ${CMAKE_CURRENT_BINARY_DIR}/fizzyConfigVersion.cmake DESTINATION ${CMAKE_INSTALL_CMAKEPACKAGEDIR})

cmake/Config.cmake.in

@@ -0,0 +1,4 @@
+@PACKAGE_INIT@
+
+include(${CMAKE_CURRENT_LIST_DIR}/fizzyTargets.cmake)
+check_required_components(fizzy)

test/CMakeLists.txt

@@ -26,6 +26,7 @@ add_subdirectory(utils)
 add_subdirectory(bench)
 add_subdirectory(bench_internal)
 add_subdirectory(compilation)
+add_subdirectory(integration)
 add_subdirectory(smoketests)
 add_subdirectory(spectests)
 add_subdirectory(testfloat)

test/integration/CMakeLists.txt

@@ -0,0 +1,5 @@
+# Fizzy: A fast WebAssembly interpreter
+# Copyright 2020 The Fizzy Authors.
+# SPDX-License-Identifier: Apache-2.0
+
+add_subdirectory(cmake_package)

test/integration/cmake_package/CMakeLists.txt

@@ -0,0 +1,38 @@
+# Fizzy: A fast WebAssembly interpreter
+# Copyright 2020 The Fizzy Authors.
+# SPDX-License-Identifier: Apache-2.0
+
+set(INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/install)
+set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/build)
+set(USE_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/use)
+
+file(MAKE_DIRECTORY ${BUILD_DIR} ${USE_BUILD_DIR})
+
+set(PREFIX ${PROJECT_NAME}/integration/cmake_package)
+
+add_test(
+    NAME ${PREFIX}/configure
+    COMMAND ${CMAKE_COMMAND} -G ${CMAKE_GENERATOR} ${PROJECT_SOURCE_DIR} -DCMAKE_INSTALL_PREFIX=${INSTALL_DIR}
+    WORKING_DIRECTORY ${BUILD_DIR}
+)
+
+add_test(
+    NAME ${PREFIX}/install
+    COMMAND ${CMAKE_COMMAND} --build ${BUILD_DIR} --target install
+)
+set_tests_properties(${PREFIX}/install PROPERTIES DEPENDS ${PREFIX}/configure)
+
+
+add_test(
+    NAME ${PREFIX}/use/configure
+    COMMAND ${CMAKE_COMMAND} -G ${CMAKE_GENERATOR} ${CMAKE_CURRENT_SOURCE_DIR}/use_fizzy -DCMAKE_PREFIX_PATH=${INSTALL_DIR}
+    WORKING_DIRECTORY ${USE_BUILD_DIR}
+)
+set_tests_properties(${PREFIX}/use/configure PROPERTIES DEPENDS ${PREFIX}/install)
+
+add_test(
+    NAME ${PREFIX}/use/build
+    COMMAND ${CMAKE_COMMAND} --build ${USE_BUILD_DIR}
+)
+set_tests_properties(${PREFIX}/use/build PROPERTIES DEPENDS ${PREFIX}/use/configure)
+

test/integration/cmake_package/use_fizzy/CMakeLists.txt

@@ -0,0 +1,11 @@
+# Fizzy: A fast WebAssembly interpreter
+# Copyright 2020 The Fizzy Authors.
+# SPDX-License-Identifier: Apache-2.0
+
+# This example shows how to use the fizzy library from the fizzy CMake package.
+cmake_minimum_required(VERSION 3.15)
+project(use_fizzy LANGUAGES CXX)
+find_package(fizzy CONFIG REQUIRED)
+
+add_executable(use_fizzy use_fizzy.cpp)
+target_link_libraries(use_fizzy PRIVATE fizzy::fizzy)

test/integration/cmake_package/use_fizzy/use_fizzy.cpp

@@ -0,0 +1,10 @@
+// Fizzy: A fast WebAssembly interpreter
+// Copyright 2020 The Fizzy Authors.
+// SPDX-License-Identifier: Apache-2.0
+
+#include <fizzy/fizzy.h>
+
+int main()
+{
+    return fizzy_validate(nullptr, 0) ? 0 : 1;
+}