Merge pull request #416 from zerobig/fix#415

Не удаляются тестовые данные расширений

exts/yaxunit/src/CommonModules/ЮТМетодыСлужебныйВызовСервера/Module.bsl

@@ -24,4 +24,68 @@
 
 КонецФункции
 
+Функция СсылочныеТипыДобавляемыеРасширениями() Экспорт
+
+	СсылочныеТипы = Новый Массив;
+	ТипыОбъектовМетаданныхСсылочногоТипа = ТипыОбъектовМетаданныхСсылочногоТипа();
+
+	УстановитьПривилегированныйРежим(Истина);
+	РасширенияСеанса = РасширенияКонфигурации.Получить(, ИсточникРасширенийКонфигурации.СеансАктивные);
+
+	Для Каждого Расширение Из РасширенияСеанса Цикл
+
+		Если НЕ Расширение.ИзменяетСтруктуруДанных() Тогда
+			Продолжить;
+		КонецЕсли;
+
+		ОМДРасширения = Новый ОбъектМетаданныхКонфигурация(Расширение.ПолучитьДанные());
+
+		Для Каждого ТипОМД Из ТипыОбъектовМетаданныхСсылочногоТипа Цикл
+			ДополнитьТипы(СсылочныеТипы, ТипОМД, ОМДРасширения);
+		КонецЦикла;
+
+	КонецЦикла;
+
+	Возврат СсылочныеТипы;
+
+КонецФункции
+
+#КонецОбласти
+
+#Область СлужебныеПроцедурыИФункции
+
+Процедура ДополнитьТипы(СсылочныеТипы, ТипОМД, ОМДРасширения)
+
+	ПринадлежностьОбъекта = Метаданные.СвойстваОбъектов.ПринадлежностьОбъекта.Собственный; 
+
+	Для Каждого ОМД Из ОМДРасширения[ТипОМД] Цикл
+
+		Если ОМД.ПринадлежностьОбъекта <> ПринадлежностьОбъекта Тогда
+			Продолжить;
+		КонецЕсли;
+
+		ИмяПустойСсылкиТипа = ОМД.ПолноеИмя() + ".ПустаяСсылка";
+		СсылкаДляОпределенияТипа = ПредопределенноеЗначение(ИмяПустойСсылкиТипа);
+		СсылочныеТипы.Добавить(ТипЗнч(СсылкаДляОпределенияТипа));
+
+	КонецЦикла;
+
+КонецПроцедуры
+
+Функция ТипыОбъектовМетаданныхСсылочногоТипа()
+
+	ТипыОбъектовМетаданныхСсылочногоТипа = Новый Массив;
+	ТипыОбъектовМетаданныхСсылочногоТипа.Добавить("Справочники");
+	ТипыОбъектовМетаданныхСсылочногоТипа.Добавить("Документы");
+	ТипыОбъектовМетаданныхСсылочногоТипа.Добавить("БизнесПроцессы");
+	ТипыОбъектовМетаданныхСсылочногоТипа.Добавить("Задачи");
+	ТипыОбъектовМетаданныхСсылочногоТипа.Добавить("ПланыСчетов");
+	ТипыОбъектовМетаданныхСсылочногоТипа.Добавить("ПланыОбмена");
+	ТипыОбъектовМетаданныхСсылочногоТипа.Добавить("ПланыВидовХарактеристик");
+	ТипыОбъектовМетаданныхСсылочногоТипа.Добавить("ПланыВидовРасчета");
+
+	Возврат ТипыОбъектовМетаданныхСсылочногоТипа;
+
+КонецФункции
+
 #КонецОбласти

exts/yaxunit/src/CommonModules/ЮТТипыДанныхСлужебный/Module.bsl

@@ -155,7 +155,15 @@
 		"<TypeDescription xmlns=""http://v8.1c.ru/8.1/data/core"">
 		|      <TypeSet xmlns:cc=""http://v8.1c.ru/8.1/data/enterprise/current-config"">cc:AnyRef</TypeSet>
 		|</TypeDescription>");
-		Возврат СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
+		ОписаниеТипаЛюбаяСсылка = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
+
+		СсылочныеТипыРасширений = ЮТМетодыСлужебныйВызовСервера.СсылочныеТипыДобавляемыеРасширениями();
+
+		Если СсылочныеТипыРасширений.Количество() <> 0 Тогда
+			ОписаниеТипаЛюбаяСсылка = Новый ОписаниеТипов(ОписаниеТипаЛюбаяСсылка, СсылочныеТипыРасширений);
+		КонецЕсли;
+
+		Возврат ОписаниеТипаЛюбаяСсылка;
 #КонецЕсли
 	КонецЕсли;