pythonPackages.arch: init at 4.11

pkgs/development/libraries/libuv/default.nix

@@ -19,6 +19,7 @@ stdenv.mkDerivation rec {
       "threadpool_multiple_event_loops" # times out on slow machines
       "get_passwd" # passed on NixOS but failed on other Linuxes
       "tcp_writealot" # times out sometimes
+      "ipc_closed_handle" # times out
     ] ++ stdenv.lib.optionals stdenv.isDarwin [
         # Sometimes: timeout (no output), failed uv_listen. Someone
         # should report these failures to libuv team. There tests should

pkgs/development/python-modules/arch/default.nix

@@ -0,0 +1,44 @@
+{ lib
+, buildPythonPackage
+, fetchPypi
+, cython
+, matplotlib
+, numpy
+, property-cached
+, python
+, scipy
+, statsmodels
+, pandas
+, pytest 
+}:
+
+buildPythonPackage rec {
+  pname = "arch";
+  version = "4.11";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "a3d5cd9086e7c44638286fbe46a4688a3668ab79400a1712c3ce43490be0c3bb";
+  };
+
+  nativeBuildInputs = [ cython ];
+  propagatedBuildInputs = [ numpy property-cached python scipy statsmodels ];
+
+  preBuild = ''
+    ${python.interpreter} setup.py build_ext -i
+  '';
+
+  checkInputs = [ matplotlib pandas pytest ];
+
+  # scipy.optimize has been changed in 1.4 which broke test_convergence_warning
+  checkPhase = ''
+    pytest arch/tests -k 'not test_convergence_warning'
+  '';
+
+  meta = with lib; {
+    description = "Autoregressive Conditional Heteroskedasticity";
+    homepage = "https://github.com/bashtage/arch";
+    license = licenses.ncsa;
+    maintainers = [ maintainers.arnoldfarkas ];
+  };
+}

pkgs/development/python-modules/property-cached/default.nix

@@ -0,0 +1,28 @@
+{ lib, buildPythonPackage, fetchPypi, setuptools, freezegun }:
+
+buildPythonPackage rec {
+  pname = "property-cached";
+  version = "1.6.3";
+
+  src = fetchPypi {
+    inherit pname version;
+    extension = "zip";
+    sha256 = "614b6972e279d981b7bccabd0b1ce4601c1739a6eb9905fd79a9c485fb20a1e0";
+  };
+
+  propagatedBuildInputs = [ setuptools ];
+
+  checkInputs = [ freezegun ];
+
+  # freezegun 3.11 broke tests.test_cached_property.TestCachedPropertyWithTTL.test_threads_ttl_expiry
+  patchPhase = ''
+    substituteInPlace tests/test_cached_property.py --replace '2 * num_threads' 'num_threads + 1'
+  '';
+
+  meta = with lib; {
+    description = "Decorator for caching properties in classes";
+    homepage = "https://github.com/althonos/property-cached/";
+    license = licenses.bsdOriginal;
+    maintainers = [ maintainers.arnoldfarkas ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -183,6 +183,8 @@ in {
 
   arrayqueues = callPackage ../development/python-modules/arrayqueues { };
 
+  arch = callPackage ../development/python-modules/arch { };
+
   aresponses = callPackage ../development/python-modules/aresponses { };
 
   argon2_cffi = callPackage ../development/python-modules/argon2_cffi { };
@@ -4745,6 +4747,8 @@ in {
 
   prettytable = callPackage ../development/python-modules/prettytable { };
 
+  property-cached = callPackage ../development/python-modules/property-cached { };
+
   property-manager = callPackage ../development/python-modules/property-manager { };
 
   prompt_toolkit = let