Rust and cargo improvements

pkgs/build-support/rust/default.nix

@@ -1,4 +1,4 @@
-{ stdenv, cacert, git, cargo, rustRegistry }:
+{ stdenv, cacert, git, rust, rustRegistry }:
 { name, depsSha256
 , src ? null
 , srcs ? null
@@ -10,7 +10,7 @@
 
 let
   fetchDeps = import ./fetchcargo.nix {
-    inherit stdenv cacert git cargo rustRegistry;
+    inherit stdenv cacert git rust rustRegistry;
   };
 
   cargoDeps = fetchDeps {
@@ -23,7 +23,7 @@ in stdenv.mkDerivation (args // {
 
   patchRegistryDeps = ./patch-registry-deps;
 
-  buildInputs = [ git cargo cargo.rustc ] ++ buildInputs;
+  buildInputs = [ git rust.cargo rust.rustc ] ++ buildInputs;
 
   configurePhase = args.configurePhase or "true";
 

pkgs/build-support/rust/fetchcargo.nix

@@ -1,9 +1,9 @@
-{ stdenv, cacert, git, cargo, rustRegistry }:
+{ stdenv, cacert, git, rust, rustRegistry }:
 { name ? "cargo-deps", src, srcs, sourceRoot, sha256, cargoUpdateHook ? "" }:
 
 stdenv.mkDerivation {
   name = "${name}-fetch";
-  buildInputs = [ cargo git ];
+  buildInputs = [ rust.cargo rust.rustc git ];
   inherit src srcs sourceRoot rustRegistry cargoUpdateHook;
 
   phases = "unpackPhase installPhase";

pkgs/development/compilers/rust/beta.nix

@@ -0,0 +1,27 @@
+{ stdenv, callPackage, rustPlatform,
+  targets ? [], targetToolchains ? [], targetPatches ? [] }:
+
+rec {
+  rustc = callPackage ./rustc.nix {
+    shortVersion = "beta-1.10.0";
+    forceBundledLLVM = false;
+    configureFlags = [ "--release-channel=beta" ];
+    srcRev = "d18e321abeecc69e4d1bf9cafba4fba53ddf267d";
+    srcSha = "1ck8mbjrq0bzq5xzwgaqdilakwm2ab0xpzqibjycds62ad4yw774";
+    patches = [ ./patches/disable-lockfile-check.patch ]
+      ++ stdenv.lib.optional stdenv.needsPax ./patches/grsec.patch;
+    inherit targets;
+    inherit targetPatches;
+    inherit targetToolchains;
+    inherit rustPlatform;
+  };
+
+  cargo = callPackage ./cargo.nix rec {
+    version = "0.10.0";
+    srcRev = "refs/tags/${version}";
+    srcSha = "06scvx5qh60mgvlpvri9ig4np2fsnicsfd452fi9w983dkxnz4l2";
+    depsSha256 = "0js4697n7v93wnqnpvamhp446w58llj66za5hkd6wannmc0gsy3b";
+    inherit rustc; # the rustc that will be wrapped by cargo
+    inherit rustPlatform; # used to build cargo
+  };
+}

pkgs/development/compilers/rust/bootstrap.nix

@@ -0,0 +1,78 @@
+{ stdenv, fetchurl, makeWrapper, cacert, zlib }:
+
+let
+  platform =
+    if stdenv.system == "i686-linux"
+    then "i686-unknown-linux-gnu"
+    else if stdenv.system == "x86_64-linux"
+    then "x86_64-unknown-linux-gnu"
+    else if stdenv.system == "i686-darwin"
+    then "i686-apple-darwin"
+    else if stdenv.system == "x86_64-darwin"
+    then "x86_64-apple-darwin"
+    else abort "missing boostrap url for platform ${stdenv.system}";
+
+  # fetch hashes by running `print-hashes.sh 1.9.0`
+  bootstrapHash =
+    if stdenv.system == "i686-linux"
+    then "dd4d9bf1b9393867eb18d00431e8fb733894984f2c7b5154bc1b64d045077b45"
+    else if stdenv.system == "x86_64-linux"
+    then "288ff13efa2577e81c77fc2cb6e2b49b1ed0ceab51b4fa12f7efb87039ac49b7"
+    else if stdenv.system == "i686-darwin"
+    then "4d4d4b256d6bd6ae2527cf61007b2553de200f0a1910b7ad41e4f51d2b21e536"
+    else if stdenv.system == "x86_64-darwin"
+    then "d59b5509e69c1cace20a57072e3b3ecefdbfd8c7e95657b0ff2ac10aa1dfebe6"
+    else throw "missing boostrap hash for platform ${stdenv.system}";
+
+  src = fetchurl {
+     url = "https://static.rust-lang.org/dist/rust-${version}-${platform}.tar.gz";
+     sha256 = bootstrapHash;
+  };
+
+  version = "1.9.0";
+in
+
+rec {
+  rustc = stdenv.mkDerivation rec {
+    name = "rustc-bootstrap-${version}";
+
+    inherit version;
+    inherit src;
+
+    buildInputs = [ makeWrapper ];
+    phases = ["unpackPhase" "installPhase"];
+
+    installPhase = ''
+      ./install.sh --prefix=$out \
+        --components=rustc,rust-std-${platform},rust-docs
+
+      patchelf \
+        --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
+        "$out/bin/rustc"
+
+      wrapProgram "$out/bin/rustc"
+    '';
+  };
+
+  cargo = stdenv.mkDerivation rec {
+    name = "cargo-bootstrap-${version}";
+
+    inherit version;
+    inherit src;
+
+    buildInputs = [ makeWrapper zlib rustc ];
+    phases = ["unpackPhase" "installPhase"];
+
+    installPhase = ''
+      ./install.sh --prefix=$out \
+        --components=cargo
+
+      patchelf \
+        --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
+        "$out/bin/cargo"
+
+      wrapProgram "$out/bin/cargo" \
+        --suffix PATH : "${rustc}/bin"
+    '';
+  };
+}

pkgs/development/compilers/rust/cargo.nix

@@ -0,0 +1,64 @@
+{ stdenv, fetchgit, file, curl, pkgconfig, python, openssl, cmake, zlib
+, makeWrapper, libiconv, cacert, rustPlatform, rustc
+, version, srcRev, srcSha, depsSha256 }:
+
+rustPlatform.buildRustPackage rec {
+  name = "cargo-${version}";
+  inherit version;
+
+  src = fetchgit {
+    url = "https://github.com/rust-lang/cargo";
+    rev = srcRev;
+    sha256 = srcSha;
+  };
+
+  inherit depsSha256;
+
+  passthru.rustc = rustc;
+
+  buildInputs = [ file curl pkgconfig python openssl cmake zlib makeWrapper ]
+    ++ stdenv.lib.optional stdenv.isDarwin libiconv;
+
+  configurePhase = ''
+    ./configure --enable-optimize --prefix=$out --local-cargo=${rustPlatform.rust.cargo}/bin/cargo
+  '';
+
+  buildPhase = "make";
+
+  installPhase = ''
+    make install
+    ${postInstall}
+  '';
+
+  postInstall = ''
+    rm "$out/lib/rustlib/components" \
+       "$out/lib/rustlib/install.log" \
+       "$out/lib/rustlib/rust-installer-version" \
+       "$out/lib/rustlib/uninstall.sh" \
+       "$out/lib/rustlib/manifest-cargo"
+
+    wrapProgram "$out/bin/cargo" \
+      --suffix PATH : "${rustc}/bin" \
+      --run "export SSL_CERT_FILE=${cacert}/etc/ssl/certs/ca-bundle.crt" \
+      ${stdenv.lib.optionalString stdenv.isDarwin ''--suffix DYLD_LIBRARY_PATH : "${rustc}/lib"''}
+  '';
+
+  checkPhase = ''
+    # Export SSL_CERT_FILE as without it one test fails with SSL verification error
+    export SSL_CERT_FILE=${cacert}/etc/ssl/certs/ca-bundle.crt
+    # Disable cross compilation tests
+    export CFG_DISABLE_CROSS_TESTS=1
+    cargo test
+  '';
+
+  # Disable check phase as there are failures (author_prefers_cargo test fails)
+  doCheck = false;
+
+  meta = with stdenv.lib; {
+    homepage = http://crates.io;
+    description = "Downloads your Rust project's dependencies and builds your project";
+    maintainers = with maintainers; [ wizeman retrry ];
+    license = [ licenses.mit licenses.asl20 ];
+    platforms = platforms.linux ++ platforms.darwin;
+  };
+}

pkgs/development/compilers/rust/default.nix

@@ -0,0 +1,33 @@
+{ stdenv, callPackage, recurseIntoAttrs, makeRustPlatform,
+  targets ? [], targetToolchains ? [], targetPatches ? [] }:
+
+let
+  rustPlatform = recurseIntoAttrs (makeRustPlatform (callPackage ./bootstrap.nix {}) rustPlatform);
+  rustSnapshotPlatform = recurseIntoAttrs (makeRustPlatform (callPackage ./snapshot.nix {}) rustPlatform);
+in
+
+rec {
+  rustc = callPackage ./rustc.nix {
+    shortVersion = "1.9.0";
+    isRelease = true;
+    forceBundledLLVM = false;
+    configureFlags = [ "--release-channel=stable" ];
+    srcRev = "e4e8b666850a763fdf1c3c2c142856ab51e32779";
+    srcSha = "1pz4qx70mqv78fxm4w1mq7csk5pssq4qmr2vwwb5v8hyx03caff8";
+    patches = [ ./patches/remove-uneeded-git.patch ]
+      ++ stdenv.lib.optional stdenv.needsPax ./patches/grsec.patch;
+    inherit targets;
+    inherit targetPatches;
+    inherit targetToolchains;
+    rustPlatform = rustSnapshotPlatform;
+  };
+
+  cargo = callPackage ./cargo.nix rec {
+    version = "0.10.0";
+    srcRev = "refs/tags/${version}";
+    srcSha = "06scvx5qh60mgvlpvri9ig4np2fsnicsfd452fi9w983dkxnz4l2";
+    depsSha256 = "0js4697n7v93wnqnpvamhp446w58llj66za5hkd6wannmc0gsy3b";
+    inherit rustc; # the rustc that will be wrapped by cargo
+    inherit rustPlatform; # used to build cargo
+  };
+}

pkgs/development/compilers/rust/head.nix

@@ -0,0 +1,27 @@
+{ stdenv, callPackage, rustPlatform,
+  targets ? [], targetToolchains ? [], targetPatches ? [] }:
+
+rec {
+  rustc = callPackage ./rustc.nix {
+    shortVersion = "master-1.11.0";
+    forceBundledLLVM = false;
+    srcRev = "298730e7032cd55809423773da397cd5c7d827d4";
+    srcSha = "0hyz5j1z75sjkgsifzgxviv3b1lhgaz8wqwvmq80xx5vd78yd0c1";
+    patches = [ ./patches/disable-lockfile-check.patch
+                ./patches/use-rustc-1.9.0.patch ]
+      ++ stdenv.lib.optional stdenv.needsPax ./patches/grsec.patch;
+    inherit targets;
+    inherit targetPatches;
+    inherit targetToolchains;
+    inherit rustPlatform;
+  };
+
+  cargo = callPackage ./cargo.nix rec {
+    version = "2016.06.07";
+    srcRev = "3e70312a2a4ebedace131fc63bb8f27463c5db28";
+    srcSha = "0nibzyfjkiqfnq0c00hhqvs856l5qls8wds252p97q5q92yvp40f";
+    depsSha256 = "1xbb33aqnf5yyws6gjys9w8kznbh9rh6hw8mpg1hhq1ahipc2j1f";
+    inherit rustc; # the rustc that will be wrapped by cargo
+    inherit rustPlatform; # used to build cargo
+  };
+}

pkgs/development/compilers/rust/print-hashes.sh

@@ -0,0 +1,17 @@
+#!/bin/sh
+
+PLATFORMS="i686-unknown-linux-gnu x86_64-unknown-linux-gnu i686-apple-darwin x86_64-apple-darwin"
+BASEURL="https://static.rust-lang.org/dist"
+VERSION=$1
+
+if [[ -z  $VERSION ]]
+then
+    echo "No version supplied"
+    exit -1
+fi
+
+for PLATFORM in $PLATFORMS
+do
+    URL="$BASEURL/rust-$VERSION-$PLATFORM.tar.gz.sha256"
+    curl $URL
+done

pkgs/development/compilers/rustc/generic.nix → pkgs/development/compilers/rust/rustc.nix

@@ -1,28 +1,17 @@
 { stdenv, fetchurl, fetchgit, fetchzip, file, python2, tzdata, procps
-, llvm, jemalloc, ncurses, darwin, binutils, rustc
+, llvm, jemalloc, ncurses, darwin, binutils, rustPlatform, git
 
 , isRelease ? false
 , shortVersion
 , forceBundledLLVM ? false
 , srcSha, srcRev
 , configureFlags ? []
 , patches
+, targets
+, targetPatches
+, targetToolchains
 } @ args:
 
-/* Rust's build process has a few quirks :
-
-- The Rust compiler is written is Rust, so it requires a bootstrap
-  compiler, which is downloaded during the build. To make the build
-  pure, we download it ourself before and put it where it is
-  expected. Once the language is stable (1.0) , we might want to
-  switch it to use nix's packaged rust compiler. This might not be possible
-  as the compiler is highly coupled to the bootstrap.
-
-NOTE : some derivation depend on rust. When updating this, please make
-sure those derivations still compile. (racer, for example).
-
-*/
-
 let
     version = if isRelease then
         "${shortVersion}"
@@ -35,15 +24,7 @@ let
 
     llvmShared = llvm.override { enableSharedLibraries = true; };
 
-    target = if stdenv.system == "i686-linux"
-      then "i686-unknown-linux-gnu"
-      else if stdenv.system == "x86_64-linux"
-      then "x86_64-unknown-linux-gnu"
-      else if stdenv.system == "i686-darwin"
-      then "i686-apple-darwin"
-      else if stdenv.system == "x86_64-darwin"
-      then "x86_64-apple-darwin"
-      else abort "no snapshot to bootstrap for this platform (missing target triple)";
+    target = builtins.replaceStrings [" "] [","] (builtins.toString targets);
 
     meta = with stdenv.lib; {
       homepage = http://www.rust-lang.org/;
@@ -71,13 +52,15 @@ stdenv.mkDerivation {
 
   # We need rust to build rust. If we don't provide it, configure will try to download it.
   configureFlags = configureFlags
-                ++ [ "--enable-local-rust" "--local-rust-root=${rustc}" "--enable-rpath" ]
+                ++ [ "--enable-local-rust" "--local-rust-root=${rustPlatform.rust.rustc}" "--enable-rpath" ]
                 # ++ [ "--jemalloc-root=${jemalloc}/lib"
                 ++ [ "--default-linker=${stdenv.cc}/bin/cc" "--default-ar=${binutils.out}/bin/ar" ]
                 ++ stdenv.lib.optional (stdenv.cc.cc ? isClang) "--enable-clang"
+                ++ stdenv.lib.optional (targets != []) "--target=${target}"
                 ++ stdenv.lib.optional (!forceBundledLLVM) "--llvm-root=${llvmShared}";
 
-  inherit patches;
+  patches = patches ++ targetPatches;
+  passthru.target = target;
 
   postPatch = ''
     substituteInPlace src/rust-installer/gen-install-script.sh \
@@ -112,8 +95,8 @@ stdenv.mkDerivation {
   '';
 
   # ps is needed for one of the test cases
-  nativeBuildInputs = [ file python2 procps rustc ];
-  buildInputs = [ ncurses ]
+  nativeBuildInputs = [ file python2 procps rustPlatform.rust.rustc git ];
+  buildInputs = [ ncurses ] ++ targetToolchains
     ++ stdenv.lib.optional (!forceBundledLLVM) llvmShared;
 
   # https://github.com/rust-lang/rust/issues/30181
@@ -125,4 +108,5 @@ stdenv.mkDerivation {
   preCheck = "export TZDIR=${tzdata}/share/zoneinfo";
 
   doCheck = true;
+  dontSetConfigureCross = true;
 }