Provide a Gradualizer diagnostic

apps/els_lsp/priv/code_navigation/src/diagnostics_gradualizer.erl

@@ -0,0 +1,11 @@
+-module(diagnostics_gradualizer).
+
+-export([g/1]).
+
+-spec f(integer()) -> integer().
+f(N) ->
+    N.
+
+-spec g(boolean()) -> boolean().
+g(N) ->
+    f(N).

apps/els_lsp/src/els_diagnostics.erl

@@ -61,6 +61,7 @@ available_diagnostics() ->
   , <<"compiler">>
   , <<"crossref">>
   , <<"dialyzer">>
+  , <<"gradualizer">>
   , <<"elvis">>
   , <<"unused_includes">>
   , <<"unused_macros">>

apps/els_lsp/src/els_gradualizer_diagnostics.erl

@@ -0,0 +1,106 @@
+%%==============================================================================
+%% Compiler diagnostics
+%%==============================================================================
+-module(els_gradualizer_diagnostics).
+
+%%==============================================================================
+%% Behaviours
+%%==============================================================================
+-behaviour(els_diagnostics).
+
+%%==============================================================================
+%% Exports
+%%==============================================================================
+-export([ is_default/0
+        , run/1
+        , source/0
+        ]).
+
+%%==============================================================================
+%% Includes
+%%==============================================================================
+-include("els_lsp.hrl").
+-include_lib("kernel/include/logger.hrl").
+
+%%==============================================================================
+%% Type Definitions
+%%==============================================================================
+%% -type macro_config() :: #{string() => string()}.
+%% -type macro_option() :: {atom()} | {atom(), any()}.
+
+%%==============================================================================
+%% Callback Functions
+%%==============================================================================
+
+-spec is_default() -> boolean().
+is_default() ->
+  false.
+
+-spec run(uri()) -> [els_diagnostics:diagnostic()].
+run(Uri) ->
+  case start_and_load() of
+    true ->
+      Path = unicode:characters_to_list(els_uri:path(Uri)),
+      Includes = [{i, I} || I <- els_config:get(include_paths)],
+      Opts = [return_errors] ++ Includes,
+      Errors = gradualizer:type_check_files([Path], Opts),
+      lists:flatmap(fun analyzer_error/1, Errors);
+    false ->
+      []
+  end.
+
+-spec source() -> binary().
+source() ->
+  <<"Gradualizer">>.
+
+%%==============================================================================
+%% Internal Functions
+%%==============================================================================
+
+-spec start_and_load() -> boolean().
+start_and_load() ->
+  try application:ensure_all_started(gradualizer) of
+    {ok, [gradualizer]} ->
+      Files = lists:flatmap(
+                fun(Dir) ->
+                    filelib:wildcard(filename:join(Dir, "*.erl"))
+                end,
+                els_config:get(apps_paths) ++ els_config:get(deps_paths)),
+      case erlang:function_exported(
+             gradualizer_db, import_erl_files, 2) of
+        true ->
+          ok = gradualizer_db:import_erl_files(
+                 Files,
+                 els_config:get(include_paths));
+        false ->
+          ok = gradualizer_db:import_erl_files(Files)
+      end,
+      true;
+    {ok, []} ->
+      true
+  catch E:R ->
+          ?LOG_ERROR("Could not start gradualizer: ~p ~p", [E, R]),
+          false
+  end.
+
+-spec analyzer_error(any()) -> any().
+analyzer_error({_Path, Error}) ->
+  FmtOpts = [{fmt_location, brief}, {color, never}],
+  FmtError = gradualizer_fmt:format_type_error(Error, FmtOpts),
+  case re:run(FmtError, "([0-9]+):([0-9]+:)? (.*)",
+              [{capture, all_but_first, binary}, dotall]) of
+    {match, [BinLine, _BinCol, Msg]} ->
+      Line = case binary_to_integer(BinLine) of
+               0 -> 1;
+               L -> L
+             end,
+      Range = els_protocol:range(
+                #{ from => {Line, 1},
+                   to => {Line + 1, 1} }),
+      [#{ range => Range,
+          message => Msg,
+          severity => ?DIAGNOSTIC_WARNING,
+          source => source() }];
+    _ ->
+      []
+  end.

apps/els_lsp/src/els_lsp.app.src

@@ -14,7 +14,8 @@
         uuid,
         getopt,
         erlfmt,
-        els_core
+        els_core,
+        gradualizer
     ]},
     {env, []},
     {modules, []},

apps/els_lsp/test/els_diagnostics_SUITE.erl

@@ -39,6 +39,7 @@
         , exclude_unused_includes/1
         , unused_macros/1
         , unused_record_fields/1
+        , gradualizer/1
         ]).
 
 %%==============================================================================
@@ -120,6 +121,11 @@ init_per_testcase(TestCase, Config) when TestCase =:= compiler_telemetry ->
   els_mock_diagnostics:setup(),
   mock_compiler_telemetry_enabled(),
   els_test_utils:init_per_testcase(TestCase, Config);
+init_per_testcase(TestCase, Config) when TestCase =:= gradualizer ->
+  meck:new(els_gradualizer_diagnostics, [passthrough, no_link]),
+  meck:expect(els_gradualizer_diagnostics, is_default, 0, true),
+  els_mock_diagnostics:setup(),
+  els_test_utils:init_per_testcase(TestCase, Config);
 init_per_testcase(TestCase, Config) ->
   els_mock_diagnostics:setup(),
   els_test_utils:init_per_testcase(TestCase, Config).
@@ -156,6 +162,11 @@ end_per_testcase(TestCase, Config) when TestCase =:= compiler_telemetry ->
   els_test_utils:end_per_testcase(TestCase, Config),
   els_mock_diagnostics:teardown(),
   ok;
+end_per_testcase(TestCase, Config) when TestCase =:= gradualizer ->
+  meck:unload(els_gradualizer_diagnostics),
+  els_test_utils:end_per_testcase(TestCase, Config),
+  els_mock_diagnostics:teardown(),
+  ok;
 end_per_testcase(TestCase, Config) ->
   els_test_utils:end_per_testcase(TestCase, Config),
   els_mock_diagnostics:teardown(),
@@ -169,7 +180,9 @@ bound_var_in_pattern(Config) ->
   Uri = ?config(diagnostics_bound_var_in_pattern_uri, Config),
   els_mock_diagnostics:subscribe(),
   ok = els_client:did_save(Uri),
-  Diagnostics = els_mock_diagnostics:wait_until_complete(),
+  Diagnostics = lists:filter(fun (#{source := <<"BoundVarInPattern">>}) -> true;
+                                 (_) -> false end,
+                             els_mock_diagnostics:wait_until_complete()),
   Expected =
     [ #{message => <<"Bound variable in pattern: Var1">>,
         range =>
@@ -778,6 +791,24 @@ unused_record_fields(Config) ->
   ?assertEqual(Expected, lists:sort(F, Diagnostics)),
   ok.
 
+-spec gradualizer(config()) -> ok.
+gradualizer(Config) ->
+  Uri = ?config(diagnostics_gradualizer_uri, Config),
+  els_mock_diagnostics:subscribe(),
+  ok = els_client:did_save(Uri),
+  Diagnostics = els_mock_diagnostics:wait_until_complete(),
+  Diagnostics == []
+    andalso ct:fail("Diagnostics should not be empty - is Gradualizer "
+                    "available in the code path?"),
+  Expected = [#{message => <<"The variable N is expected to have type "
+                             "integer() but it has type false | true\n">>,
+                range => #{'end' => #{character => 0, line => 11},
+                           start => #{character => 0, line => 10}},
+                severity => 2, source => <<"Gradualizer">>}],
+  F = fun(#{message := M1}, #{message := M2}) -> M1 =< M2 end,
+  ?assertEqual(Expected, lists:sort(F, Diagnostics)),
+  ok.
+
 %%==============================================================================
 %% Internal Functions
 %%==============================================================================

rebar.config

@@ -16,6 +16,7 @@
        , {ephemeral,     "2.0.4"}
        , {tdiff,         "0.1.2"}
        , {uuid,          "2.0.1", {pkg, uuid_erl}}
+       , {gradualizer, {git, "https://github.com/josefs/Gradualizer.git", {ref, "0510404"}}}
        ]
 }.
 

rebar.lock

@@ -8,6 +8,10 @@
        {ref,"2e93fc4a646111357642b0179a2a63151868d890"}},
   0},
  {<<"getopt">>,{pkg,<<"getopt">>,<<"1.0.1">>},2},
+ {<<"gradualizer">>,
+  {git,"https://github.com/josefs/Gradualizer.git",
+       {ref,"051040400924dfcfe59f7a8936beb34b43278191"}},
+  0},
  {<<"jsx">>,{pkg,<<"jsx">>,<<"3.0.0">>},0},
  {<<"katana_code">>,{pkg,<<"katana_code">>,<<"0.2.1">>},1},
  {<<"providers">>,{pkg,<<"providers">>,<<"1.8.1">>},1},