vicinae: init

flake/dev/flake.nix

@@ -179,6 +179,14 @@
       inputs.nixpkgs.follows = "dev-nixpkgs";
     };
 
+    vicinae = {
+      url = "github:vicinaehq/vicinae";
+      inputs = {
+        nixpkgs.follows = "dev-nixpkgs";
+        flake-utils.inputs.systems.follows = "dev-systems";
+      };
+    };
+
     zen-browser = {
       url = "github:0xc000022070/zen-browser-flake";
       inputs = {

modules/vicinae/hm.nix

@@ -0,0 +1,61 @@
+{
+  mkTarget,
+  lib,
+  options,
+  ...
+}:
+mkTarget {
+  name = "vicinae";
+  humanName = "Vicinae";
+
+  configElements = lib.optionals (options.programs ? vicinae) [
+    (
+      { colors, polarity }:
+      {
+        services.vicinae = {
+          settings.theme.name = "stylix";
+          themes.stylix = {
+            meta = {
+              name = "stylix";
+              description = "theme generated by stylix";
+              variant = if polarity == "either" then "light" else polarity;
+            };
+            colors = with colors.withHashtag; {
+              core = {
+                background = base00;
+                foreground = base05;
+                secondary_background = base01;
+                border = base02;
+                accent = base0D;
+              };
+              accents = {
+                # TODO: magenta and purple shouldn't be the same color
+                blue = base0D;
+                green = base0B;
+                magenta = base0E;
+                orange = base09;
+                purple = base0E;
+                red = base08;
+                yellow = base0A;
+                cyan = base0C;
+              };
+              list.item = {
+                selection = {
+                  background.name = base02;
+                  secondary_background = base03;
+                };
+                hover.background = base01;
+              };
+            };
+          };
+        };
+      }
+    )
+    (
+      { opacity }:
+      {
+        services.vicinae.settings.window.opacity = opacity.popups;
+      }
+    )
+  ];
+}

modules/vicinae/meta.nix

@@ -0,0 +1,6 @@
+{ lib, ... }:
+{
+  name = "Vicinae";
+  homepage = "https://docs.vicinae.com";
+  maintainers = [ lib.maintainers.da157 ];
+}

modules/vicinae/testbeds/vicinae.nix

@@ -0,0 +1,11 @@
+{ lib, ... }:
+{
+  stylix.testbed.ui = {
+    graphicalEnvironment = "hyprland";
+    command.text = "sleep 5 && vicinae open";
+  };
+
+  home-manager.sharedModules = lib.singleton {
+    services.vicinae.enable = true;
+  };
+}

stylix/testbed/default.nix

@@ -45,6 +45,10 @@ let
 
               nvf = inputs.nvf.nixosModules.default;
 
+              vicinae.home-manager.sharedModules = [
+                inputs.vicinae.homeManagerModules.default
+              ];
+
               zen-browser.home-manager.sharedModules = [
                 inputs.zen-browser.homeModules.default
               ];