ios: remove shared_application and support app extension build

shell/platform/darwin/common/framework/Source/FlutterNSBundleUtils.h

@@ -9,12 +9,12 @@
 
 NS_ASSUME_NONNULL_BEGIN
 
-// Finds a bundle with the named `bundleID` within `searchURL`.
+// Finds a bundle with the named `flutterFrameworkBundleID` within `searchURL`.
 //
 // Returns `nil` if the bundle cannot be found or if errors are encountered.
-NSBundle* FLTFrameworkBundleInternal(NSString* bundleID, NSURL* searchURL);
+NSBundle* FLTFrameworkBundleInternal(NSString* flutterFrameworkBundleID, NSURL* searchURL);
 
-// Finds a bundle with the named `bundleID`.
+// Finds a bundle with the named `flutterFrameworkBundleID`.
 //
 // `+[NSBundle bundleWithIdentifier:]` is slow, and can take in the order of
 // tens of milliseconds in a minimal flutter app, and closer to 100 milliseconds
@@ -28,7 +28,20 @@ NSBundle* FLTFrameworkBundleInternal(NSString* bundleID, NSURL* searchURL);
 // frameworks used by this file are placed. If the desired bundle cannot be
 // found here, the implementation falls back to
 // `+[NSBundle bundleWithIdentifier:]`.
-NSBundle* FLTFrameworkBundleWithIdentifier(NSString* bundleID);
+NSBundle* FLTFrameworkBundleWithIdentifier(NSString* flutterFrameworkBundleID);
+
+// Find the bundle of the application.
+//
+// This returns [NSBundle mainBundle] if the current running process is the application.
+NSBundle* FLTGetApplicationBundle();
+
+// Find the Flutter asset directory from `bundle`.
+//
+// The raw path can be set by the application via info.plist's `FLTAssetsPath` key.
+// If the key is not set, `flutter_assets` is used as the raw path value.
+//
+// If no valid asset is found under the raw path, return nil.
+NSURL* FLTAssetsURLFromBundle(NSBundle* bundle);
 
 NS_ASSUME_NONNULL_END
 

shell/platform/darwin/common/framework/Source/FlutterNSBundleUtils.mm

@@ -8,7 +8,7 @@
 
 FLUTTER_ASSERT_ARC
 
-NSBundle* FLTFrameworkBundleInternal(NSString* bundleID, NSURL* searchURL) {
+NSBundle* FLTFrameworkBundleInternal(NSString* flutterFrameworkBundleID, NSURL* searchURL) {
   NSDirectoryEnumerator<NSURL*>* frameworkEnumerator = [NSFileManager.defaultManager
                  enumeratorAtURL:searchURL
       includingPropertiesForKeys:nil
@@ -18,19 +18,46 @@
                     errorHandler:nil];
 
   for (NSURL* candidate in frameworkEnumerator) {
-    NSBundle* bundle = [NSBundle bundleWithURL:candidate];
-    if ([bundle.bundleIdentifier isEqualToString:bundleID]) {
-      return bundle;
+    NSBundle* flutterFrameworkBundle = [NSBundle bundleWithURL:candidate];
+    if ([flutterFrameworkBundle.bundleIdentifier isEqualToString:flutterFrameworkBundleID]) {
+      return flutterFrameworkBundle;
     }
   }
   return nil;
 }
 
-NSBundle* FLTFrameworkBundleWithIdentifier(NSString* bundleID) {
-  NSBundle* bundle = FLTFrameworkBundleInternal(bundleID, NSBundle.mainBundle.privateFrameworksURL);
-  if (bundle != nil) {
-    return bundle;
+NSBundle* FLTGetApplicationBundle() {
+  NSBundle* mainBundle = [NSBundle mainBundle];
+  // App extension bundle is in <AppName>.app/PlugIns/Extension.appex.
+  if ([mainBundle.bundleURL.pathExtension isEqualToString:@"appex"]) {
+    // Up two levels.
+    return [NSBundle bundleWithURL:mainBundle.bundleURL.URLByDeletingLastPathComponent
+                                       .URLByDeletingLastPathComponent];
   }
-  // Fallback to slow implementation.
-  return [NSBundle bundleWithIdentifier:bundleID];
+  return mainBundle;
+}
+
+NSBundle* FLTFrameworkBundleWithIdentifier(NSString* flutterFrameworkBundleID) {
+  NSBundle* appBundle = FLTGetApplicationBundle();
+  NSBundle* flutterFrameworkBundle =
+      FLTFrameworkBundleInternal(flutterFrameworkBundleID, appBundle.privateFrameworksURL);
+  if (flutterFrameworkBundle == nil) {
+    // Fallback to slow implementation.
+    flutterFrameworkBundle = [NSBundle bundleWithIdentifier:flutterFrameworkBundleID];
+  }
+  if (flutterFrameworkBundle == nil) {
+    flutterFrameworkBundle = [NSBundle mainBundle];
+  }
+  return flutterFrameworkBundle;
+}
+
+NSURL* FLTAssetsURLFromBundle(NSBundle* bundle) {
+  NSString* assetsPathFromInfoPlist = [bundle objectForInfoDictionaryKey:@"FLTAssetsPath"];
+  NSString* flutterAssetsPath = assetsPathFromInfoPlist ?: @"flutter_assets";
+  NSURL* assets = [bundle URLForResource:flutterAssetsPath withExtension:nil];
+
+  if ([assets checkResourceIsReachableAndReturnError:NULL]) {
+    return assets;
+  }
+  return nil;
 }

shell/platform/darwin/ios/BUILD.gn

@@ -336,6 +336,10 @@ shared_library("create_flutter_framework_dylib") {
 
   ldflags = [ "-Wl,-install_name,@rpath/Flutter.framework/Flutter" ]
 
+  if (darwin_extension_safe) {
+    ldflags += [ "-fapplication-extension" ]
+  }
+
   public = _flutter_framework_headers
 
   deps = [
@@ -426,14 +430,28 @@ copy("copy_license") {
 shared_library("copy_and_verify_framework_module") {
   framework_search_path = rebase_path("$root_out_dir")
   visibility = [ ":*" ]
-  cflags_objc = [ "-F$framework_search_path" ]
+  cflags_objc = [
+    "-F$framework_search_path",
+    "-fapplication-extension",
+  ]
 
   sources = [ "framework/Source/FlutterUmbrellaImport.m" ]
   deps = [
     ":copy_framework_headers",
     ":copy_framework_info_plist",
     ":copy_framework_module_map",
   ]
+
+  if (darwin_extension_safe) {
+    ldflags = [
+      "-F$framework_search_path",
+      "-fapplication-extension",
+      "-Xlinker",
+      "-fatal_warnings",
+    ]
+    deps += [ ":copy_dylib" ]
+    frameworks = [ "Flutter.framework" ]
+  }
 }
 
 group("universal_flutter_framework") {

shell/platform/darwin/ios/framework/Headers/FlutterPlugin.h

@@ -353,7 +353,8 @@ typedef enum {
  *
  * @param delegate The receiving object, such as the plugin's main class.
  */
-- (void)addApplicationDelegate:(NSObject<FlutterPlugin>*)delegate;
+- (void)addApplicationDelegate:(NSObject<FlutterPlugin>*)delegate
+    NS_EXTENSION_UNAVAILABLE_IOS("Disallowed in plugins used in app extensions");
 
 /**
  * Returns the file name for the given asset.

shell/platform/darwin/ios/framework/Source/FlutterDartProject.mm

@@ -41,16 +41,13 @@
   // 3. Settings from the NSBundle with the default bundle ID.
   // 4. Settings from the main NSBundle and default values.
 
-  NSBundle* mainBundle = [NSBundle mainBundle];
+  NSBundle* mainBundle = FLTGetApplicationBundle();
   NSBundle* engineBundle = [NSBundle bundleForClass:[FlutterViewController class]];
 
   bool hasExplicitBundle = bundle != nil;
   if (bundle == nil) {
     bundle = FLTFrameworkBundleWithIdentifier([FlutterDartProject defaultBundleIdentifier]);
   }
-  if (bundle == nil) {
-    bundle = mainBundle;
-  }
 
   auto settings = flutter::SettingsFromCommandLine(command_line);
 
@@ -122,29 +119,24 @@
 
   // Checks to see if the flutter assets directory is already present.
   if (settings.assets_path.empty()) {
-    NSString* assetsName = [FlutterDartProject flutterAssetsName:bundle];
-    NSString* assetsPath = [bundle pathForResource:assetsName ofType:@""];
-
-    if (assetsPath.length == 0) {
-      assetsPath = [mainBundle pathForResource:assetsName ofType:@""];
-    }
+    NSURL* assetsURL = FLTAssetsURLFromBundle(bundle);
 
-    if (assetsPath.length == 0) {
-      NSLog(@"Failed to find assets path for \"%@\"", assetsName);
+    if (!assetsURL) {
+      NSLog(@"Failed to find assets path for 1\"%@\"", bundle);
     } else {
-      settings.assets_path = assetsPath.UTF8String;
+      settings.assets_path = assetsURL.path.UTF8String;
 
       // Check if there is an application kernel snapshot in the assets directory we could
       // potentially use.  Looking for the snapshot makes sense only if we have a VM that can use
       // it.
       if (!flutter::DartVM::IsRunningPrecompiledCode()) {
         NSURL* applicationKernelSnapshotURL =
-            [NSURL URLWithString:@(kApplicationKernelSnapshotFileName)
-                   relativeToURL:[NSURL fileURLWithPath:assetsPath]];
-        if ([[NSFileManager defaultManager] fileExistsAtPath:applicationKernelSnapshotURL.path]) {
+            [assetsURL URLByAppendingPathComponent:@(kApplicationKernelSnapshotFileName)];
+        NSError* error;
+        if ([applicationKernelSnapshotURL checkResourceIsReachableAndReturnError:&error]) {
           settings.application_kernel_asset = applicationKernelSnapshotURL.path.UTF8String;
         } else {
-          NSLog(@"Failed to find snapshot: %@", applicationKernelSnapshotURL.path);
+          NSLog(@"Failed to find snapshot at %@: %@", applicationKernelSnapshotURL.path, error);
         }
       }
     }
@@ -339,9 +331,7 @@ + (NSString*)flutterAssetsName:(NSBundle*)bundle {
   if (bundle == nil) {
     bundle = FLTFrameworkBundleWithIdentifier([FlutterDartProject defaultBundleIdentifier]);
   }
-  if (bundle == nil) {
-    bundle = [NSBundle mainBundle];
-  }
+
   NSString* flutterAssetsName = [bundle objectForInfoDictionaryKey:@"FLTAssetsPath"];
   if (flutterAssetsName == nil) {
     flutterAssetsName = @"Frameworks/App.framework/flutter_assets";

shell/platform/darwin/ios/framework/Source/FlutterDartProjectTest.mm

@@ -73,6 +73,20 @@ - (void)testFLTFrameworkBundleInternalWhenBundleIsPresent {
   XCTAssertNotNil(found);
 }
 
+- (void)testFLTGetApplicationBundleWhenCurrentTargetIsNotExtension {
+  NSBundle* bundle = FLTGetApplicationBundle();
+  XCTAssertEqual(bundle, [NSBundle mainBundle]);
+}
+
+- (void)testFLTGetApplicationBundleWhenCurrentTargetIsExtension {
+  id mockMainBundle = OCMPartialMock([NSBundle mainBundle]);
+  NSURL* url = [[NSBundle mainBundle].bundleURL URLByAppendingPathComponent:@"foo/ext.appex"];
+  OCMStub([mockMainBundle bundleURL]).andReturn(url);
+  NSBundle* bundle = FLTGetApplicationBundle();
+  [mockMainBundle stopMocking];
+  XCTAssertEqualObjects(bundle.bundleURL, [NSBundle mainBundle].bundleURL);
+}
+
 - (void)testDisableImpellerSettingIsCorrectlyParsed {
   id mockMainBundle = OCMPartialMock([NSBundle mainBundle]);
   OCMStub([mockMainBundle objectForInfoDictionaryKey:@"FLTEnableImpeller"]).andReturn(@"NO");

shell/platform/darwin/ios/framework/Source/FlutterEngine.mm

@@ -1516,7 +1516,8 @@ - (void)addMethodCallDelegate:(NSObject<FlutterPlugin>*)delegate
   }];
 }
 
-- (void)addApplicationDelegate:(NSObject<FlutterPlugin>*)delegate {
+- (void)addApplicationDelegate:(NSObject<FlutterPlugin>*)delegate
+    NS_EXTENSION_UNAVAILABLE_IOS("Disallowed in plugins used in app extensions") {
   id<UIApplicationDelegate> appDelegate = [[UIApplication sharedApplication] delegate];
   if ([appDelegate conformsToProtocol:@protocol(FlutterAppLifeCycleProvider)]) {
     id<FlutterAppLifeCycleProvider> lifeCycleProvider =

shell/platform/darwin/ios/framework/Source/FlutterPlatformPlugin.mm

@@ -17,7 +17,10 @@
 
 constexpr char kTextPlainFormat[] = "text/plain";
 const UInt32 kKeyPressClickSoundId = 1306;
+
+#if not APPLICATION_EXTENSION_API_ONLY
 const NSString* searchURLPrefix = @"x-web-search://?";
+#endif
 
 }  // namespace
 
@@ -37,6 +40,24 @@
 
 using namespace flutter;
 
+static void SetStatusBarHiddenForSharedApplication(BOOL hidden) {
+#if APPLICATION_EXTENSION_API_ONLY
+  [UIApplication sharedApplication].statusBarHidden = hidden;
+#else
+  FML_LOG(WARNING) << "Application based status bar styling is not available in app extension.";
+#endif
+}
+
+static void SetStatusBarStyleForSharedApplication(UIStatusBarStyle style) {
+#if APPLICATION_EXTENSION_API_ONLY
+  // Note: -[UIApplication setStatusBarStyle] is deprecated in iOS9
+  // in favor of delegating to the view controller.
+  [[UIApplication sharedApplication] setStatusBarStyle:style];
+#else
+  FML_LOG(WARNING) << "Application based status bar styling is not available in app extension.";
+#endif
+}
+
 @interface FlutterPlatformPlugin ()
 
 /**
@@ -141,6 +162,9 @@ - (void)showShareViewController:(NSString*)content {
 }
 
 - (void)searchWeb:(NSString*)searchTerm {
+#if APPLICATION_EXTENSION_API_ONLY
+  FML_LOG(WARNING) << "SearchWeb.invoke is not availabe in app extension.";
+#else
   NSString* escapedText = [searchTerm
       stringByAddingPercentEncodingWithAllowedCharacters:[NSCharacterSet
                                                              URLHostAllowedCharacterSet]];
@@ -149,6 +173,7 @@ - (void)searchWeb:(NSString*)searchTerm {
   [[UIApplication sharedApplication] openURL:[NSURL URLWithString:searchURL]
                                      options:@{}
                            completionHandler:nil];
+#endif
 }
 
 - (void)playSystemSound:(NSString*)soundType {
@@ -231,7 +256,7 @@ - (void)setSystemChromeEnabledSystemUIOverlays:(NSArray*)overlays {
     // We opt out of view controller based status bar visibility since we want
     // to be able to modify this on the fly. The key used is
     // UIViewControllerBasedStatusBarAppearance.
-    [UIApplication sharedApplication].statusBarHidden = statusBarShouldBeHidden;
+    SetStatusBarHiddenForSharedApplication(statusBarShouldBeHidden);
   }
 }
 
@@ -246,7 +271,7 @@ - (void)setSystemChromeEnabledSystemUIMode:(NSString*)mode {
     // We opt out of view controller based status bar visibility since we want
     // to be able to modify this on the fly. The key used is
     // UIViewControllerBasedStatusBarAppearance.
-    [UIApplication sharedApplication].statusBarHidden = !edgeToEdge;
+    SetStatusBarHiddenForSharedApplication(!edgeToEdge);
   }
   [[NSNotificationCenter defaultCenter]
       postNotificationName:edgeToEdge ? FlutterViewControllerShowHomeIndicator
@@ -284,9 +309,7 @@ - (void)setSystemChromeSystemUIOverlayStyle:(NSDictionary*)message {
                       object:nil
                     userInfo:@{@(kOverlayStyleUpdateNotificationKey) : @(statusBarStyle)}];
   } else {
-    // Note: -[UIApplication setStatusBarStyle] is deprecated in iOS9
-    // in favor of delegating to the view controller.
-    [[UIApplication sharedApplication] setStatusBarStyle:statusBarStyle];
+    SetStatusBarStyleForSharedApplication(statusBarStyle);
   }
 }
 

shell/platform/darwin/ios/framework/Source/FlutterPlatformPluginTest.mm

@@ -50,9 +50,11 @@ - (void)testSearchWebInvokedWithEscapedTerm {
 
   FlutterResult result = ^(id result) {
     OCMVerify([mockPlugin searchWeb:@"Testing Word!"]);
+#if not APPLICATION_EXTENSION_API_ONLY
     OCMVerify([mockApplication openURL:[NSURL URLWithString:@"x-web-search://?Testing%20Word!"]
                                options:@{}
                      completionHandler:nil]);
+#endif
     [invokeExpectation fulfill];
   };
 
@@ -82,9 +84,11 @@ - (void)testSearchWebInvokedWithNonEscapedTerm {
 
   FlutterResult result = ^(id result) {
     OCMVerify([mockPlugin searchWeb:@"Test"]);
+#if not APPLICATION_EXTENSION_API_ONLY
     OCMVerify([mockApplication openURL:[NSURL URLWithString:@"x-web-search://?Test"]
                                options:@{}
                      completionHandler:nil]);
+#endif
     [invokeExpectation fulfill];
   };