libglycin-gtk4: init (split out of libglycin)

doc/hooks/index.md

@@ -22,6 +22,7 @@ haredo.section.md
 installShellFiles.section.md
 julec.section.md
 just.section.md
+libglycin.section.md
 libiconv.section.md
 libxml2.section.md
 meson.section.md

doc/hooks/libglycin.section.md

@@ -0,0 +1,47 @@
+# libglycin {#libglycin-hooks}
+
+[Glycin](https://gitlab.gnome.org/GNOME/glycin) is a library for sandboxed and extendable image loading.
+
+[]{#libglycin-setup-hook} For most applications using it, individual image formats are loaded through binaries provided by `glycin-loaders`. The paths of these loaders must be injected into the environment, e.g. using [`wrapGAppsHook`](#ssec-gnome-hooks). `libglycin.setupHook` will do that.
+
+[]{#libglycin-patch-vendor-hook} Additionally, for Rust projects `glycin` Rust crate itself requires a patch to become self-contained. `libglycin.patchVendorHook` will do that. This is not needed for projects using the ELF library from `libglycin` package.
+
+## Example code snippet {#libglycin-hooks-example-code-snippet}
+
+```nix
+{
+  lib,
+  rustPlatform,
+  libglycin,
+  glycin-loaders,
+  wrapGAppsHook4,
+}:
+
+rustPlatform.buildRustPackage {
+  # ...
+
+  cargoHash = "...";
+
+  nativeBuildInputs = [
+    wrapGAppsHook4
+    libglycin.patchVendorHook
+  ];
+
+  buildInputs = [
+    libglycin.setupHook
+    glycin-loaders
+  ];
+
+  # ...
+}
+```
+
+## Variables controlling glycin-loaders {#libglycin-hook-variables-controlling}
+
+### `glycinCargoDepsPath` {#glycin-cargo-deps-path}
+
+Path to a directory containing the `glycin` crate to patch. Defaults to the crate directory created by `cargoSetupHook`, or `./vendor/`.
+
+### `dontWrapGlycinLoaders` {#glycin-dont-wrap}
+
+Disable adding the Glycin loaders path `XDG_DATA_DIRS` with `wrapGAppsHook`.

doc/languages-frameworks/gnome.section.md

@@ -129,6 +129,8 @@ The hooks do the following:
 
 - []{#ssec-gnome-hooks-gst-grl-plugins} Setup hooks of `gst_all_1.gstreamer` and `grilo` will populate the `GST_PLUGIN_SYSTEM_PATH_1_0` and `GRL_PLUGIN_PATH` variables, respectively, which will then be added to the wrapper by `wrapGApps*` hook.
 
+- []{#ssec-gnome-hooks-libglycin} `libglycin`'s [setup hook](#libglycin-setup-hook) will populate `XDG_DATA_DIRS` with the path to the loaders.
+
 You can also pass additional arguments to `makeWrapper` using `gappsWrapperArgs` in `preFixup` hook:
 
 ```nix

doc/redirects.json

@@ -2468,6 +2468,27 @@
   "setup-hook-gdk-pixbuf": [
     "index.html#setup-hook-gdk-pixbuf"
   ],
+  "libglycin-hooks": [
+    "index.html#libglycin-hooks"
+  ],
+  "libglycin-setup-hook": [
+    "index.html#libglycin-setup-hook"
+  ],
+  "libglycin-patch-vendor-hook": [
+    "index.html#libglycin-patch-vendor-hook"
+  ],
+  "libglycin-hooks-example-code-snippet": [
+    "index.html#libglycin-hooks-example-code-snippet"
+  ],
+  "libglycin-hook-variables-controlling": [
+    "index.html#libglycin-hook-variables-controlling"
+  ],
+  "glycin-cargo-deps-path": [
+    "index.html#glycin-cargo-deps-path"
+  ],
+  "glycin-dont-wrap": [
+    "index.html#glycin-dont-wrap"
+  ],
   "ghc": [
     "index.html#ghc"
   ],
@@ -3158,6 +3179,9 @@
   "ssec-gnome-hooks-gst-grl-plugins": [
     "index.html#ssec-gnome-hooks-gst-grl-plugins"
   ],
+  "ssec-gnome-hooks-libglycin": [
+    "index.html#ssec-gnome-hooks-libglycin"
+  ],
   "ssec-gnome-updating": [
     "index.html#ssec-gnome-updating"
   ],

pkgs/by-name/au/authenticator/package.nix

@@ -21,7 +21,6 @@
   sqlite,
   wayland,
   zbar,
-  glycin-loaders,
   nix-update-script,
 }:
 
@@ -78,8 +77,6 @@ stdenv.mkDerivation (finalAttrs: {
     gappsWrapperArgs+=(
       # vp8enc preset
       --prefix GST_PRESET_PATH : "${gst_all_1.gst-plugins-good}/share/gstreamer-1.0/presets"
-      # See https://gitlab.gnome.org/sophie-h/glycin/-/blob/0.1.beta.2/glycin/src/config.rs#L44
-      --prefix XDG_DATA_DIRS : "${glycin-loaders}/share"
     )
   '';
 

pkgs/by-name/ba/bazaar/package.nix

@@ -9,7 +9,6 @@
   pkg-config,
   wrapGAppsHook4,
   appstream,
-  bubblewrap,
   flatpak,
   glib-networking,
   glycin-loaders,
@@ -18,6 +17,7 @@
   libadwaita,
   libdex,
   libglycin,
+  libglycin-gtk4,
   libsoup_3,
   libxmlb,
   libyaml,
@@ -56,6 +56,8 @@ stdenv.mkDerivation (finalAttrs: {
     libadwaita
     libdex
     libglycin
+    libglycin-gtk4
+    glycin-loaders
     libsoup_3
     libxmlb
     libyaml
@@ -64,15 +66,7 @@ stdenv.mkDerivation (finalAttrs: {
     libsecret
   ];
 
-  preFixup = ''
-    gappsWrapperArgs+=(
-      --prefix PATH : "$out/bin:${lib.makeBinPath [ bubblewrap ]}"
-      --prefix XDG_DATA_DIRS : "${glycin-loaders}/share"
-    )
-  '';
-
   passthru = {
-    inherit (libglycin) glycinPathsPatch;
     updateScript = nix-update-script { };
   };
 

pkgs/by-name/co/constrict/package.nix

@@ -11,6 +11,7 @@
   desktop-file-utils,
   libadwaita,
   libglycin,
+  libglycin-gtk4,
   libva-utils,
   ffmpeg,
   gst-thumbnailers,
@@ -42,6 +43,8 @@ python3Packages.buildPythonApplication (finalAttrs: {
   buildInputs = [
     libadwaita
     libglycin
+    libglycin-gtk4
+    glycin-loaders
   ];
 
   dependencies = [
@@ -60,7 +63,6 @@ python3Packages.buildPythonApplication (finalAttrs: {
   preFixup = ''
     makeWrapperArgs+=(
       ''${gappsWrapperArgs[@]}
-      --prefix XDG_DATA_DIRS : "${glycin-loaders}/share"
       --prefix PATH : ${lib.makeBinPath finalAttrs.runtimeDeps}
     )
   '';

pkgs/by-name/fr/fractal/package.nix

@@ -23,10 +23,10 @@
   libshumate,
   wrapGAppsHook4,
   blueprint-compiler,
-  bubblewrap,
   sqlite,
   xdg-desktop-portal,
   libseccomp,
+  libglycin,
   glycin-loaders,
   libwebp,
 }:
@@ -64,6 +64,7 @@ stdenv.mkDerivation (finalAttrs: {
     glib
     grass-sass
     gtk4
+    libglycin.patchVendorHook
     meson
     ninja
     pkg-config
@@ -79,6 +80,8 @@ stdenv.mkDerivation (finalAttrs: {
 
   buildInputs = [
     glib
+    libglycin.setupHook
+    glycin-loaders
     gtk4
     gtksourceview5
     lcms2
@@ -99,13 +102,6 @@ stdenv.mkDerivation (finalAttrs: {
     gst-plugins-rs
   ]);
 
-  preFixup = ''
-    gappsWrapperArgs+=(
-      --prefix XDG_DATA_DIRS : "${glycin-loaders}/share"
-      --prefix PATH : "${lib.makeBinPath [ bubblewrap ]}"
-    )
-  '';
-
   env.CARGO_BUILD_TARGET = stdenv.hostPlatform.rust.rustcTargetSpec;
 
   passthru = {

pkgs/by-name/gl/glycin-loaders/package.nix

@@ -1,13 +1,12 @@
 {
   stdenv,
   lib,
-  fetchurl,
   cairo,
   cargo,
   gettext,
-  git,
-  gnome,
+  glib,
   gtk4,
+  libglycin,
   lcms2,
   libheif,
   libjxl,
@@ -17,95 +16,86 @@
   meson,
   ninja,
   pkg-config,
+  python3,
+  shared-mime-info,
   rustc,
   rustPlatform,
-  common-updater-scripts,
-  _experimental-update-script-combinators,
 }:
 
 stdenv.mkDerivation (finalAttrs: {
   pname = "glycin-loaders";
-  version = "2.0.7";
 
-  src = fetchurl {
-    url = "mirror://gnome/sources/glycin/${lib.versions.majorMinor finalAttrs.version}/glycin-${finalAttrs.version}.tar.xz";
-    hash = "sha256-xBasKbbT7NxnuQwVU3uhKTzrevlvoQHK5nt9HTflCrA=";
-  };
-
-  cargoDeps = rustPlatform.fetchCargoVendor {
-    inherit (finalAttrs) src;
-    name = "glycin-loaders-deps-${finalAttrs.version}";
-    hash = "sha256-UVVVjMt4vWkLob0H/MxIaW6rkBSFImu+5dezaCnc3Q8=";
-    dontConfigure = true;
-  };
+  inherit (libglycin) version src cargoDeps;
 
   nativeBuildInputs = [
     cargo
     gettext # for msgfmt
-    git
     meson
     ninja
     pkg-config
     rustc
     rustPlatform.cargoSetupHook
+  ]
+  ++ lib.optionals finalAttrs.finalPackage.doCheck [
+    python3
+    # Tests use Rust glycin library.
+    libglycin.patchVendorHook
   ];
 
   buildInputs = [
-    gtk4 # for GdkTexture
     cairo
-    lcms2
     libheif
     libxml2 # for librsvg crate
     librsvg
     libseccomp
     libjxl
   ];
 
+  # Tests in passthru.tests to avoid dependency cycles.
+  checkInputs = [
+    glib
+    gtk4
+    lcms2
+  ];
+
   mesonFlags = [
     "-Dglycin-loaders=true"
     "-Dglycin-thumbnailer=false"
     "-Dlibglycin=false"
     "-Dlibglycin-gtk4=false"
     "-Dvapi=false"
+    (lib.mesonBool "tests" finalAttrs.finalPackage.doCheck)
   ];
 
   strictDeps = true;
 
   postPatch = ''
     substituteInPlace glycin-loaders/meson.build \
       --replace-fail "cargo_target_dir / rust_target / loader," "cargo_target_dir / '${stdenv.hostPlatform.rust.cargoShortTarget}' / rust_target / loader,"
+  ''
+  + lib.optionalString finalAttrs.finalPackage.doCheck ''
+    chmod +x build-aux/setup-integration-test.py
+
+    patchShebangs \
+      build-aux/setup-integration-test.py
+  '';
+
+  preCheck = lib.optionalString finalAttrs.finalPackage.doCheck ''
+    # Fix test files being considered application/octet-stream
+    export XDG_DATA_DIRS=${shared-mime-info}/share:$XDG_DATA_DIRS
+
+    # fonts test will not be able to create cache without this
+    export XDG_CACHE_HOME=$(mktemp -d)
   '';
 
   env.CARGO_BUILD_TARGET = stdenv.hostPlatform.rust.rustcTargetSpec;
 
   passthru = {
-    updateScript =
-      let
-        updateSource = gnome.updateScript {
-          attrPath = "glycin-loaders";
-          packageName = "glycin";
-        };
-        updateLockfile = {
-          command = [
-            "sh"
-            "-c"
-            ''
-              PATH=${
-                lib.makeBinPath [
-                  common-updater-scripts
-                ]
-              }
-              update-source-version glycin-loaders --ignore-same-version --source-key=cargoDeps.vendorStaging > /dev/null
-            ''
-          ];
-          # Experimental feature: do not copy!
-          supportedFeatures = [ "silent" ];
-        };
-      in
-      _experimental-update-script-combinators.sequence [
-        updateSource
-        updateLockfile
-      ];
+    tests = {
+      withTests = finalAttrs.finalPackage.overrideAttrs {
+        doCheck = true;
+      };
+    };
   };
 
   meta = {

pkgs/by-name/gs/gst-thumbnailers/package.nix

@@ -49,14 +49,9 @@ stdenv.mkDerivation (finalAttrs: {
     gst_all_1.gst-plugins-ugly
     fontconfig
     libglycin
+    glycin-loaders
   ];
 
-  preFixup = ''
-    gappsWrapperArgs+=(
-      --prefix XDG_DATA_DIRS : "${glycin-loaders}/share"
-    )
-  '';
-
   meta = {
     description = "Generate thumbnailer for video and audio files";
     homepage = "https://gitlab.gnome.org/GNOME/gst-thumbnailers";