telegraf: init at 0.13.2

nixos/modules/misc/ids.nix

@@ -275,6 +275,7 @@
       gocd-server = 252;
       terraria = 253;
       mattermost = 254;
+      telegraf = 255;
 
       # When adding a uid, make sure it doesn't match an existing gid. And don't use uids above 399!
 
@@ -520,6 +521,7 @@
       gocd-server = 252;
       terraria = 253;
       mattermost = 254;
+      telegraf = 255;
 
       # When adding a gid, make sure it doesn't match an existing
       # uid. Users and groups with the same name should have equal

nixos/modules/module-list.nix

@@ -293,6 +293,7 @@
   ./services/monitoring/smartd.nix
   ./services/monitoring/statsd.nix
   ./services/monitoring/systemhealth.nix
+  ./services/monitoring/telegraf.nix
   ./services/monitoring/teamviewer.nix
   ./services/monitoring/ups.nix
   ./services/monitoring/uptime.nix

nixos/modules/services/monitoring/telegraf.nix

@@ -0,0 +1,71 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.services.telegraf;
+
+  configFile = pkgs.runCommand "config.toml" {
+    buildInputs = [ pkgs.remarshal ];
+  } ''
+    remarshal -if json -of toml \
+      < ${pkgs.writeText "config.json" (builtins.toJSON cfg.extraConfig)} \
+      > $out
+  '';
+in
+{
+
+  ###### interface
+
+  options = {
+
+    services.telegraf = {
+
+      enable = mkEnableOption "telegraf server";
+
+      package = mkOption {
+        default = pkgs.telegraf;
+        defaultText = "pkgs.telegraf";
+        description = "Which telegraf derivation to use";
+        type = types.package;
+      };
+
+      extraConfig = mkOption {
+        default = {};
+        description = "Extra configuration options for telegraf";
+        type = types.attrs;
+      };
+    };
+
+  };
+
+
+  ###### implementation
+
+  config = mkIf config.services.telegraf.enable {
+
+    systemd.services.telegraf = {
+      description = "Telegraf Agent";
+      wantedBy = [ "multi-user.target" ];
+      after = [ "network-interfaces.target" ];
+      serviceConfig = {
+        ExecStart = ''${cfg.package}/bin/telegraf -config "${configFile}"'';
+        User = "telegraf";
+        Group = "telegraf";
+      };
+    };
+
+    users.extraUsers = [{
+      name = "telegraf";
+      uid = config.ids.uids.telegraf;
+      description = "telegraf daemon user";
+    }];
+
+    users.extraGroups = [{
+      name = "telegraf";
+      gid = config.ids.gids.telegraf;
+    }];
+  };
+
+}
+

pkgs/tools/system/telegraf/default.nix

@@ -0,0 +1,27 @@
+{ lib, buildGoPackage, fetchFromGitHub }:
+
+buildGoPackage rec {
+  name = "telegraf-${version}";
+  version = "0.13.2";
+
+  src = fetchFromGitHub {
+    owner = "influxdata";
+    repo = "telegraf";
+    rev = "${version}";
+    sha256 = "1zdb85wkx5q7c799sn695ckzym6avqz05xlvw0d1p919c2ilba9f";
+  };
+
+  goPackagePath = "github.com/influxdata/telegraf";
+
+  # Generated with the `gdm2nix.rb` script and the `Godeps` file from the
+  # influxdb repo root.
+  goDeps = ./deps.json;
+
+  meta = with lib; {
+    description = " The plugin-driven server agent for collecting & reporting metrics. ";
+    license = licenses.mit;
+    homepage = https://github.com/influxdata/telegraf;
+    maintainers = with maintainers; [ roblabla ];
+    platforms = platforms.linux;
+  };
+}