Add nix/flake support

Example:

nix build github:mimblewimble/grin

./result/bin/grin --help

flake.nix

@@ -0,0 +1,51 @@
+{
+  description = "THE MIMBLEWIMBLE BLOCKCHAIN.";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/release-22.11";
+  };
+
+  outputs = { self, nixpkgs, }:
+    let
+      supportedSystems =
+        [
+          "x86_64-linux"
+          "x86_64-darwin"
+          "aarch64-linux"
+          "aarch64-darwin"
+        ];
+      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+      nixpkgsFor = forAllSystems (system: import nixpkgs
+        { inherit system; overlays = [ self.overlay ]; }
+      );
+    in
+    {
+      overlay = final: prev:
+        with final;
+        {
+          grin = pkgs.rustPlatform.buildRustPackage {
+            pname = "grin";
+            version = "5.2.0-alpha.2";
+            src = ./.;
+
+            cargoLock = {
+              lockFile = ./Cargo.lock;
+            };
+
+            nativeBuildInputs = [ pkgs.llvmPackages_latest.clang ];
+            buildInputs = [ pkgs.ncurses ];
+            LIBCLANG_PATH =
+              "${pkgs.llvmPackages_latest.libclang.lib}/lib";
+
+            # do not let test results block the build process
+            doCheck = false;
+          };
+        };
+
+      packages = forAllSystems (
+        system: {
+          default = nixpkgsFor.${system}.grin;
+        }
+      );
+    };
+}