stylix/testbeds/themes: overhaul testbed themes for broader coverage

README.md

@@ -40,7 +40,7 @@ philosophy.
 Try a live demo of this dark theme by running:
 
 ```console
-nix run github:nix-community/stylix#testbed:gnome:dark
+nix run github:nix-community/stylix#testbed:gnome:full-dark
 ```
 
 ### KDE Plasma 5

doc/src/testbeds.md

@@ -77,16 +77,16 @@ github:nix-community/stylix
     └───x86_64-linux
         ├───doc: package 'stylix-book'
         ├───palette-generator: package 'palette-generator'
-        ├───"testbed:gnome:cursorless": package 'testbed-gnome-cursorless'
-        ├───"testbed:gnome:dark": package 'testbed-gnome-dark'
-        ├───"testbed:gnome:imageless": package 'testbed-gnome-imageless'
-        ├───"testbed:gnome:light": package 'testbed-gnome-light'
-        ├───"testbed:gnome:schemeless": package 'testbed-gnome-schemeless'
-        ├───"testbed:kde:cursorless": package 'testbed-kde-cursorless'
-        ├───"testbed:kde:dark": package 'testbed-kde-dark'
-        ├───"testbed:kde:imageless": package 'testbed-kde-imageless'
-        ├───"testbed:kde:light": package 'testbed-kde-light'
-        └───"testbed:kde:schemeless": package 'testbed-kde-schemeless'
+        ├───"testbed:gnome:default": package 'testbed-gnome-default'
+        ├───"testbed:gnome:disabled": package 'testbed-gnome-disabled'
+        ├───"testbed:gnome:empty": package 'testbed-gnome-empty'
+        ├───"testbed:gnome:full-dark": package 'testbed-gnome-full-dark'
+        ├───"testbed:gnome:partial-light": package 'testbed-gnome-partial-light'
+        ├───"testbed:kde:default": package 'testbed-kde-default'
+        ├───"testbed:kde:disabled": package 'testbed-kde-disabled'
+        ├───"testbed:kde:empty": package 'testbed-kde-empty'
+        ├───"testbed:kde:full-dark": package 'testbed-kde-full-dark'
+        └───"testbed:kde:partial-light": package 'testbed-kde-partial-light'
 ```
 
 (This has been edited down to only the relevant parts.)

flake.nix

@@ -74,11 +74,6 @@
       flake = false;
     };
 
-    tinted-schemes = {
-      url = "github:tinted-theming/schemes";
-      flake = false;
-    };
-
     tinted-tmux = {
       url = "github:tinted-theming/tinted-tmux";
       flake = false;

flake/dev/flake.nix

@@ -72,7 +72,6 @@
   #                 nur.follows = "";
   #                 tinted-foot.follows = "";
   #                 tinted-kitty.follows = "";
-  #                 tinted-schemes.follows = "";
   #                 tinted-tmux.follows = "";
   #                 tinted-zed.follows = "";
   #               };

stylix/home-manager-integration.nix

@@ -208,22 +208,20 @@ in
     };
   };
 
-  config = lib.mkIf config.stylix.enable (
-    lib.optionalAttrs (options ? home-manager) (
-      lib.mkMerge [
-        (lib.mkIf config.stylix.homeManagerIntegration.autoImport {
-          home-manager.sharedModules =
-            [
-              config.stylix.homeManagerIntegration.module
-            ]
-            ++ lib.optionals config.stylix.homeManagerIntegration.followSystem copyModules;
-        })
-        (lib.mkIf config.home-manager.useGlobalPkgs {
-          home-manager.sharedModules = lib.singleton {
-            config.stylix.overlays.enable = false;
-          };
-        })
-      ]
-    )
+  config = lib.optionalAttrs (options ? home-manager) (
+    lib.mkMerge [
+      (lib.mkIf config.stylix.homeManagerIntegration.autoImport {
+        home-manager.sharedModules =
+          [
+            config.stylix.homeManagerIntegration.module
+          ]
+          ++ lib.optionals config.stylix.homeManagerIntegration.followSystem copyModules;
+      })
+      (lib.mkIf config.home-manager.useGlobalPkgs {
+        home-manager.sharedModules = lib.singleton {
+          config.stylix.overlays.enable = false;
+        };
+      })
+    ]
   );
 }

stylix/testbed/themes/default.nix

@@ -0,0 +1,8 @@
+# Test the default Stylix configuration.
+{ pkgs, ... }:
+{
+  stylix = {
+    base16Scheme = "${pkgs.base16-schemes}/share/themes/catppuccin-macchiato.yaml";
+    enable = true;
+  };
+}

stylix/testbed/themes/disabled.nix

@@ -0,0 +1,2 @@
+# Test Stylix being disabled.
+{ stylix.enable = false; }

stylix/testbed/themes/empty.nix

@@ -0,0 +1,38 @@
+# Test Stylix being enabled with all its features disabled.
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+{
+  stylix = {
+    enable = true;
+    icons.enable = false;
+    overlays.enable = false;
+
+    # TODO: Disable the color functionality by replacing the mandatory
+    # stylix.base16Scheme declaration with 'stylix.colors.enable = false;' once
+    # this option is implemented.
+    base16Scheme = "${pkgs.base16-schemes}/share/themes/mellow-purple.yaml";
+
+    # TODO: Properly disable the cursor functionality by replacing the
+    # stylix.cursor declaration with 'stylix.cursor.enable = false;' once this
+    # option is implemented.
+    cursor = null;
+
+    # TODO: Disable the font functionality with 'stylix.fonts.enable = false;'
+    # once this option is implemented.
+
+    # TODO: Properly disable the image functionality by replacing the
+    # stylix.image declaration with 'stylix.image.enable = false;' once this
+    # option is implemented. The stylix.image.enable namespace is subject to
+    # change.
+    image = null;
+
+    # TODO: Properly disable the opacity functionality by replacing the
+    # stylix.opacity declaration with 'stylix.opacity.enable = false;' once this
+    # option is implemented.
+    opacity = lib.genAttrs (builtins.attrNames config.stylix.opacity) (_: 1.0);
+  };
+}

stylix/testbed/themes/full-dark.nix

@@ -0,0 +1,113 @@
+# Test a complete Stylix configuration with a dark theme, image, and all options
+# set to non-default values.
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+{
+  stylix = {
+    enable = true;
+
+    # TODO: Declare different dark and light themes after resolving [1].
+    #
+    # [1]: https://github.com/nix-community/stylix/issues/1855
+    icons = {
+      dark = "Adwaita";
+      enable = true;
+      light = "Adwaita";
+      package = pkgs.adwaita-icon-theme;
+    };
+
+    overlays.enable = true;
+    polarity = "dark";
+
+    override =
+      {
+        author = "Stylix";
+        scheme = "Catppuccin Macchiato and Mocha";
+        slug = "catppuccin-macchiato-and-mocha";
+      }
+      // lib.importJSON (
+        pkgs.runCommand "catppuccin-macchiato-and-mocha.json"
+          {
+            nativeBuildInputs = [ pkgs.yq-go ];
+            src = "${pkgs.base16-schemes}/share/themes/catppuccin-mocha.yaml";
+          }
+          ''
+            yq \
+              --output-format json \
+              '
+                .palette |
+                with_entries(select(.key | test("^base0(1|3|5|7|9|B|D|F)$")))
+              ' \
+              <"$src" \
+              >"$out"
+          ''
+      );
+
+    # TODO: Explicitly enable the color functionality with 'stylix.colors.enable
+    # = true;' once this option is implemented.
+    base16Scheme = "${pkgs.base16-schemes}/share/themes/catppuccin-macchiato.yaml";
+
+    cursor = {
+      name = "Bibata-Modern-Amber";
+      package = pkgs.bibata-cursors;
+      size = 25;
+    };
+
+    fonts = {
+      # TODO: Since this declaration is the default stylix.fonts.emoji value,
+      # the default value or this declaration should be changed.
+      emoji = {
+        name = "Noto Color Emoji";
+        package = pkgs.noto-fonts-color-emoji;
+      };
+
+      monospace = {
+        name = "Fira Code";
+        package = pkgs.fira-code;
+      };
+
+      sansSerif = {
+        name = "Noto Sans";
+        package = pkgs.noto-fonts;
+      };
+
+      serif = {
+        name = "Noto Serif";
+        package = pkgs.noto-fonts;
+      };
+
+      sizes = lib.genAttrs (builtins.attrNames config.stylix.fonts.sizes) (_: 14);
+    };
+
+    # Test path containing special characters.
+    image =
+      let
+        file = "${
+          lib.pipe "-0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ_abcdefghijklmnopqrstuvwxyz" [
+            lib.stringToCharacters
+            (builtins.concatStringsSep " ")
+          ]
+        }.jpg";
+      in
+      "${
+        pkgs.runCommandLocal "image-path-containing-special-characters"
+          {
+            src = pkgs.fetchurl {
+              hash = "sha256-Dm/0nKiTFOzNtSiARnVg7zM0J1o+EuIdUQ3OAuasM58=";
+              name = "image.jpg";
+              url = "https://unsplash.com/photos/ZqLeQDjY6fY/download";
+            };
+          }
+          ''
+            mkdir "$out"
+            cp "$src" "$out"/${lib.escapeShellArg file}
+          ''
+      }/${file}";
+
+    opacity = lib.genAttrs (builtins.attrNames config.stylix.opacity) (_: 0.8);
+  };
+}