Auto-discover new WPT as they are added (#3329)

Author: npaun

build/wd_test.bzl

@@ -5,6 +5,7 @@ def wd_test(
         data = [],
         name = None,
         args = [],
+        ts_deps = [],
         **kwargs):
     """Rule to define tests that run `workerd test` with a particular config.
 
@@ -38,7 +39,7 @@ def wd_test(
             source_map = True,
             composite = True,
             declaration = True,
-            deps = ["//src/node:node@tsproject"],
+            deps = ["//src/node:node@tsproject"] + ts_deps,
         )
         data += [js_src.removesuffix(".ts") + ".js" for js_src in ts_srcs]
 

build/wpt_test.bzl

@@ -2,41 +2,121 @@
 # Licensed under the Apache 2.0 license found in the LICENSE file or at:
 #     https://opensource.org/licenses/Apache-2.0
 
-# The public entry point is a macro named wpt_test. It first invokes a private
-# rule named _wpt_test_gen to access the files in the wpt filegroup and
-# generate a corresponding wd-test file. It then invokes the wd_test macro
-# to set up the test.
-
 load("//:build/wd_test.bzl", "wd_test")
 
-def wpt_test(name, wpt_directory, test_js):
-    test_gen_rule = "{}@_wpt_test_gen".format(name)
-    _wpt_test_gen(
-        name = test_gen_rule,
+def wpt_test(name, wpt_directory, test_config):
+    """
+    Main entry point.
+    1. Generates a workerd test suite in JS. This contains the logic to run
+       each WPT test file, applying the relevant test config.
+    2. Generates a wd-test file for this test suite. This contains all of the
+       paths to modules needed to run the test: generated test suite, test config
+       file, WPT test scripts, associated JSON resources.
+    """
+
+    js_test_gen_rule = "{}@_wpt_js_test_gen".format(name)
+    test_config_as_js = test_config.removesuffix(".ts") + ".js"
+
+    _wpt_js_test_gen(
+        name = js_test_gen_rule,
         test_name = name,
         wpt_directory = wpt_directory,
-        test_js = test_js,
+        test_config = test_config_as_js,
+    )
+
+    wd_test_gen_rule = "{}@_wpt_wd_test_gen".format(name)
+    _wpt_wd_test_gen(
+        name = wd_test_gen_rule,
+        test_name = name,
+        wpt_directory = wpt_directory,
+        test_config = test_config_as_js,
+        test_js_generated = js_test_gen_rule,
     )
 
     wd_test(
         name = "{}".format(name),
-        src = test_gen_rule,
+        src = wd_test_gen_rule,
         args = ["--experimental"],
+        ts_deps = ["//src/wpt:wpt-test-harness"],
         data = [
             "//src/wpt:wpt-test-harness",
-            test_js,
+            test_config,
+            js_test_gen_rule,
             wpt_directory,
             "//src/workerd/io:trimmed-supported-compatibility-date.txt",
         ],
     )
 
-def _wpt_test_gen_impl(ctx):
+def _wpt_js_test_gen_impl(ctx):
+    """
+    Generates a workerd test suite in JS. This contains the logic to run
+    each WPT test file, applying the relevant test config.
+    """
+
+    src = ctx.actions.declare_file("{}-test.generated.js".format(ctx.attr.test_name))
+    ctx.actions.write(
+        output = src,
+        content = WPT_JS_TEST_TEMPLATE.format(
+            test_config = ctx.file.test_config.basename,
+            cases = generate_external_cases(ctx.attr.wpt_directory.files),
+        ),
+    )
+
+    return DefaultInfo(
+        files = depset([src]),
+    )
+
+def generate_external_cases(files):
+    """
+    Generate a workerd test case that runs each test file in the WPT module.
+    """
+
+    result = []
+
+    for file in files.to_list():
+        if file.extension == "js":
+            entry = """export const {} = run(config, '{}');""".format(test_case_name(file.basename), file.basename)
+            result.append(entry)
+
+    return "\n".join(result)
+
+def test_case_name(filename):
+    """
+    Converts a JS filename to a valid JS identifier for use as a test case name.
+    WPT files are named with the convention some-words-with-hyphens.some-suffix.js.
+    We would turn this into someWordsWithHyphensSomeSuffix.
+    """
+
+    words = (filename
+        .removesuffix(".js")
+        .removesuffix(".any")
+        .replace(".", "-")
+        .split("-"))
+
+    return words[0] + "".join([word.capitalize() for word in words[1:]])
+
+WPT_JS_TEST_TEMPLATE = """// This file is autogenerated by wpt_test.bzl
+// DO NOT EDIT.
+import {{ run }} from 'wpt:harness';
+import config from '{test_config}';
+
+{cases}
+"""
+
+def _wpt_wd_test_gen_impl(ctx):
+    """
+    Generates a wd-test file for this test suite. This contains all of the
+    paths to modules needed to run the test: generated test suite, test config
+    file, WPT test scripts, associated JSON resources.
+    """
+
     src = ctx.actions.declare_file("{}.wd-test".format(ctx.attr.test_name))
     ctx.actions.write(
         output = src,
-        content = WPT_TEST_TEMPLATE.format(
+        content = WPT_WD_TEST_TEMPLATE.format(
             test_name = ctx.attr.test_name,
-            test_js = wd_relative_path(ctx.file.test_js),
+            test_config = ctx.file.test_config.basename,
+            test_js_generated = wd_relative_path(ctx.file.test_js_generated),
             modules = generate_external_modules(ctx.attr.wpt_directory.files),
         ),
     )
@@ -45,14 +125,15 @@ def _wpt_test_gen_impl(ctx):
         files = depset([src]),
     )
 
-WPT_TEST_TEMPLATE = """
+WPT_WD_TEST_TEMPLATE = """
 using Workerd = import "/workerd/workerd.capnp";
 const unitTests :Workerd.Config = (
   services = [
     ( name = "{test_name}",
       worker = (
         modules = [
-          (name = "worker", esModule = embed "{test_js}"),
+          (name = "worker", esModule = embed "{test_js_generated}"),
+          (name = "{test_config}", esModule = embed "{test_config}"),
           (name = "wpt:harness", esModule = embed "../../../../../workerd/src/wpt/harness.js"),
           {modules}
         ],
@@ -75,6 +156,7 @@ def wd_relative_path(file):
     Returns a relative path which can be referenced in the .wd-test file.
     This is four directories up from the bazel short_path
     """
+
     return "../" * 4 + file.short_path
 
 def generate_external_modules(files):
@@ -85,6 +167,7 @@ def generate_external_modules(files):
     Example for a JSON file:
         (name = "resources/urltestdata.json", json = embed "../../../../../wpt/url/resources/urltestdata.json"),
     """
+
     result = []
 
     for file in files.to_list():
@@ -102,14 +185,28 @@ def generate_external_modules(files):
 
     return ",\n".join(result)
 
-_wpt_test_gen = rule(
-    implementation = _wpt_test_gen_impl,
+_wpt_wd_test_gen = rule(
+    implementation = _wpt_wd_test_gen_impl,
+    attrs = {
+        # A string to use as the test name. Used in the wd-test filename and the worker's name
+        "test_name": attr.string(),
+        # A file group representing a directory of wpt tests. All files in the group will be embedded.
+        "wpt_directory": attr.label(),
+        # A JS file containing the test configuration.
+        "test_config": attr.label(allow_single_file = True),
+        # An auto-generated JS file containing the test logic.
+        "test_js_generated": attr.label(allow_single_file = True),
+    },
+)
+
+_wpt_js_test_gen = rule(
+    implementation = _wpt_js_test_gen_impl,
     attrs = {
         # A string to use as the test name. Used in the wd-test filename and the worker's name
         "test_name": attr.string(),
         # A file group representing a directory of wpt tests. All files in the group will be embedded.
         "wpt_directory": attr.label(),
-        # A JS file containing the actual test logic.
-        "test_js": attr.label(allow_single_file = True),
+        # A JS file containing the test configuration.
+        "test_config": attr.label(allow_single_file = True),
     },
 )

src/workerd/api/wpt/BUILD.bazel

@@ -2,10 +2,34 @@
 # Licensed under the Apache 2.0 license found in the LICENSE file or at:
 #     https://opensource.org/licenses/Apache-2.0
 
+load("@npm//:eslint/package_json.bzl", eslint_bin = "bin")
 load("//:build/wpt_test.bzl", "wpt_test")
 
+srcs = glob(["*-test.ts"])
+
 [wpt_test(
-    name = file.replace("-test.js", ""),
-    test_js = file,
-    wpt_directory = "@wpt//:{}".format(file.replace("-test.js", "")),
-) for file in glob(["*-test.js"])]
+    name = file.replace("-test.ts", ""),
+    test_config = file,
+    wpt_directory = "@wpt//:{}".format(file.replace("-test.ts", "")),
+) for file in srcs]
+
+eslint_bin.eslint_test(
+    name = "all@eslint",
+    size = "large",
+    args = [
+        "--config $(location {})".format("eslint.config.mjs"),
+        "--parser-options project:$(location {})".format("tsconfig.json"),
+        "-f stylish",
+        "--report-unused-disable-directives",
+    ] + ["$(location " + src + ")" for src in srcs],
+    data = srcs + [
+        "eslint.config.mjs",
+        "tsconfig.json",
+        "//tools:base-eslint",
+    ],
+    tags = ["lint"],
+    target_compatible_with = select({
+        "@platforms//os:windows": ["@platforms//:incompatible"],
+        "//conditions:default": [],
+    }),
+)

src/workerd/api/wpt/eslint.config.mjs

@@ -0,0 +1,11 @@
+import { baseConfig } from '../../../../tools/base.eslint.config.mjs';
+
+export default [
+  ...baseConfig({ tsconfigRootDir: import.meta.dirname }),
+  {
+    files: ['src/workerd/api/wpt/*-test.js'],
+    rules: {
+      'sort-keys': 'error',
+    },
+  },
+];

src/workerd/api/wpt/tsconfig.json

@@ -0,0 +1,31 @@
+{
+  "compilerOptions": {
+    "target": "ESNext",
+    "module": "ESNext",
+    "lib": ["ESNext", "dom"],
+    "alwaysStrict": true,
+    "strict": true,
+    "allowJs": true,
+    "allowUnreachableCode": false,
+    "allowUnusedLabels": false,
+    "exactOptionalPropertyTypes": true,
+    "noFallthroughCasesInSwitch": true,
+    "noImplicitOverride": true,
+    "noImplicitReturns": true,
+    "noPropertyAccessFromIndexSignature": false,
+    "noUncheckedIndexedAccess": true,
+    "noUnusedLocals": true,
+    "noUnusedParameters": true,
+    "strictNullChecks": true,
+    "esModuleInterop": true,
+    "moduleResolution": "node",
+    "declaration": true,
+    "composite": true,
+    "sourceMap": true,
+    "paths": {
+      "wpt:*": ["../../../wpt/*"]
+    }
+  },
+  "include": ["**/*.ts"],
+  "exclude": []
+}