[WIP] bazel: use experimental cmake_external for cares/nghttp2.

WORKSPACE

@@ -4,6 +4,9 @@ load("//bazel:repositories.bzl", "envoy_dependencies")
 load("//bazel:cc_configure.bzl", "cc_configure")
 
 envoy_dependencies()
+load("@rules_foreign_cc//:workspace_definitions.bzl", "rules_foreign_cc_dependencies")
+rules_foreign_cc_dependencies()
+
 cc_configure()
 
 load("@envoy_api//bazel:repositories.bzl", "api_dependencies")

bazel/EXTERNAL_DEPS.md

@@ -9,6 +9,18 @@ build process.
    `external_deps` attribute.
 3. `bazel test //test/...`
 
+# Adding external dependencies to Envoy (extern cmake)
+
+This is the preferred style of adding dependencies that use cmake for their build system.
+
+1. Define a the source Bazel repository in [`bazel/repositories.bzl`](repositories.bzl), in the
+   `envoy_dependencies()` function.
+2. Add a `cmake_external` rule to [`bazel/foreign_cc/BUILD`](bazel/foreign_cc/BUILD). This will
+   reference the source repository in step 1.
+3. Reference your new external dependency in some `envoy_cc_library` via Y in the
+   `external_deps` attribute.
+4. `bazel test //test/...`
+
 # Adding external dependencies to Envoy (genrule repository)
 
 This is the newer style of adding dependencies with no upstream Bazel configs.

bazel/foreign_cc/BUILD

@@ -0,0 +1,39 @@
+licenses(["notice"])  # Apache 2
+
+load("//bazel:envoy_build_system.bzl", "envoy_package")
+load("@rules_foreign_cc//tools/build_defs:cmake.bzl", "cmake_external")
+load("@foreign_cc_platform_utils//:tools.bzl", "NINJA_COMMAND", "NINJA_DEP")
+
+envoy_package()
+
+cmake_external(
+    name = "ares",
+    cache_entries = {
+        "CARES_SHARED": "no",
+        "CARES_STATIC": "on",
+    },
+    cmake_options = ["-GNinja"],
+    lib_source = "@com_github_c_ares_c_ares//:all",
+    make_commands = [
+        NINJA_COMMAND,
+        NINJA_COMMAND + " install",
+    ],
+    static_libraries = ["libcares.a"],
+    tools_deps = NINJA_DEP,
+)
+
+cmake_external(
+    name = "nghttp2",
+    cache_entries = {
+        "ENABLE_STATIC_LIB": "on",
+        "ENABLE_LIB_ONLY": "on",
+    },
+    cmake_options = ["-GNinja"],
+    lib_source = "@com_github_nghttp2_nghttp2//:all",
+    make_commands = [
+        NINJA_COMMAND,
+        NINJA_COMMAND + " install",
+    ],
+    static_libraries = ["libnghttp2.a"],
+    tools_deps = NINJA_DEP,
+)

bazel/foreign_cc/nghttp2.patch

@@ -0,0 +1,12 @@
+diff --git a/lib/CMakeLists.txt b/lib/CMakeLists.txt
+index 17e422b2..e58070f5 100644
+--- a/lib/CMakeLists.txt
++++ b/lib/CMakeLists.txt
+@@ -52,6 +52,7 @@
+     COMPILE_FLAGS "${WARNCFLAGS}"
+     VERSION ${LT_VERSION} SOVERSION ${LT_SOVERSION}
+     ARCHIVE_OUTPUT_NAME nghttp2
++    ARCHIVE_OUTPUT_DIRECTORY static
+   )
+   target_compile_definitions(nghttp2_static PUBLIC "-DNGHTTP2_STATICLIB")
+   if(ENABLE_STATIC_LIB)

bazel/repositories.bzl

@@ -3,8 +3,8 @@ load(
     "git_repository",
     "new_git_repository",
 )
+load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
 load(":genrule_repository.bzl", "genrule_repository")
-load(":patched_http_archive.bzl", "patched_http_archive")
 load(":repository_locations.bzl", "REPOSITORY_LOCATIONS")
 load(":target_recipes.bzl", "TARGET_RECIPES")
 load(
@@ -17,6 +17,10 @@ load("@bazel_tools//tools/cpp:lib_cc_configure.bzl", "get_env_var")
 # dict of {build recipe name: longform extension name,}
 PPC_SKIP_TARGETS = {"luajit": "envoy.filters.http.lua"}
 
+# Make all contents of an external repository accessible under a filegroup.  Used for external HTTP
+# archives, e.g. cares.
+BUILD_ALL_CONTENT = """filegroup(name = "all", srcs = glob(["**"]), visibility = ["//visibility:public"])"""
+
 def _repository_impl(name, **kwargs):
     # `existing_rule_keys` contains the names of repositories that have already
     # been defined in the Bazel workspace. By skipping repos with existing keys,
@@ -278,13 +282,17 @@ def envoy_dependencies(path = "@envoy_deps//", skip_targets = []):
     if "envoy_build_config" not in native.existing_rules().keys():
         _default_envoy_build_config(name = "envoy_build_config")
 
+    # Setup rules_foreign_cc
+    _foreign_cc_dependencies()
+
     # The long repo names (`com_github_fmtlib_fmt` instead of `fmtlib`) are
     # semi-standard in the Bazel community, intended to avoid both duplicate
     # dependencies and name conflicts.
     _boringssl()
     _com_google_absl()
     _com_github_bombela_backward()
     _com_github_circonus_labs_libcircllhist()
+    _com_github_c_ares_c_ares()
     _com_github_cyan4973_xxhash()
     _com_github_eile_tclap()
     _com_github_fmtlib_fmt()
@@ -296,6 +304,7 @@ def envoy_dependencies(path = "@envoy_deps//", skip_targets = []):
     _com_github_grpc_grpc()
     _com_github_google_jwt_verify()
     _com_github_nanopb_nanopb()
+    _com_github_nghttp2_nghttp2()
     _com_github_nodejs_http_parser()
     _com_github_tencent_rapidjson()
     _com_google_googletest()
@@ -336,6 +345,18 @@ def _com_github_circonus_labs_libcircllhist():
         actual = "@com_github_circonus_labs_libcircllhist//:libcircllhist",
     )
 
+def _com_github_c_ares_c_ares():
+    location = REPOSITORY_LOCATIONS["com_github_c_ares_c_ares"]
+    http_archive(
+        name = "com_github_c_ares_c_ares",
+        build_file_content = BUILD_ALL_CONTENT,
+        **location
+    )
+    native.bind(
+        name = "ares",
+        actual = "//bazel/foreign_cc:ares",
+    )
+
 def _com_github_cyan4973_xxhash():
     _repository_impl(
         name = "com_github_cyan4973_xxhash",
@@ -396,6 +417,21 @@ def _com_github_google_libprotobuf_mutator():
         actual = "@com_github_google_libprotobuf_mutator//:libprotobuf_mutator",
     )
 
+def _com_github_nghttp2_nghttp2():
+    location = REPOSITORY_LOCATIONS["com_github_nghttp2_nghttp2"]
+    http_archive(
+        name = "com_github_nghttp2_nghttp2",
+        build_file_content = BUILD_ALL_CONTENT,
+        patch_args = ["-p1"],
+        patch_cmds = ["find . -name '*.sh' -exec sed -i.orig '1s|#!/usr/bin/env sh\$|/bin/sh\$|' {} +"],
+        patches = ["//bazel/foreign_cc:nghttp2.patch"],
+        **location
+    )
+    native.bind(
+        name = "nghttp2",
+        actual = "//bazel/foreign_cc:nghttp2",
+    )
+
 def _io_opentracing_cpp():
     _repository_impl("io_opentracing_cpp")
     native.bind(
@@ -542,6 +578,14 @@ def _com_github_google_jwt_verify():
         actual = "@com_github_google_jwt_verify//:jwt_verify_lib",
     )
 
+def _foreign_cc_dependencies():
+    http_archive(
+        name = "rules_foreign_cc",
+        strip_prefix = "rules_foreign_cc-master",
+        # TODO(htuch): Pin to SHA or release.
+        url = "https://github.com/bazelbuild/rules_foreign_cc/archive/master.zip",
+    )
+
 def _apply_dep_blacklist(ctxt, recipes):
     newlist = []
     skip_list = dict()

bazel/repository_locations.bzl

@@ -18,6 +18,11 @@ REPOSITORY_LOCATIONS = dict(
         strip_prefix = "backward-cpp-1.4",
         urls = ["https://github.com/bombela/backward-cpp/archive/v1.4.tar.gz"],
     ),
+    com_github_c_ares_c_ares = dict(
+        sha256 = "62dd12f0557918f89ad6f5b759f0bf4727174ae9979499f5452c02be38d9d3e8",
+        strip_prefix = "c-ares-cares-1_14_0",
+        urls = ["https://github.com/c-ares/c-ares/archive/cares-1_14_0.tar.gz"],
+    ),
     com_github_circonus_labs_libcircllhist = dict(
         commit = "050da53a44dede7bda136b93a9aeef47bd91fa12",  # 2018-07-02
         remote = "https://github.com/circonus-labs/libcircllhist",
@@ -62,6 +67,11 @@ REPOSITORY_LOCATIONS = dict(
         strip_prefix = "nanopb-f8ac463766281625ad710900479130c7fcb4d63b",
         urls = ["https://github.com/nanopb/nanopb/archive/f8ac463766281625ad710900479130c7fcb4d63b.tar.gz"],
     ),
+    com_github_nghttp2_nghttp2 = dict(
+        sha256 = "42fff7f290100c02234ac3b0095852e4392e6bfd95ebed900ca8bd630850d88c",
+        strip_prefix = "nghttp2-1.33.0",
+        urls = ["https://github.com/nghttp2/nghttp2/releases/download/v1.33.0/nghttp2-1.33.0.tar.gz"],
+    ),
     io_opentracing_cpp = dict(
         sha256 = "4455ca507936bc4b658ded10a90d8ebbbd61c58f06207be565a4ffdc885687b5",
         strip_prefix = "opentracing-cpp-1.5.0",

bazel/target_recipes.bzl

@@ -2,12 +2,10 @@
 # target in //ci/prebuilt/BUILD to the underlying build recipe in
 # ci/build_container/build_recipes.
 TARGET_RECIPES = {
-    "ares": "cares",
     "benchmark": "benchmark",
     "event": "libevent",
     "tcmalloc_and_profiler": "gperftools",
     "luajit": "luajit",
-    "nghttp2": "nghttp2",
     "yaml_cpp": "yaml-cpp",
     "zlib": "zlib",
 }

ci/WORKSPACE

@@ -12,6 +12,9 @@ local_repository(
 envoy_dependencies(
     path = "@envoy//ci/prebuilt",
 )
+# TODO(htuch): Roll this into envoy_dependencies()
+load("@rules_foreign_cc//:workspace_definitions.bzl", "rules_foreign_cc_dependencies")
+rules_foreign_cc_dependencies()
 
 cc_configure()
 

ci/WORKSPACE.filter.example

@@ -11,6 +11,9 @@ load("//bazel:cc_configure.bzl", "cc_configure")
 envoy_dependencies(
     path = "@envoy//ci/prebuilt",
 )
+# TODO(htuch): Roll this into envoy_dependencies()
+load("@rules_foreign_cc//:workspace_definitions.bzl", "rules_foreign_cc_dependencies")
+rules_foreign_cc_dependencies()
 
 cc_configure()
 

ci/prebuilt/BUILD

@@ -7,16 +7,6 @@ config_setting(
     values = {"cpu": "x64_windows"},
 )
 
-cc_library(
-    name = "ares",
-    srcs = select({
-        ":windows_x86_64": ["thirdparty_build/lib/cares.lib"],
-        "//conditions:default": ["thirdparty_build/lib/libcares.a"],
-    }),
-    hdrs = glob(["thirdparty_build/include/ares*.h"]),
-    includes = ["thirdparty_build/include"],
-)
-
 cc_library(
     name = "benchmark",
     srcs = select({
@@ -49,16 +39,6 @@ cc_library(
     # the headers get included using -I vs. -isystem which then causes old-style-cast warnings.
 )
 
-cc_library(
-    name = "nghttp2",
-    srcs = select({
-        ":windows_x86_64": ["thirdparty_build/lib/nghttp2.lib"],
-        "//conditions:default": ["thirdparty_build/lib/libnghttp2.a"],
-    }),
-    hdrs = glob(["thirdparty_build/include/nghttp2/**/*.h"]),
-    includes = ["thirdparty_build/include"],
-)
-
 cc_library(
     name = "tcmalloc_and_profiler",
     srcs = ["thirdparty_build/lib/libtcmalloc_and_profiler.a"],