Sdl: dangerous migration

maintainers/team-list.nix

@@ -931,6 +931,12 @@ with lib.maintainers; {
     shortName = "SageMath";
   };
 
+  sdl = {
+    members = [ ];
+    scope = "Maintain SDL libraries.";
+    shortName = "SDL";
+  };
+
   sphinx = {
     members = [ ];
     scope = "Maintain Sphinx related packages.";

pkgs/by-name/sd/SDL2_Pango/package.nix

@@ -1,48 +1,50 @@
-{ lib
-, stdenv
-, fetchFromGitHub
-, autoreconfHook
-, pkg-config
-, freetype
-, pango
-, SDL2
-, darwin
+{
+  lib,
+  SDL2,
+  autoreconfHook,
+  darwin,
+  fetchFromGitHub,
+  freetype,
+  pango,
+  pkg-config,
+  stdenv,
 }:
 
-stdenv.mkDerivation rec {
+stdenv.mkDerivation (finalAttrs: {
   pname = "sdl2-pango";
   version = "2.1.5";
 
   src = fetchFromGitHub {
     owner = "markuskimius";
     repo = "SDL2_Pango";
-    rev = "v${version}";
+    rev = "v${finalAttrs.version}";
     hash = "sha256-8SL5ylxi87TuKreC8m2kxlLr8rcmwYYvwkp4vQZ9dkc=";
   };
 
-  outputs = [ "out" "dev" ];
-
-  strictDeps = true;
-
   nativeBuildInputs = [
+    SDL2
     autoreconfHook
     pkg-config
-    SDL2
   ];
 
   buildInputs = [
+    SDL2
     freetype
     pango
-    SDL2
   ] ++ lib.optionals stdenv.isDarwin [
     darwin.libobjc
   ];
 
-  meta = with lib; {
-    description = "A library for graphically rendering internationalized and tagged text in SDL2 using TrueType fonts";
+  outputs = [ "out" "dev" ];
+
+  strictDeps = true;
+
+  meta = {
     homepage = "https://github.com/markuskimius/SDL2_Pango";
-    license = licenses.lgpl21Plus;
-    maintainers = with maintainers; [ rardiol ];
-    platforms = platforms.all;
+    description = "A library for graphically rendering internationalized and tagged text in SDL2 using TrueType fonts";
+    license = lib.licenses.lgpl21Plus;
+    maintainers = lib.teams.sdl.members
+                  ++ (with lib.maintainers; [ ]);
+    inherit (SDL2.meta) platforms;
   };
-}
+})

pkgs/by-name/sd/SDL2_gfx/package.nix

@@ -0,0 +1,75 @@
+{ lib,
+  SDL2,
+  darwin,
+  fetchurl,
+  pkg-config,
+  stdenv,
+  testers,
+  # Boolean flags
+  enableMmx ? stdenv.hostPlatform.isx86,
+  enableSdltest ? (!stdenv.isDarwin),
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "SDL2_gfx";
+  version = "1.0.4";
+
+  src = fetchurl {
+    url = "http://www.ferzkopp.net/Software/SDL2_gfx/SDL2_gfx-${finalAttrs.version}.tar.gz";
+    hash = "sha256-Y+DgGt3tyd8vhbk6JI8G6KBK/6AUqDXC6jS/405XYmI=";
+  };
+
+  nativeBuildInputs = [
+    SDL2
+    pkg-config
+  ];
+
+  buildInputs = [
+    SDL2
+  ]
+  ++ lib.optionals stdenv.isDarwin [
+    darwin.libobjc
+  ];
+
+  outputs = [ "out" "dev" ];
+
+  configureFlags = [
+    (lib.enableFeature enableMmx "mmx")
+    (lib.enableFeature enableSdltest "sdltest")
+  ];
+
+  strictDeps = true;
+
+  passthru = {
+    tests.pkg-config = testers.hasPkgConfigModules {
+      package = finalAttrs.finalPackage;
+    };
+  };
+
+  meta = {
+    homepage = "http://www.ferzkopp.net/wordpress/2016/01/02/sdl_gfx-sdl2_gfx/";
+    description = "SDL graphics drawing primitives and support functions";
+    longDescription = ''
+      The SDL_gfx library evolved out of the SDL_gfxPrimitives code which
+      provided basic drawing routines such as lines, circles or polygons and
+      SDL_rotozoom which implemented a interpolating rotozoomer for SDL
+      surfaces.
+
+      The current components of the SDL_gfx library are:
+
+      - Graphic Primitives (SDL_gfxPrimitves.h)
+      - Rotozoomer (SDL_rotozoom.h)
+      - Framerate control (SDL_framerate.h)
+      - MMX image filters (SDL_imageFilter.h)
+      - Custom Blit functions (SDL_gfxBlitFunc.h)
+
+      The library is backwards compatible to the above mentioned code. Its is
+      written in plain C and can be used in C++ code.
+    '';
+    license = lib.licenses.zlib;
+    maintainers = lib.teams.sdl.members
+                  ++ (with lib.maintainers; [ ]);
+    pkgConfigModules = [ "SDL2_gfx" ];
+    inherit (SDL2.meta) platforms;
+  };
+})

pkgs/by-name/sd/SDL2_mixer/package.nix

@@ -76,7 +76,8 @@ stdenv.mkDerivation (finalAttrs: {
     homepage = "https://github.com/libsdl-org/SDL_mixer";
     description = "SDL multi-channel audio mixer library";
     license = lib.licenses.zlib;
-    maintainers = with lib.maintainers; [ AndersonTorres ];
+    maintainers = lib.teams.sdl.members
+                  ++ (with lib.maintainers; [ AndersonTorres ]);
     platforms = lib.platforms.unix;
   };
 })

pkgs/by-name/sd/SDL2_net/package.nix

@@ -44,7 +44,8 @@ stdenv.mkDerivation (finalAttrs: {
     homepage = "https://github.com/libsdl-org/SDL_net";
     description = "SDL multiplatform networking library";
     license = lib.licenses.zlib;
-    maintainers = with lib.maintainers; [ AndersonTorres ];
+    maintainers = lib.teams.sdl.members
+                  ++ (with lib.maintainers; [ ]);
     inherit (SDL2.meta) platforms;
   };
 })

pkgs/development/libraries/SDL2_sound/default.nix → pkgs/by-name/sd/SDL2_sound/package.nix

@@ -8,10 +8,15 @@
 , libmikmod
 , libvorbis
 , timidity
-, AudioToolbox
-, CoreAudio
+, darwin
 }:
 
+let
+  inherit (darwin.apple_sdk.frameworks)
+    AudioToolbox
+    CoreAudio
+  ;
+in
 stdenv.mkDerivation rec {
   pname = "SDL2_sound";
   version = "2.0.1";

pkgs/by-name/sd/SDL2_ttf/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  SDL2,
+  darwin,
+  fetchurl,
+  freetype,
+  harfbuzz,
+  libGL,
+  pkg-config,
+  stdenv,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "SDL2_ttf";
+  version = "2.22.0";
+
+  src = fetchurl {
+    url = "https://www.libsdl.org/projects/SDL_ttf/release/SDL2_ttf-${finalAttrs.version}.tar.gz";
+    sha256 = "sha256-1Iy9HOR1ueF4IGvzty1Wtm2E1E9krAWAMyg5YjTWdyM=";
+  };
+
+  nativeBuildInputs = [
+    SDL2
+    pkg-config
+  ];
+
+  buildInputs = [
+    SDL2
+    freetype
+    harfbuzz
+  ]
+  ++ lib.optionals (!stdenv.isDarwin) [
+    libGL
+  ]
+  ++ lib.optionalss stdenv.isDarwin [
+    darwin.libobjc
+  ];
+
+  configureFlags = [
+    (lib.enableFeature false "harfbuzz-builtin")
+    (lib.enableFeature (!stdenv.isDarwin) "sdltest")
+  ];
+
+  strictDeps = true;
+
+  passthru = {
+    tests.pkg-config = testers.hasPkgConfigModules {
+      package = finalAttrs.finalPackage;
+    };
+  };
+
+  meta = {
+    homepage = "https://github.com/libsdl-org/SDL_ttf";
+    description = "Support for TrueType (.ttf) font files with Simple Directmedia Layer";
+    license = lib.licenses.zlib;
+    maintainers = lib.teams.sdl.members
+                  ++ (with lib.maintainers; [ ]);
+    inherit (SDL2.meta) platforms;
+    pkgConfigModules = [ "SDL2_ttf" ];
+  };
+})

pkgs/by-name/sd/SDL_audiolib/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  SDL2,
+  cmake,
+  fetchFromGitHub,
+  pkg-config,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "SDL_audiolib";
+  version = "0-unstable-2022-04-17";
+
+  src = fetchFromGitHub {
+    owner = "realnc";
+    repo = "SDL_audiolib";
+    rev = "908214606387ef8e49aeacf89ce848fb36f694fc";
+    hash = "sha256-11KkwIhG1rX7yDFSj92NJRO9L2e7XZGq2gOJ54+sN/A=";
+  };
+
+  nativeBuildInputs = [
+    SDL2
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    SDL2
+  ];
+
+  strictDeps = true;
+
+  cmakeFlags = [
+    (lib.cmakeBool "USE_DEC_ADLMIDI" false)
+    (lib.cmakeBool "USE_DEC_BASSMIDI" false)
+    (lib.cmakeBool "USE_DEC_DRFLAC" false)
+    (lib.cmakeBool "USE_DEC_FLUIDSYNTH" false)
+    (lib.cmakeBool "USE_DEC_LIBOPUSFILE" false)
+    (lib.cmakeBool "USE_DEC_LIBVORBIS" false)
+    (lib.cmakeBool "USE_DEC_MODPLUG" false)
+    (lib.cmakeBool "USE_DEC_MPG123" false)
+    (lib.cmakeBool "USE_DEC_MUSEPACK" false)
+    (lib.cmakeBool "USE_DEC_OPENMPT" false)
+    (lib.cmakeBool "USE_DEC_SNDFILE" false)
+    (lib.cmakeBool "USE_DEC_WILDMIDI" false)
+    (lib.cmakeBool "USE_DEC_XMP" false)
+    (lib.cmakeBool "USE_RESAMP_SOXR" false)
+    (lib.cmakeBool "USE_RESAMP_SRC" false)
+  ];
+
+  meta = {
+    description = "Audio decoding, resampling and mixing library for SDL";
+    homepage = "https://github.com/realnc/SDL_audiolib";
+    license = lib.licenses.lgpl3Plus;
+    maintainers = lib.teams.sdl.members
+                  ++ (with lib.maintainers; [ ]);
+    inherit (SDL2.meta) platforms;
+  };
+})

pkgs/by-name/sd/SDL_gfx/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  SDL,
+  fetchurl,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "SDL_gfx";
+  version = "2.0.27";
+
+  src = fetchurl {
+    url = "https://www.ferzkopp.net/Software/SDL_gfx-2.0/SDL_gfx-${finalAttrs.version}.tar.gz";
+    hash = "sha256-37FaxfjOeklS3BLSrtl0dRjF5rM1wOMWNtI/k8Yw9Bk=";
+  };
+
+  # SDL_gfx.pc refers to sdl.pc and some SDL_gfx headers import SDL.h
+  propagatedBuildInputs = [ SDL ];
+  buildInputs = [ SDL ];
+
+  configureFlags = [
+    (lib.enableFeature false "mmx")
+    (lib.enableFeature (!stdenv.isDarwin) "sdltest")
+  ];
+
+  strictDeps = true;
+
+  meta = {
+    homepage = "https://sourceforge.net/projects/sdlgfx/";
+    description = "SDL graphics drawing primitives and support functions";
+    longDescription = ''
+      The SDL_gfx library evolved out of the SDL_gfxPrimitives code which
+      provided basic drawing routines such as lines, circles or polygons and
+      SDL_rotozoom which implemented a interpolating rotozoomer for SDL
+      surfaces.
+
+      The current components of the SDL_gfx library are:
+
+      - Graphic Primitives (SDL_gfxPrimitves.h)
+      - Rotozoomer (SDL_rotozoom.h)
+      - Framerate control (SDL_framerate.h)
+      - MMX image filters (SDL_imageFilter.h)
+      - Custom Blit functions (SDL_gfxBlitFunc.h)
+
+      The library is backwards compatible to the above mentioned code. Its is
+      written in plain C and can be used in C++ code.
+    '';
+    license = lib.licenses.zlib;
+    maintainers = lib.teams.sdl.members
+                  ++ (with lib.maintainers; [ ]);
+    inherit (SDL.meta) platforms;
+  };
+})