[node-api] Add new port

ports/node-api/cmake-js-fetch/CMakeLists.txt

@@ -0,0 +1,19 @@
+cmake_minimum_required(VERSION 3.10)
+project(cmake-js-fetch)
+
+set(f ${CMAKE_CURRENT_BINARY_DIR}/node.cmake)
+
+foreach(p ${CMAKE_JS_INC})
+  string(REPLACE "\\" "\\\\" p ${p})
+  file(APPEND ${f} "set(CMAKE_JS_INC \"${p}\")\n")
+endforeach()
+
+foreach(p ${CMAKE_JS_SRC})
+  string(REPLACE "\\" "\\\\" p ${p})
+  file(APPEND ${f} "set(CMAKE_JS_SRC \"${p}\")\n")
+endforeach()
+
+foreach(p ${CMAKE_JS_LIB})
+  string(REPLACE "\\" "\\\\" p ${p})
+  file(APPEND ${f} "set(CMAKE_JS_LIB \"${p}\")\n")
+endforeach()

ports/node-api/package.json

@@ -0,0 +1,5 @@
+{
+  "scripts": {
+    "cmake-js-fetch": "cmake-js configure --directory cmake-js-fetch"
+  }
+}

ports/node-api/portfile.cmake

@@ -0,0 +1,56 @@
+# Based on qtwebengine
+find_program(NODEJS NAMES node PATHS "${CURRENT_HOST_INSTALLED_DIR}/tools/node" "bin" NO_DEFAULT_PATHS)
+find_program(NODEJS NAMES node)
+if(NOT NODEJS)
+    message(FATAL_ERROR "node not found! Please install it via your system package manager!")
+endif()
+
+get_filename_component(NODEJS_DIR "${NODEJS}" DIRECTORY)
+
+# check if vcpkg host is windows
+if(VCPKG_HOST_IS_WINDOWS)
+    set(npm_command "${NODEJS_DIR}/npm.cmd")
+else()
+    set(npm_command "${NODEJS_DIR}/npm")
+endif()
+
+file(REMOVE_RECURSE "${DOWNLOADS}/tmp-cmakejs-output")
+file(REMOVE_RECURSE "${DOWNLOADS}/tmp-cmakejs-home")
+file(MAKE_DIRECTORY "${DOWNLOADS}/tmp-cmakejs-output")
+file(MAKE_DIRECTORY "${DOWNLOADS}/tmp-cmakejs-home")
+
+vcpkg_execute_npm_command(
+    NPM_COMMAND ${npm_command}
+    COMMAND install [email protected]
+    WORKING_DIRECTORY "${NODEJS_DIR}"
+)
+
+# Precent pollution of user home directory
+file(READ "${NODEJS_DIR}/node_modules/cmake-js/lib/environment.js" environment_js)
+string(REPLACE "process.env[(os.platform() === \"win32\") ? \"USERPROFILE\" : \"HOME\"]" "\"${DOWNLOADS}/tmp-cmakejs-home\"" environment_js "${environment_js}")
+file(WRITE "${NODEJS_DIR}/node_modules/cmake-js/lib/environment.js" "${environment_js}")
+
+vcpkg_execute_npm_command(
+    NPM_COMMAND ${npm_command}
+    COMMAND run cmake-js-fetch --scripts-prepend-node-path -- --out "${DOWNLOADS}/tmp-cmakejs-output"
+    WORKING_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}" 
+)
+
+include("${DOWNLOADS}/tmp-cmakejs-output/node.cmake")
+
+file(COPY "${CMAKE_JS_INC}" DESTINATION "${CURRENT_PACKAGES_DIR}/include")
+file(COPY "${CMAKE_JS_LIB}" DESTINATION "${CURRENT_PACKAGES_DIR}/lib")
+file(COPY "${CMAKE_JS_LIB}" DESTINATION "${CURRENT_PACKAGES_DIR}/debug/lib")
+
+# Non-empty only for Windows at the current version of NodeJS
+if(CMAKE_JS_SRC)
+    file(COPY "${CMAKE_JS_SRC}" DESTINATION "${CURRENT_PACKAGES_DIR}/include/node")
+endif()
+
+# Handle copyright
+file(INSTALL "${NODEJS_DIR}/LICENSE" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
+
+# vcpkg remove doesn't remove cmake-js, so we need to remove it manually right now
+file(GLOB cmakejs_files "${NODEJS_DIR}/cmake-js*")
+file(REMOVE ${cmakejs_files})
+file(REMOVE_RECURSE "${NODEJS_DIR}/node_modules/cmake-js")

ports/node-api/vcpkg.json

@@ -0,0 +1,19 @@
+{
+  "name": "node-api",
+  "version-semver": "14.17.4",
+  "description": "NodeJS API for writing modules in C++",
+  "homepage": "https://nodejs.org/api/addons.html",
+  "license": "MIT",
+  "supports": "windows | linux | osx",
+  "dependencies": [
+    "vcpkg-tool-nodejs",
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ]
+}

ports/vcpkg-tool-nodejs/portfile.cmake

@@ -6,7 +6,13 @@ set(PROG_VERSION 14.17.4)
 set(BREW_PACKAGE_NAME "${PROGNAME}")
 set(APT_PACKAGE_NAME "${PROGNAME}")
 
-if(VCPKG_CROSSCOMPILING)
+set(RELAX_CROSSCOMPILING_CHECK OFF)
+if(VCPKG_TARGET_IS_WINDOWS AND VCPKG_HOST_IS_WINDOWS)
+    # it's ok to "cross-compile" from windows to windows in case of this port
+    set(RELAX_CROSSCOMPILING_CHECK ON)
+endif()
+
+if(VCPKG_CROSSCOMPILING AND NOT RELAX_CROSSCOMPILING_CHECK)
     message(FATAL_ERROR "This is a host only port!")
 endif()
 

ports/vcpkg-tool-nodejs/vcpkg.json

@@ -1,5 +1,5 @@
 {
   "name": "vcpkg-tool-nodejs",
   "version-semver": "14.17.4",
-  "supports": "native"
+  "supports": "windows | linux | osx"
 }

scripts/cmake/vcpkg_execute_npm_command.cmake

@@ -0,0 +1,28 @@
+function(vcpkg_execute_npm_command)
+  cmake_parse_arguments(A "" "WORKING_DIRECTORY;OUTPUT_VARIABLE;RESULT_VARIABLE;NPM_COMMAND" "COMMAND" ${ARGN})
+  foreach(arg WORKING_DIRECTORY COMMAND NPM_COMMAND)
+    if("${A_${arg}}" STREQUAL "")
+      message(FATAL_ERROR "Missing ${arg} argument")
+    endif()
+  endforeach()
+
+  if(NOT IS_ABSOLUTE "${A_WORKING_DIRECTORY}")
+    message(FATAL_ERROR "Expected WORKING_DIRECTORY to be an absolute path, but got: ${A_WORKING_DIRECTORY}")
+  endif()
+
+  execute_process(COMMAND "${A_NPM_COMMAND}" ${A_COMMAND}
+    WORKING_DIRECTORY ${A_WORKING_DIRECTORY}
+    RESULT_VARIABLE npm_result
+    OUTPUT_VARIABLE npm_output
+  )
+
+  if("${A_RESULT_VARIABLE}" STREQUAL "")
+    if(NOT "${npm_result}" STREQUAL "0")
+      message(FATAL_ERROR "${A_NPM_COMMAND} ${A_COMMAND} exited with ${npm_result}:\n${npm_output}")
+    endif()
+  else()
+    set("${A_RESULT_VARIABLE}" "${npm_result}" PARENT_SCOPE)
+  endif()
+
+  set("${A_OUTPUT_VARIABLE}" "${npm_output}" PARENT_SCOPE)
+endfunction()

scripts/ports.cmake

@@ -56,6 +56,7 @@ include("${SCRIPTS}/cmake/vcpkg_list.cmake")
 include("${SCRIPTS}/cmake/vcpkg_minimum_required.cmake")
 include("${SCRIPTS}/cmake/vcpkg_replace_string.cmake")
 include("${SCRIPTS}/cmake/vcpkg_test_cmake.cmake")
+include("${SCRIPTS}/cmake/vcpkg_execute_npm_command.cmake")
 
 include("${SCRIPTS}/cmake/z_vcpkg_apply_patches.cmake")
 include("${SCRIPTS}/cmake/z_vcpkg_forward_output_variable.cmake")

versions/baseline.json

@@ -4976,6 +4976,10 @@
       "baseline": "2021-02-21",
       "port-version": 3
     },
+    "node-api": {
+      "baseline": "14.17.4",
+      "port-version": 0
+    },
     "nonius": {
       "baseline": "2019-04-20",
       "port-version": 2

versions/n-/node-api.json

@@ -0,0 +1,9 @@
+{
+  "versions": [
+    {
+      "git-tree": "c7f7248a9cbc46b1328a30a3b06a3ed19ea4ad04",
+      "version-semver": "14.17.4",
+      "port-version": 0
+    }
+  ]
+}