iOS platform view gesture blocking policy.

shell/platform/darwin/ios/framework/Headers/FlutterPlugin.h

@@ -225,6 +225,42 @@ typedef void (*FlutterPluginRegistrantCallback)(NSObject<FlutterPluginRegistry>*
 - (void)handleMethodCall:(FlutterMethodCall*)call result:(FlutterResult)result;
 @end
 
+#pragma mark -
+/***************************************************************************************************
+ * How the UIGestureRecognizers of a platform view should be blocked.
+ *
+ * UIGestureRecognizers of a platform views can be blocked based on the decisions made by the
+ * Flutter Framework. e.g. When an interact-able widget is covering the platform view and a gesture
+ * happened on the widget, The framework may decide to block the UIGestureRecognizers that are
+ * recognized (via the gesture recognized acton ) on the platform view if any.
+ *
+ * This policy describes how the blocking process is implemented.
+ */
+typedef enum {
+  /**
+   * The flutter framework blocks all the UIGestureRecognizers on the platform view as soon as it
+   * decides they should be blocked.
+   *
+   * If this policy is implemented, only touchesBegan for all the UIGestureRecognizers is guaranteed
+   * to be called.
+   */
+  FlutterPlatformViewGestureRecognizersBlockingPolicyEager,
+  /**
+   * The flutter framework blocks all the UIGestureRecognizers until the `touchesEnded` method is
+   * called for every UIGestureRecognizers on the platform view.
+   *
+   * If this policy is implemented, all of the `touchesBegan`, `touchesMoved`, `touchesEnded` and
+   * `touchesCancelled` on any UIGestureRecognizers are guaranteed to be called if iOS system
+   * decided to call them.
+   */
+  FlutterPlatformViewGestureRecognizersBlockingPolicyWaitUntilTouchesEnded,
+  /**
+   * The default behavior is currently set to `FlutterPlatformViewGestureBlockingPolicyEager`
+   */
+  FlutterPlatformViewGestureRecognizersBlockingPolicyDefault =
+      FlutterPlatformViewGestureRecognizersBlockingPolicyEager,
+} FlutterPlatformViewGestureRecognizersBlockingPolicy;
+
 #pragma mark -
 /***************************************************************************************************
  *Registration context for a single `FlutterPlugin`, providing a one stop shop
@@ -264,6 +300,23 @@ typedef void (*FlutterPluginRegistrantCallback)(NSObject<FlutterPluginRegistry>*
 - (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
                      withId:(NSString*)factoryId;
 
+/**
+ * Registers a `FlutterPlatformViewFactory` for creation of platform views.
+ *
+ * Plugins expose `UIView` for embedding in Flutter apps by registering a view factory.
+ *
+ * @param factory The view factory that will be registered.
+ * @param factoryId A unique identifier for the factory, the Dart code of the Flutter app can use
+ *   this identifier to request creation of a `UIView` by the registered factory.
+ * @param gestureBlockingPolicy How UIGestureRecognizers on the platform views are
+ * blocked.
+ *
+ */
+- (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
+                              withId:(NSString*)factoryId
+    gestureRecognizersBlockingPolicy:
+        (FlutterPlatformViewGestureRecognizersBlockingPolicy)gestureRecognizersBlockingPolicy;
+
 /**
  * Publishes a value for external use of the plugin.
  *

shell/platform/darwin/ios/framework/Source/FlutterEngine.mm

@@ -737,7 +737,17 @@ - (NSString*)lookupKeyForAsset:(NSString*)asset fromPackage:(NSString*)package {
 
 - (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
                      withId:(NSString*)factoryId {
-  [_flutterEngine platformViewsController] -> RegisterViewFactory(factory, factoryId);
+  [self registerViewFactory:factory
+                                withId:factoryId
+      gestureRecognizersBlockingPolicy:FlutterPlatformViewGestureRecognizersBlockingPolicyDefault];
+}
+
+- (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
+                              withId:(NSString*)factoryId
+    gestureRecognizersBlockingPolicy:
+        (FlutterPlatformViewGestureRecognizersBlockingPolicy)gestureRecognizersBlockingPolicy {
+  [_flutterEngine platformViewsController] -> RegisterViewFactory(factory, factoryId,
+                                                                  gestureRecognizersBlockingPolicy);
 }
 
 @end

shell/platform/darwin/ios/framework/Source/FlutterPlatformViews.mm

@@ -86,8 +86,10 @@
   views_[viewId] = fml::scoped_nsobject<NSObject<FlutterPlatformView>>([embedded_view retain]);
 
   FlutterTouchInterceptingView* touch_interceptor = [[[FlutterTouchInterceptingView alloc]
-       initWithEmbeddedView:embedded_view.view
-      flutterViewController:flutter_view_controller_.get()] autorelease];
+                  initWithEmbeddedView:embedded_view.view
+                 flutterViewController:flutter_view_controller_.get()
+      gestureRecognizersBlockingPolicy:gesture_recognizers_blocking_policies[viewType]]
+      autorelease];
 
   touch_interceptors_[viewId] =
       fml::scoped_nsobject<FlutterTouchInterceptingView>([touch_interceptor retain]);
@@ -149,11 +151,13 @@
 
 void FlutterPlatformViewsController::RegisterViewFactory(
     NSObject<FlutterPlatformViewFactory>* factory,
-    NSString* factoryId) {
+    NSString* factoryId,
+    FlutterPlatformViewGestureRecognizersBlockingPolicy gestureRecognizerBlockingPolicy) {
   std::string idString([factoryId UTF8String]);
   FML_CHECK(factories_.count(idString) == 0);
   factories_[idString] =
       fml::scoped_nsobject<NSObject<FlutterPlatformViewFactory>>([factory retain]);
+  gesture_recognizers_blocking_policies[idString] = gestureRecognizerBlockingPolicy;
 }
 
 void FlutterPlatformViewsController::SetFrameSize(SkISize frame_size) {
@@ -513,6 +517,15 @@
 // invoking an acceptGesture method on the platform_views channel). And this is how we allow the
 // Flutter framework to delay or prevent the embedded view from getting a touch sequence.
 @interface DelayingGestureRecognizer : UIGestureRecognizer <UIGestureRecognizerDelegate>
+
+// Indicates that if the `DelayingGestureRecognizer`'s state should be set to
+// `UIGestureRecognizerStateEnded` during next `touchesEnded` call.
+@property(nonatomic) bool shouldEndInNextTouchesEnded;
+
+// Indicates that the `DelayingGestureRecognizer`'s `touchesEnded` has been invoked without
+// setting the state to `UIGestureRecognizerStateEnded`.
+@property(nonatomic) bool touchedEndedWithoutBlocking;
+
 - (instancetype)initWithTarget:(id)target
                         action:(SEL)action
           forwardingRecognizer:(UIGestureRecognizer*)forwardingRecognizer;
@@ -535,9 +548,12 @@ - (instancetype)initWithTarget:(id)target
 
 @implementation FlutterTouchInterceptingView {
   fml::scoped_nsobject<DelayingGestureRecognizer> _delayingRecognizer;
+  FlutterPlatformViewGestureRecognizersBlockingPolicy _blockingPolicy;
 }
 - (instancetype)initWithEmbeddedView:(UIView*)embeddedView
-               flutterViewController:(UIViewController*)flutterViewController {
+               flutterViewController:(UIViewController*)flutterViewController
+    gestureRecognizersBlockingPolicy:
+        (FlutterPlatformViewGestureRecognizersBlockingPolicy)blockingPolicy {
   self = [super initWithFrame:embeddedView.frame];
   if (self) {
     self.multipleTouchEnabled = YES;
@@ -554,6 +570,7 @@ - (instancetype)initWithEmbeddedView:(UIView*)embeddedView
               initWithTarget:self
                       action:nil
         forwardingRecognizer:forwardingRecognizer]);
+    _blockingPolicy = blockingPolicy;
 
     [self addGestureRecognizer:_delayingRecognizer.get()];
     [self addGestureRecognizer:forwardingRecognizer];
@@ -566,7 +583,27 @@ - (void)releaseGesture {
 }
 
 - (void)blockGesture {
-  _delayingRecognizer.get().state = UIGestureRecognizerStateEnded;
+  switch (_blockingPolicy) {
+    case FlutterPlatformViewGestureRecognizersBlockingPolicyEager:
+      // We block all other gesture recognizers immediately in this policy.
+      _delayingRecognizer.get().state = UIGestureRecognizerStateEnded;
+      break;
+    case FlutterPlatformViewGestureRecognizersBlockingPolicyWaitUntilTouchesEnded:
+      if (_delayingRecognizer.get().touchedEndedWithoutBlocking) {
+        // If touchesEnded of the `DelayingGesureRecognizer` has been already invoked,
+        // we want to set the state of the `DelayingGesureRecognizer` to
+        // `UIGestureRecognizerStateEnded` as soon as possible.
+        _delayingRecognizer.get().state = UIGestureRecognizerStateEnded;
+      } else {
+        // If touchesEnded of the `DelayingGesureRecognizer` has not been invoked,
+        // We will set a flag to notify the `DelayingGesureRecognizer` to set the state to
+        // `UIGestureRecognizerStateEnded` when touchesEnded is called.
+        _delayingRecognizer.get().shouldEndInNextTouchesEnded = YES;
+      }
+      break;
+    default:
+      break;
+  }
 }
 
 // We want the intercepting view to consume the touches and not pass the touches up to the parent
@@ -596,7 +633,10 @@ - (instancetype)initWithTarget:(id)target
   self = [super initWithTarget:target action:action];
   if (self) {
     self.delaysTouchesBegan = YES;
+    self.delaysTouchesEnded = YES;
     self.delegate = self;
+    self.shouldEndInNextTouchesEnded = NO;
+    self.touchedEndedWithoutBlocking = NO;
     _forwardingRecognizer.reset([forwardingRecognizer retain]);
   }
   return self;
@@ -614,6 +654,21 @@ - (BOOL)gestureRecognizer:(UIGestureRecognizer*)gestureRecognizer
   return otherGestureRecognizer == self;
 }
 
+- (void)touchesBegan:(NSSet<UITouch*>*)touches withEvent:(UIEvent*)event {
+  self.touchedEndedWithoutBlocking = NO;
+  [super touchesBegan:touches withEvent:event];
+}
+
+- (void)touchesEnded:(NSSet<UITouch*>*)touches withEvent:(UIEvent*)event {
+  if (self.shouldEndInNextTouchesEnded) {
+    self.state = UIGestureRecognizerStateEnded;
+    self.shouldEndInNextTouchesEnded = NO;
+  } else {
+    self.touchedEndedWithoutBlocking = YES;
+  }
+  [super touchesEnded:touches withEvent:event];
+}
+
 - (void)touchesCancelled:(NSSet*)touches withEvent:(UIEvent*)event {
   self.state = UIGestureRecognizerStateFailed;
 }

shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.h

@@ -11,6 +11,7 @@
 #include "flutter/shell/platform/darwin/common/framework/Headers/FlutterBinaryMessenger.h"
 #include "flutter/shell/platform/darwin/common/framework/Headers/FlutterChannels.h"
 #include "flutter/shell/platform/darwin/ios/framework/Headers/FlutterPlatformViews.h"
+#include "flutter/shell/platform/darwin/ios/framework/Headers/FlutterPlugin.h"
 
 // A UIView that is used as the parent for embedded UIViews.
 //
@@ -19,7 +20,9 @@
 // 2. Dispatching all events that are hittested to the embedded view to the FlutterView.
 @interface FlutterTouchInterceptingView : UIView
 - (instancetype)initWithEmbeddedView:(UIView*)embeddedView
-               flutterViewController:(UIViewController*)flutterViewController;
+               flutterViewController:(UIViewController*)flutterViewController
+    gestureRecognizersBlockingPolicy:
+        (FlutterPlatformViewGestureRecognizersBlockingPolicy)blockingPolicy;
 
 // Stop delaying any active touch sequence (and let it arrive the embedded view).
 - (void)releaseGesture;
@@ -80,7 +83,10 @@ class FlutterPlatformViewsController {
 
   void SetFlutterViewController(UIViewController* flutter_view_controller);
 
-  void RegisterViewFactory(NSObject<FlutterPlatformViewFactory>* factory, NSString* factoryId);
+  void RegisterViewFactory(
+      NSObject<FlutterPlatformViewFactory>* factory,
+      NSString* factoryId,
+      FlutterPlatformViewGestureRecognizersBlockingPolicy gestureRecognizerBlockingPolicy);
 
   void SetFrameSize(SkISize frame_size);
 
@@ -152,6 +158,10 @@ class FlutterPlatformViewsController {
   // Only compoiste platform views in this set.
   std::unordered_set<int64_t> views_to_recomposite_;
 
+  // The FlutterPlatformViewGestureRecognizersBlockingPolicy for each type of platform view.
+  std::map<std::string, FlutterPlatformViewGestureRecognizersBlockingPolicy>
+      gesture_recognizers_blocking_policies;
+
   std::map<int64_t, std::unique_ptr<SkPictureRecorder>> picture_recorders_;
 
   void OnCreate(FlutterMethodCall* call, FlutterResult& result);

testing/scenario_app/ios/Scenarios/Scenarios/TextPlatformView.m

@@ -57,7 +57,4 @@ - (UIView*)view {
   return _textView;
 }
 
-// - (void)onMethodCall:(FlutterMethodCall*)call result:(FlutterResult)result {
-// }
-
 @end