[#1353] Add support for prepareRename request

apps/els_core/src/els_client.erl

@@ -46,7 +46,8 @@
     document_formatting/3,
     document_rangeformatting/3,
     document_ontypeformatting/4,
-    document_rename/4,
+    rename/4,
+    prepare_rename/3,
     folding_range/1,
     shutdown/0,
     start_link/1,
@@ -179,11 +180,16 @@ document_rangeformatting(Uri, Range, FormattingOptions) ->
 document_ontypeformatting(Uri, Position, Char, FormattingOptions) ->
     gen_server:call(?SERVER, {document_ontypeformatting, {Uri, Position, Char, FormattingOptions}}).
 
--spec document_rename(uri(), non_neg_integer(), non_neg_integer(), binary()) ->
+-spec rename(uri(), non_neg_integer(), non_neg_integer(), binary()) ->
     ok.
-document_rename(Uri, Line, Character, NewName) ->
+rename(Uri, Line, Character, NewName) ->
     gen_server:call(?SERVER, {rename, {Uri, Line, Character, NewName}}).
 
+-spec prepare_rename(uri(), non_neg_integer(), non_neg_integer()) ->
+    ok.
+prepare_rename(Uri, Line, Character) ->
+    gen_server:call(?SERVER, {preparerename, {Uri, Line, Character}}).
+
 -spec did_open(uri(), binary(), number(), binary()) -> ok.
 did_open(Uri, LanguageId, Version, Text) ->
     gen_server:call(?SERVER, {did_open, {Uri, LanguageId, Version, Text}}).
@@ -447,6 +453,7 @@ method_lookup(document_formatting) -> <<"textDocument/formatting">>;
 method_lookup(document_rangeformatting) -> <<"textDocument/rangeFormatting">>;
 method_lookup(document_ontypeormatting) -> <<"textDocument/onTypeFormatting">>;
 method_lookup(rename) -> <<"textDocument/rename">>;
+method_lookup(preparerename) -> <<"textDocument/prepareRename">>;
 method_lookup(did_open) -> <<"textDocument/didOpen">>;
 method_lookup(did_save) -> <<"textDocument/didSave">>;
 method_lookup(did_close) -> <<"textDocument/didClose">>;
@@ -506,7 +513,9 @@ request_params({initialize, {RootUri, InitOptions}}) ->
                     #{<<"snippetSupport">> => 'true'}
             },
         <<"hover">> =>
-            #{<<"contentFormat">> => ContentFormat}
+            #{<<"contentFormat">> => ContentFormat},
+        <<"rename">> =>
+            #{<<"prepareSupport">> => 'true'}
     },
     #{
         <<"rootUri">> => RootUri,
@@ -538,6 +547,14 @@ request_params({rename, {Uri, Line, Character, NewName}}) ->
         },
         newName => NewName
     };
+request_params({preparerename, {Uri, Line, Character}}) ->
+    #{
+        textDocument => #{uri => Uri},
+        position => #{
+            line => Line,
+            character => Character
+        }
+    };
 request_params({folding_range, {Uri}}) ->
     TextDocument = #{uri => Uri},
     #{textDocument => TextDocument};

apps/els_lsp/src/els_general_provider.erl

@@ -194,7 +194,8 @@ server_capabilities() ->
                 els_execute_command_provider:options(),
             codeLensProvider =>
                 els_code_lens_provider:options(),
-            renameProvider => true,
+            renameProvider =>
+                els_rename_provider:options(),
             callHierarchyProvider => true,
             semanticTokensProvider =>
                 #{

apps/els_lsp/src/els_methods.erl

@@ -27,6 +27,7 @@
     textdocument_codeaction/2,
     textdocument_codelens/2,
     textdocument_rename/2,
+    textdocument_preparerename/2,
     textdocument_preparecallhierarchy/2,
     textdocument_semantictokens_full/2,
     textdocument_signaturehelp/2,
@@ -432,6 +433,16 @@ textdocument_rename(Params, State) ->
         els_provider:handle_request(Provider, {rename, Params}),
     {response, Response, State}.
 
+%%==============================================================================
+%% textDocument/prepareRename
+%%=============================================================================
+-spec textdocument_preparerename(params(), els_server:state()) -> result().
+textdocument_preparerename(Params, State) ->
+    Provider = els_prepare_rename_provider,
+    {response, Response} =
+        els_provider:handle_request(Provider, {prepare_rename, Params}),
+    {response, Response, State}.
+
 %%==============================================================================
 %% textDocument/semanticTokens/full
 %%==============================================================================

apps/els_lsp/src/els_prepare_rename_provider.erl

@@ -0,0 +1,84 @@
+-module(els_prepare_rename_provider).
+
+-behaviour(els_provider).
+
+-export([
+    handle_request/1
+]).
+
+%%==============================================================================
+%% Includes
+%%==============================================================================
+-include_lib("kernel/include/logger.hrl").
+
+%%==============================================================================
+%% Defines
+%%==============================================================================
+
+%%==============================================================================
+%% Types
+%%==============================================================================
+
+%%==============================================================================
+%% els_provider functions
+%%==============================================================================
+-spec handle_request(any()) -> {response, any()}.
+handle_request({prepare_rename, Params0}) ->
+    #{
+        <<"textDocument">> := #{<<"uri">> := Uri},
+        <<"position">> := #{
+            <<"line">> := Line,
+            <<"character">> := Character
+        }
+    } = Params0,
+    case els_utils:lookup_document(Uri) of
+        {ok, Document} ->
+            Params = Params0#{<<"newName">> => <<"newName">>},
+            POIs = els_dt_document:get_element_at_pos(
+                Document,
+                Line + 1,
+                Character + 1
+            ),
+            case POIs of
+                [POI | _] ->
+                    try
+                        els_provider:handle_request(
+                            els_rename_provider,
+                            {rename, Params}
+                        )
+                    of
+                        {response, null} ->
+                            {response, null};
+                        {response, _} ->
+                            {response, els_protocol:range(rename_range(POI))}
+                    catch
+                        Class:Reason:Stacktrace ->
+                            ?LOG_ERROR(
+                                "prepareRenamed failed: ~p:~p\n"
+                                "Stacktrace:\n~p\n",
+                                [Class, Reason, Stacktrace]
+                            ),
+                            {response, null}
+                    end;
+                _ ->
+                    {response, null}
+            end;
+        {error, Error} ->
+            ?LOG_WARNING("Failed to read uri: ~p ~p", [Error, Uri]),
+            {response, null}
+    end.
+
+%%==============================================================================
+%% Internal functions
+%%==============================================================================
+-spec rename_range(els_poi:poi()) -> els_poi:poi_range().
+rename_range(#{data := #{name_range := Range}}) ->
+    Range;
+rename_range(#{kind := Kind, range := #{from := {FromL, FromC}, to := To}}) when
+    Kind =:= macro;
+    Kind =:= record_expr
+->
+    %% Don't include # or ? in name..
+    #{from => {FromL, FromC + 1}, to => To};
+rename_range(#{range := Range}) ->
+    Range.

apps/els_lsp/src/els_rename_provider.erl

@@ -3,7 +3,8 @@
 -behaviour(els_provider).
 
 -export([
-    handle_request/1
+    handle_request/1,
+    options/0
 ]).
 
 %%==============================================================================
@@ -38,10 +39,23 @@ handle_request({rename, Params}) ->
     WorkspaceEdits = workspace_edits(Uri, Elem, NewName),
     {response, WorkspaceEdits}.
 
+-spec options() -> boolean() | map().
+options() ->
+    case els_config:get(capabilities) of
+        #{<<"textDocument">> := #{<<"rename">> := #{<<"prepareSupport">> := true}}} ->
+            #{prepareProvider => true};
+        _ ->
+            true
+    end.
+
 %%==============================================================================
 %% Internal functions
 %%==============================================================================
--spec workspace_edits(uri(), [els_poi:poi()], binary()) -> null | [any()].
+-spec workspace_edits(
+    uri(),
+    [els_poi:poi()],
+    binary()
+) -> null | [any()].
 workspace_edits(_Uri, [], _NewName) ->
     null;
 workspace_edits(OldUri, [#{kind := module} = POI | _], NewName) ->
@@ -61,7 +75,8 @@ workspace_edits(OldUri, [#{kind := module} = POI | _], NewName) ->
     ]),
     Changes = [
         #{
-            textDocument => #{uri => RefUri, version => null},
+            textDocument =>
+                #{uri => RefUri, version => null},
             edits => [
                 #{
                     range => editable_range(RefPOI, module),

apps/els_lsp/test/els_initialization_SUITE.erl

@@ -25,7 +25,8 @@
     initialize_lenses_invalid/1,
     initialize_providers_default/1,
     initialize_providers_custom/1,
-    initialize_providers_invalid/1
+    initialize_providers_invalid/1,
+    initialize_prepare_rename/1
 ]).
 
 %%==============================================================================
@@ -255,3 +256,12 @@ initialize_providers_invalid(Config) ->
     #{capabilities := Capabilities} = els_general_provider:server_capabilities(),
     ?assertEqual(true, maps:is_key(hoverProvider, Capabilities)),
     ok.
+
+-spec initialize_prepare_rename(config()) -> ok.
+initialize_prepare_rename(_Config) ->
+    RootUri = els_test_utils:root_uri(),
+    els_client:initialize(RootUri),
+    #{capabilities := #{renameProvider := RenameProvider}} =
+        els_general_provider:server_capabilities(),
+    ?assertEqual(#{prepareProvider => true}, RenameProvider),
+    ok.