zeal: migrate to by-name

pkgs/data/documentation/zeal/default.nix → pkgs/by-name/ze/zeal/make-zeal.nix

@@ -1,54 +1,62 @@
-{ lib
-, stdenv
-, fetchFromGitHub
-, cmake
-, extra-cmake-modules
-, pkg-config
-, httplib
-, qtbase
-, qtimageformats
-, qtwebengine
-, qtx11extras
-, libarchive
-, libXdmcp
-, libpthreadstubs
-, wrapQtAppsHook
-, xcbutilkeysyms
+{
+  pname,
+  version,
+  hash,
+  flavor,
 }:
 
-let
-  isQt5 = lib.versions.major qtbase.version == "5";
+{
+  lib,
+  cmake,
+  extra-cmake-modules,
+  fetchFromGitHub,
+  httplib,
+  libXdmcp,
+  libarchive,
+  libpthreadstubs,
+  pkg-config,
+  qt5,
+  qt6,
+  stdenv,
+  xcbutilkeysyms,
+}:
 
+let
+  qt =
+    if flavor == "qt5" then
+      qt5
+    else if flavor == "qt6" then
+      qt6
+    else
+      throw "unknown flavor ${flavor}";
 in
-stdenv.mkDerivation (finalAttrs: {
-  pname = "zeal";
-  version = "0.7.2";
+stdenv.mkDerivation {
+  inherit pname version;
 
   src = fetchFromGitHub {
     owner = "zealdocs";
     repo = "zeal";
-    rev = "v${finalAttrs.version}";
-    hash = "sha256-9tlo7+namWNWrWVQNqaOvtK4NQIdb0p8qvFrrbUamOo=";
+    rev = "v${version}";
+    inherit hash;
   };
 
   nativeBuildInputs = [
     cmake
     extra-cmake-modules
     pkg-config
-    wrapQtAppsHook
+    qt.wrapQtAppsHook
   ];
 
   buildInputs = [
     httplib
     libXdmcp
     libarchive
     libpthreadstubs
-    qtbase
-    qtimageformats
-    qtwebengine
+    qt.qtbase
+    qt.qtimageformats
+    qt.qtwebengine
     xcbutilkeysyms
-  ]
-  ++ lib.optionals isQt5 [ qtx11extras ];
+  ] ++ lib.optionals (flavor == "qt5") [ qt.qtx11extras ];
 
   cmakeFlags = [
     (lib.cmakeBool "ZEAL_RELEASE_BUILD" true)
@@ -61,10 +69,13 @@ stdenv.mkDerivation (finalAttrs: {
       app), available for Linux and Windows.
     '';
     homepage = "https://zealdocs.org/";
-    changelog = "https://github.com/zealdocs/zeal/releases/tag/v${finalAttrs.version}";
+    changelog = "https://github.com/zealdocs/zeal/releases/tag/v${version}";
     license = lib.licenses.gpl3Plus;
-    maintainers = with lib.maintainers; [ peterhoeg AndersonTorres ];
+    maintainers = with lib.maintainers; [
+      peterhoeg
+      AndersonTorres
+    ];
     mainProgram = "zeal";
-    inherit (qtbase.meta) platforms;
+    inherit (qt.qtbase.meta) platforms;
   };
-})
+}

pkgs/by-name/ze/zeal/package.nix

@@ -0,0 +1,72 @@
+args@{
+  lib,
+  cmake,
+  extra-cmake-modules,
+  fetchFromGitHub,
+  httplib,
+  libXdmcp,
+  libarchive,
+  libpthreadstubs,
+  pkg-config,
+  qt5,
+  qt6,
+  stdenv,
+  xcbutilkeysyms,
+}:
+let
+  zealData = {
+    pname = "zeal";
+    version = "0.7.2";
+    hash = "sha256-9tlo7+namWNWrWVQNqaOvtK4NQIdb0p8qvFrrbUamOo=";
+  };
+
+  mkZeal =
+    {
+      pname,
+      version,
+      hash,
+      flavor,
+    }:
+    args:
+    import ./make-zeal.nix {
+      inherit
+        pname
+        version
+        hash
+        flavor
+        ;
+    } args;
+
+  _qt5 =
+    mkZeal {
+      pname = zealData.pname + "-qt5";
+      inherit (zealData) version hash;
+      flavor = "qt5";
+    } args
+    // {
+      passthru = {
+        inherit flavors;
+      };
+    };
+
+  _qt6 =
+    mkZeal {
+      pname = zealData.pname + "-qt6";
+      inherit (zealData) version hash;
+      flavor = "qt6";
+    } args
+    // {
+      passthru = {
+        inherit flavors;
+      };
+    };
+
+  default = _qt5;
+
+  flavors = {
+    qt5 = _qt5;
+    qt6 = _qt6;
+    inherit default;
+  };
+in
+default

pkgs/top-level/all-packages.nix

@@ -13282,11 +13282,8 @@ with pkgs;
     inherit (plasma5Packages) breeze-icons;
   };
 
-  zeal-qt5 = libsForQt5.callPackage ../data/documentation/zeal { };
-  zeal = zeal-qt5;
-  zeal-qt6 = qt6Packages.callPackage ../data/documentation/zeal {
-    qtx11extras = null; # Because it does not exist in qt6
-  };
+  zeal-qt5 = zeal.passthru.flavors.qt5;
+  zeal-qt6 = zeal.passthru.flavors.qt6;
 
   ### APPLICATIONS / GIS