add gstreamer 1.2.1

pkgs/desktops/xfce/applications/parole.nix

@@ -0,0 +1,43 @@
+{ stdenv, fetchurl, makeWrapper, pkgconfig, intltool, gst_all_1
+, gtk, dbus_glib, libxfce4ui, libxfce4util, xfconf
+, taglib, libnotify
+, withGstPlugins ? true
+}:
+
+stdenv.mkDerivation rec {
+  p_name  = "parole";
+  ver_maj = "0.5";
+  ver_min = "4";
+
+  src = fetchurl {
+    url = "mirror://xfce/src/apps/${p_name}/${ver_maj}/${name}.tar.bz2";
+    sha256 = "1hxzqg9dfghrhvmnnccwwa4278fh2awkcqy89sla05m08mxvvx60";
+  };
+  name = "${p_name}-${ver_maj}.${ver_min}";
+
+  nativeBuildInputs = [ pkgconfig intltool ];
+
+  buildInputs = [
+    makeWrapper gst_all_1.gst-plugins-base
+    gtk dbus_glib libxfce4ui libxfce4util xfconf
+    taglib libnotify
+  ];
+
+  configureFlags = [ "--with-gstreamer=1.0" ];
+
+  postInstall = stdenv.lib.optionalString withGstPlugins ''
+    wrapProgram "$out/bin/parole" --prefix \
+      GST_PLUGIN_PATH ":" ${stdenv.lib.concatStringsSep ":"
+        (map (s: s+"/lib/gstreamer-1.0") (with gst_all_1; [
+          gst-plugins-base gst-plugins-good
+          gst-plugins-bad gst-plugins-ugly
+          gst-libav
+        ])) }
+  '';
+
+  meta = {
+    homepage = "http://goodies.xfce.org/projects/applications/${p_name}";
+    description = "Modern simple media player";
+    platforms = stdenv.lib.platforms.linux;
+  };
+}

pkgs/desktops/xfce/default.nix

@@ -41,6 +41,7 @@ xfce_self = rec { # the lines are very long but it seems better than the even-od
 
   gigolo          = callPackage ./applications/gigolo.nix { };
   mousepad        = callPackage ./applications/mousepad.nix { };
+  parole          = callPackage ./applications/parole.nix { };
   ristretto       = callPackage ./applications/ristretto.nix { };
   terminal        = xfce4terminal; # it has changed its name
   xfce4mixer      = callPackage ./applications/xfce4-mixer.nix { };

pkgs/development/libraries/gstreamer/bad/default.nix

@@ -0,0 +1,34 @@
+{ stdenv, fetchurl, pkgconfig, python, gst-plugins-base, orc
+, faac, faad2, libass, libkate, libmms
+, libmodplug, mpeg2dec, mpg123 
+, openjpeg, libopus, librsvg
+, timidity, libvdpau, wayland
+, libwebp, xvidcore, gnutls
+}:
+
+stdenv.mkDerivation rec {
+  name = "gst-plugins-bad-1.2.2";
+
+  meta = {
+    homepage = "http://gstreamer.freedesktop.org";
+    license = stdenv.lib.licenses.gpl2Plus;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ iyzsong ];
+  };
+
+  src = fetchurl {
+    url = "${meta.homepage}/src/gst-plugins-bad/${name}.tar.xz";
+    sha256 = "63e78db11b482d0529a0bde01e2ac23fd32c7cb99a5508b53ee4ca1051871b2c";
+  };
+
+  nativeBuildInputs = [ pkgconfig python ];
+
+  buildInputs = [
+    gst-plugins-base orc
+    faac faad2 libass libkate libmms
+    libmodplug mpeg2dec mpg123 
+    openjpeg libopus librsvg
+    timidity libvdpau wayland
+    libwebp xvidcore gnutls
+  ];
+}

pkgs/development/libraries/gstreamer/base/default.nix

@@ -0,0 +1,32 @@
+{ stdenv, fetchurl, pkgconfig, python, gstreamer, gobjectIntrospection
+, orc, alsaLib, libXv, pango, libtheora
+, cdparanoia, libvisual
+}:
+
+stdenv.mkDerivation rec {
+  name = "gst-plugins-base-1.2.2";
+
+  meta = {
+    description = "Base plugins and helper libraries";
+    homepage = "http://gstreamer.freedesktop.org";
+    license = stdenv.lib.licenses.lgpl2Plus;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ iyzsong ];
+  };
+
+  src = fetchurl {
+    url = "${meta.homepage}/src/gst-plugins-base/${name}.tar.xz";
+    sha256 = "fa90cf21eac0a77f9393100356aef99ae42072c31dc218d3ae2e7f86cd5ced69";
+  };
+
+  nativeBuildInputs = [
+    pkgconfig python gobjectIntrospection
+  ];
+
+  buildInputs = [
+    orc alsaLib libXv pango libtheora
+    cdparanoia libvisual
+  ];
+
+  propagatedBuildInputs = [ gstreamer ];
+}

pkgs/development/libraries/gstreamer/core/default.nix

@@ -0,0 +1,26 @@
+{ stdenv, fetchurl, pkgconfig, perl, bison, flex, python, gobjectIntrospection
+, glib 
+}:
+
+stdenv.mkDerivation rec {
+  name = "gstreamer-1.2.2";
+
+  meta = {
+    description = "Open source multimedia framework";
+    homepage = "http://gstreamer.freedesktop.org";
+    license = stdenv.lib.licenses.lgpl2Plus;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ iyzsong ];
+  };
+
+  src = fetchurl {
+    url = "${meta.homepage}/src/gstreamer/${name}.tar.xz";
+    sha256 = "b9f12137ab663edc6c37429b38ca7911074b9c2a829267fe855d4e57d916a0b6";
+  };
+
+  nativeBuildInputs = [
+    pkgconfig perl bison flex python gobjectIntrospection
+  ];
+
+  propagatedBuildInputs = [ glib ];
+}

pkgs/development/libraries/gstreamer/default.nix

@@ -0,0 +1,15 @@
+{ callPackage }:
+
+rec {
+  gstreamer = callPackage ./core { };
+
+  gst-plugins-base = callPackage ./base { inherit gstreamer; };
+
+  gst-plugins-good = callPackage ./good { inherit gst-plugins-base; };
+
+  gst-plugins-bad = callPackage ./bad { inherit gst-plugins-base; };
+
+  gst-plugins-ugly = callPackage ./ugly { inherit gst-plugins-base; };
+
+  gst-libav = callPackage ./libav { inherit gst-plugins-base; };
+}

pkgs/development/libraries/gstreamer/good/default.nix

@@ -0,0 +1,33 @@
+{ stdenv, fetchurl, pkgconfig, python
+, gst-plugins-base, orc, bzip2
+, libv4l, libdv, libavc1394, libiec61883
+, libvpx, speex, flac, taglib
+, cairo, gdk_pixbuf, aalib, libcaca
+, libsoup, pulseaudio
+}:
+
+stdenv.mkDerivation rec {
+  name = "gst-plugins-good-1.2.2";
+
+  meta = {
+    homepage = "http://gstreamer.freedesktop.org";
+    license = stdenv.lib.licenses.gpl2Plus;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ iyzsong ];
+  };
+
+  src = fetchurl {
+    url = "${meta.homepage}/src/gst-plugins-good/${name}.tar.xz";
+    sha256 = "6c090f00e8e4588f12807bd9fbb06a03b84a512c93e84d928123ee4a42228a81";
+  };
+
+  nativeBuildInputs = [ pkgconfig python ];
+
+  buildInputs = [
+    gst-plugins-base orc bzip2
+    libv4l libdv libavc1394 libiec61883
+    libvpx speex flac taglib
+    cairo gdk_pixbuf aalib libcaca
+    libsoup pulseaudio
+  ];
+}

pkgs/development/libraries/gstreamer/libav/default.nix

@@ -0,0 +1,35 @@
+{ stdenv, fetchurl, pkgconfig, python, yasm
+, gst-plugins-base, orc, bzip2
+, withSystemLibav ? false, libav ? null
+}:
+
+assert withSystemLibav -> libav != null;
+
+stdenv.mkDerivation rec {
+  name = "gst-libav-1.2.2";
+
+  meta = {
+    homepage = "http://gstreamer.freedesktop.org";
+    license = stdenv.lib.licenses.lgpl2Plus;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ iyzsong ];
+  };
+
+  src = fetchurl {
+    url = "${meta.homepage}/src/gst-libav/${name}.tar.xz";
+    sha256 = "585eb7971006100ad771a852e07bd2f3e23bcc6eb0b1253a40b5a0e40e4e7418";
+  };
+
+  configureFlags = stdenv.lib.optionalString withSystemLibav
+    "--with-system-libav";
+
+  nativeBuildInputs = with stdenv.lib;
+    [ pkgconfig python ]
+    ++ optional (!withSystemLibav) yasm
+    ;
+
+  buildInputs = with stdenv.lib;
+    [ gst-plugins-base orc bzip2 ]
+    ++ optional withSystemLibav libav
+    ;
+}

pkgs/development/libraries/gstreamer/ugly/default.nix

@@ -0,0 +1,29 @@
+{ stdenv, fetchurl, pkgconfig, python
+, gst-plugins-base, orc
+, a52dec, libcdio, libdvdread
+, lame, libmad, libmpeg2, x264
+}:
+
+stdenv.mkDerivation rec {
+  name = "gst-plugins-ugly-1.2.2";
+
+  meta = {
+    homepage = "http://gstreamer.freedesktop.org";
+    license = stdenv.lib.licenses.lgpl2Plus;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ iyzsong ];
+  };
+
+  src = fetchurl {
+    url = "${meta.homepage}/src/gst-plugins-ugly/${name}.tar.xz";
+    sha256 = "4b6aac272a5be0d68f365ef6fba0f829fc5c1d1d601bb4dd9e85f5289b2b56c3";
+  };
+
+  nativeBuildInputs = [ pkgconfig python ];
+
+  buildInputs = [
+    gst-plugins-base orc
+    a52dec libcdio libdvdread
+    lame libmad libmpeg2 x264
+  ];
+}

pkgs/top-level/all-packages.nix

@@ -4399,6 +4399,8 @@ let
   mpfr = callPackage ../development/libraries/mpfr { };
   mpfr_3_1_2 = callPackage ../development/libraries/mpfr/3.1.2.nix { };
 
+  gst_all_1 = callPackage ../development/libraries/gstreamer { };
+
   gst_all = {
     inherit (pkgs) gstreamer gnonlin gst_python qt_gstreamer;
     gstPluginsBase = pkgs.gst_plugins_base;
@@ -4408,29 +4410,29 @@ let
     gstFfmpeg = pkgs.gst_ffmpeg;
   };
 
-  gstreamer = callPackage ../development/libraries/gstreamer/gstreamer {};
+  gstreamer = callPackage ../development/libraries/gstreamer/legacy/gstreamer {};
 
-  gst_plugins_base = callPackage ../development/libraries/gstreamer/gst-plugins-base {};
+  gst_plugins_base = callPackage ../development/libraries/gstreamer/legacy/gst-plugins-base {};
 
-  gst_plugins_good = callPackage ../development/libraries/gstreamer/gst-plugins-good {};
+  gst_plugins_good = callPackage ../development/libraries/gstreamer/legacy/gst-plugins-good {};
 
-  gst_plugins_bad = callPackage ../development/libraries/gstreamer/gst-plugins-bad {};
+  gst_plugins_bad = callPackage ../development/libraries/gstreamer/legacy/gst-plugins-bad {};
 
-  gst_plugins_ugly = callPackage ../development/libraries/gstreamer/gst-plugins-ugly {};
+  gst_plugins_ugly = callPackage ../development/libraries/gstreamer/legacy/gst-plugins-ugly {};
 
-  gst_ffmpeg = callPackage ../development/libraries/gstreamer/gst-ffmpeg {
+  gst_ffmpeg = callPackage ../development/libraries/gstreamer/legacy/gst-ffmpeg {
     ffmpeg = ffmpeg_0_10;
   };
 
-  gst_python = callPackage ../development/libraries/gstreamer/gst-python {};
+  gst_python = callPackage ../development/libraries/gstreamer/legacy/gst-python {};
 
-  gnonlin = callPackage ../development/libraries/gstreamer/gnonlin {};
+  gnonlin = callPackage ../development/libraries/gstreamer/legacy/gnonlin {};
 
   gusb = callPackage ../development/libraries/gusb {
     inherit (gnome) gtkdoc;
   };
 
-  qt_gstreamer = callPackage ../development/libraries/gstreamer/qt-gstreamer {};
+  qt_gstreamer = callPackage ../development/libraries/gstreamer/legacy/qt-gstreamer {};
 
   gnet = callPackage ../development/libraries/gnet { };