Add ability to specify library directories for target rpaths

cmake-format-rapids-cmake.json

@@ -271,6 +271,11 @@
           "LINKED_LIBRARIES": "*",
           "INSTALL_DIR": "1"
         }
+      },
+      "rapids_cython_set_lib_dirs": {
+        "pargs": {
+          "nargs": "*"
+        }
       }
 
     }

docs/api.rst

@@ -70,6 +70,7 @@ The `rapids_cython` functions allow projects to easily build cython modules usin
 
    /command/rapids_cython_init
    /command/rapids_cython_create_modules
+   /command/rapids_cython_set_lib_dirs
 
 
 Find

docs/command/rapids_cython_set_lib_dirs.rst

@@ -0,0 +1 @@
+.. cmake-module:: ../../rapids-cmake/cython/set_lib_dirs.cmake

rapids-cmake/cython/create_modules.cmake

@@ -117,8 +117,15 @@ function(rapids_cython_create_modules)
     endif()
     install(TARGETS ${cython_module} DESTINATION ${_RAPIDS_CYTHON_INSTALL_DIR})
 
-    # Default the INSTALL_RPATH for all modules to $ORIGIN.
-    set_target_properties(${cython_module} PROPERTIES INSTALL_RPATH "\$ORIGIN")
+    # Default the INSTALL_RPATH for all modules to $ORIGIN. We also append any lib dirs specified in
+    # the current project.
+    set(_rpath_dirs)
+    foreach(_lib_dir IN LISTS RAPIDS_CYTHON_${PROJECT_NAME}_LIB_DIRS)
+      cmake_path(RELATIVE_PATH _lib_dir)
+      list(APPEND _rpath_dirs "\$ORIGIN/${_lib_dir}")
+    endforeach()
+    list(JOIN _rpath_dirs ";" _rpath_dirs)
+    set_target_properties(${cython_module} PROPERTIES INSTALL_RPATH "\$ORIGIN;${_rpath_dirs}")
 
     list(APPEND CREATED_TARGETS "${cython_module}")
   endforeach()

rapids-cmake/cython/set_lib_dirs.cmake

@@ -0,0 +1,53 @@
+# =============================================================================
+# Copyright (c) 2022, NVIDIA CORPORATION.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may not use this file except
+# in compliance with the License. You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software distributed under the License
+# is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express
+# or implied. See the License for the specific language governing permissions and limitations under
+# the License.
+# =============================================================================
+
+include_guard(GLOBAL)
+
+#[=======================================================================[.rst:
+rapids_cython_set_lib_dirs
+--------------------------
+
+.. versionadded:: v22.12.00
+
+Set the directories where any dependent libraries will be placed.
+
+.. code-block:: cmake
+
+  rapids_cython_set_lib_dirs(<dir1> <dir2> ...)
+
+The relative path to the provided directories is appended to the rpath of any
+library built using rapids_cython_create_modules within the current project.
+
+.. note::
+  Requires :cmake:command:`rapids_cython_init` to be called before usage.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+  :cmake:variable:`RAPIDS_CYTHON_<ProjectName>_LIB_DIRS` will be set to the list of
+  directories provided to this function, where ProjectName is the name given to the
+  most recent :cmake:command:`project <cmake:command:project>` call.
+
+#]=======================================================================]
+function(rapids_cython_set_lib_dirs)
+  # Note that this function may be called safely before rapids-cython is initialized.
+  list(APPEND CMAKE_MESSAGE_CONTEXT "rapids.cython.set_lib_dirs")
+
+  # Need to convert all paths to absolute so that the later relative path conversions work.
+  set(_abs_lib_dirs)
+  foreach(_lib_dir IN LISTS ARGV)
+    cmake_path(ABSOLUTE_PATH _lib_dir)
+    list(APPEND _abs_lib_dirs ${_lib_dir})
+  endforeach()
+  set(RAPIDS_CYTHON_${PROJECT_NAME}_LIB_DIRS "${_abs_lib_dirs}" PARENT_SCOPE)
+endfunction()

rapids-cmake/rapids-cython.cmake

@@ -17,3 +17,4 @@ include_guard(GLOBAL)
 
 include(${CMAKE_CURRENT_LIST_DIR}/cython/init.cmake)
 include(${CMAKE_CURRENT_LIST_DIR}/cython/create_modules.cmake)
+include(${CMAKE_CURRENT_LIST_DIR}/cython/set_lib_dirs.cmake)

testing/cython/CMakeLists.txt

@@ -22,3 +22,5 @@ add_cmake_config_test(create_modules_errors.cmake SHOULD_FAIL "You must call rap
 add_cmake_config_test(create_modules)
 add_cmake_config_test(create_modules_with_library)
 add_cmake_config_test(create_modules_with_prefix)
+
+add_cmake_config_test(set_lib_dirs)

testing/cython/create_modules/CMakeLists.txt

@@ -40,5 +40,5 @@ rapids_cython_create_modules(
     )
 
 if(NOT TARGET test)
-  message(FATAL_ERROR "rapids_cython_init didn't create the target `test`")
+  message(FATAL_ERROR "rapids_cython_create_modules didn't create the target `test`")
 endif()

testing/cython/create_modules_with_prefix/CMakeLists.txt

@@ -41,5 +41,5 @@ rapids_cython_create_modules(
     )
 
 if(NOT TARGET test_test)
-  message(FATAL_ERROR "rapids_cython_init didn't create the prefixed library target `test_test`")
+  message(FATAL_ERROR "rapids_cython_create_modules didn't create the prefixed library target `test_test`")
 endif()

testing/cython/set_lib_dirs/CMakeLists.txt

@@ -0,0 +1,46 @@
+#=============================================================================
+# Copyright (c) 2022, NVIDIA CORPORATION.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#=============================================================================
+
+cmake_minimum_required(VERSION 3.20)
+
+include(${rapids-cmake-dir}/cython/create_modules.cmake)
+include(${rapids-cmake-dir}/cython/init.cmake)
+include(${rapids-cmake-dir}/cython/set_lib_dirs.cmake)
+
+project(rapids_cython-set_lib_dirs LANGUAGES C CXX)
+
+# Silence warning about running without scikit-build.
+set(SKBUILD ON)
+
+# Ensure that scikit-build's CMake files are discoverable. The glob is to
+# capture the current git commit hash.
+file(GLOB skbuild_resource_dir LIST_DIRECTORIES ON "${CPM_SOURCE_CACHE}/skbuild/*/skbuild/resources/cmake")
+LIST(APPEND CMAKE_MODULE_PATH "${skbuild_resource_dir}")
+
+# Make sure set_lib_dirs can run before rapids_cython_init.
+rapids_cython_set_lib_dirs(../libraries)
+
+rapids_cython_init()
+
+# Test that the RPATH of the resulting target is properly set.
+rapids_cython_create_modules(
+    SOURCE_FILES test.pyx
+    )
+
+get_target_property(rpath test INSTALL_RPATH)
+if (NOT rpath STREQUAL "$ORIGIN;$ORIGIN/../libraries")
+  message(FATAL_ERROR "rapids_cython_set_lib_dirs failed to set the RPATH correctly.")
+endif()