Support for VirtualBox network resources

examples/vbox-network.nix

@@ -0,0 +1,45 @@
+{
+    resources.virtualboxNetworks.net1 = { resources, ... }: {
+        type = "natnetwork";
+        cidrBlock = "192.168.100.0/24";
+        staticIPs = {
+            "192.168.100.11" = resources.machines.node1;
+            "192.168.100.12" = "node2";
+        };
+    };
+
+    resources.virtualboxNetworks.net2 = { resources, ... }: {
+        type = "hostonly";
+        cidrBlock = "192.168.101.0/24";
+        staticIPs = [
+            {
+                machine = resources.machines.node1;
+                address = "192.168.101.10";
+            }
+        ];
+    };
+
+    node1 = { resources, lib, pkgs, ... }: {
+        deployment.targetEnv = "virtualbox";
+        deployment.virtualbox.headless = true;
+        deployment.virtualbox.networks = [
+            { "type" = "nat"; }
+            resources.virtualboxNetworks.net1
+            resources.virtualboxNetworks.net2
+        ];
+    };
+
+    node2 = { resources, lib, pkgs, ... }: {
+        deployment.targetEnv = "virtualbox";
+        deployment.virtualbox.headless = true;
+        deployment.virtualbox.networks = [
+            resources.virtualboxNetworks.net2
+            resources.virtualboxNetworks.net1
+        ];
+    };
+
+    node3 = { resources, lib, pkgs, ... }: {
+        deployment.targetEnv = "virtualbox";
+        deployment.virtualbox.headless = true;
+    };
+}

nix/default.nix

@@ -16,5 +16,7 @@
   options = [
     ./virtualbox.nix
   ];
-  resources = { ... }: {};
+  resources = { evalResources, zipAttrs, resourcesByType, ...}: {
+    virtualboxNetworks = evalResources ./virtualbox-network.nix (zipAttrs resourcesByType.virtualboxNetworks or []);
+  };
 }

nix/virtualbox-network.nix

@@ -0,0 +1,73 @@
+{ config, lib, pkgs, uuid, name, ... }:
+
+with lib;
+with import <nixops/lib.nix> lib;
+
+let
+    toMachineName = m: if builtins.isString m then m else m._name;
+in
+rec {
+    options = {
+        type = mkOption {
+            default = "hostonly";
+            description = ''
+              The type of the VirtualBox network.
+              Either NAT network or Host-only network can be specified. Defaults to Host-only Network.
+            '';
+            type = types.enum [ "natnetwork" "hostonly" ];
+        };
+
+        cidrBlock = mkOption {
+            example = "192.168.56.0/24";
+            description = ''
+              The IPv4 CIDR block for the VirtualBox network. The following IP addresses are reserved for the network:
+              Network     - The first  address in the IP range, e.g. 192.168.56.0   in 192.168.56.0/24
+              Gateway     - The second address in the IP range, e.g. 192.168.56.1   in 192.168.56.0/24
+              DHCP Server - The third  address in the IP range, e.g. 192.168.56.2   in 192.168.56.0/24
+              Broadcast   - The last   address in the IP range, e.g. 192.168.56.255 in 192.168.56.0/24
+            '';
+            type = types.str;
+        };
+
+        staticIPs = mkOption {
+            example = ''
+              # As an attrset
+              {
+                "192.168.56.10" = "node1";
+                "192.168.56.11" = "node2";
+                ...
+              }
+              # Or as a list
+              [
+                { address = "192.168.56.10"; machine = "node1"; }
+                { address = "192.168.56.11"; machine = "node2"; }
+                ...
+              ]
+            '';
+            default = [];
+            description = "The list of machine to IPv4 address bindings for fixing IP address of the machine in the network";
+            apply = a: if builtins.isAttrs a then mapAttrs (k: toMachineName) a else a;
+            type = with types; either attrs (listOf (submodule {
+                options = {
+                    address = mkOption {
+                        example = "192.168.56.3";
+                        type = str;
+                        description = ''
+                          The IPv4 address assigned to the machine as static IP.
+                          The static IP must be a non-reserved IP address.
+                        '';
+                    };
+                    machine = mkOption {
+                        type = either str (resource "machine");
+                        apply = toMachineName;
+                        description = "The name of the machine in the network";
+                    };
+                };
+            }));
+        };
+    };
+
+    config = {
+        _type = "virtualbox-network";
+    };
+}

nix/virtualbox.nix

@@ -1,6 +1,7 @@
-{ config, pkgs, lib, ... }:
+{ config, pkgs, lib, resources, ... }:
 
 with lib;
+with import <nixops/lib.nix> lib;
 
 let
 
@@ -91,6 +92,38 @@ in
       });
     };
 
+    deployment.virtualbox.networks = mkOption {
+        default = [ { type = "nat"; } { type = "hostonly"; name = "vboxnet0"; } ];
+        description = ''
+          The list of networks to which the instance is attached. The network can be either
+          a virtualbox-network resource or a network not managed by NixOps.
+
+          For the sake of backward compatibility, the default list contains the following networks:
+           - NAT
+           - Host-only network vboxnet0
+
+          Note: NixOps requires at least one Host-only network to access the instance for management purposes,
+          When multiple Host-only networks exist, the first one in the list will be used for machine connection.
+        '';
+        type = with types; addCheck (nonEmptyListOf
+            (either
+                (resource "virtualbox-network")
+                (submodule {
+                    options = {
+                        name = mkOption {
+                            default = "";
+                            description = "The name of the network not managed by NixOps";
+                            type = str;
+                        };
+                        type = mkOption {
+                            description = "The type of the network";
+                            type = enum [ "none" "nat" "natnetwork" "bridged" "hostonly" "intnet" "generic" ];
+                        };
+                    };
+                })
+            )) (l: any (n: n.type == "hostonly") l);
+    };
+
     deployment.virtualbox.sharedFolders = mkOption {
       default = {};