lib: add apply and callWith

lib/customisation.nix

@@ -296,4 +296,30 @@ rec {
       };
     in self;
 
+
+
+  /* Apply a function to an attrset of potential args, automatically filtering
+     the set to those the function can accept.
+     NOTE: This is strictly meant to be used with functions that accept attrsets
+     as their argument, and is best suited for use with `setFunctionArgs'.
+
+     nix-repl> lib.applyArgs ( { x, y }: x + y ) { x = 1; y = 2; z = -1; }
+     3
+  */
+  applyArgs = f: args: let
+    fn = if lib.isFunction f then f else import f;
+  in fn ( builtins.intersectAttrs ( lib.functionArgs fn ) args );
+
+
+  /* Non-overridable form of `callPackageWith'.
+     Applying matching args from `auto' with `args' to function/file `f'.
+
+     nix-repl> f = lib.callWith { x = 1; y = 2; z = -1; } ( { x, y }: x + y )
+     nix-repl> f { x = 3; }
+     5
+  */
+  callWith = auto: f: args: let
+    fn = if lib.isFunction f then f else import f;
+  in fn ( ( builtins.intersectAttrs ( lib.functionArgs fn ) auto ) // args );
+
 }

lib/default.nix

@@ -109,7 +109,7 @@ let
       noDepEntry fullDepEntry packEntry stringAfter;
     inherit (self.customisation) overrideDerivation makeOverridable
       callPackageWith callPackagesWith extendDerivation hydraJob
-      makeScope makeScopeWithSplicing;
+      makeScope makeScopeWithSplicing applyArgs callWith;
     inherit (self.derivations) lazyDerivation;
     inherit (self.meta) addMetaAttrs dontDistribute setName updateName
       appendToName mapDerivationAttrset setPrio lowPrio lowPrioSet hiPrio

lib/tests/misc.nix

@@ -1419,4 +1419,33 @@ runTests {
     expr = (with types; either int (listOf (either bool str))).description;
     expected = "signed integer or list of (boolean or string)";
   };
+
+  testApplyArgsFormal = {
+    expr = applyArgs ( { x, y }: x + y ) { x = 1; y = 2; z = -1; };
+    expected = 3;
+  };
+
+  testApplyArgsInformal = {
+    expr = applyArgs ( args: ( args.x or 1 ) + ( args.y or 2 ) ) {
+      x = 3;
+      y = 4;
+      z = -1;
+    };
+    expected = 3;
+  };
+
+  testCallWithFormal = {
+    expr = callWith { x = 1; y = 2; z = -1; } ( { x, y }: x + y ) { x = 3; };
+    expected = 5;
+  };
+
+  testCallWithInformal = {
+    expr = callWith { x = 1; y = 2; z = -1; } ( args: args.x + args.y ) {
+      x = 3;
+      y = 4;
+      z = -2;
+    };
+    expected = 7;
+  };
+
 }