update GitHub tarball sha256 hashes

[peff]

GitHub recently applied an old Git bugfix to their servers (git/git@22f0dcd), which caused the byte representation of some tarballs to change.

I computed the mapping of old to new tarballs by building two versions of git, with and without that commit, and then computing the archive hash for each case. I used this script (note the "git.with" and "git.without" builds were in my $PATH):

#!/usr/bin/perl

sub hash {
  my ($git, $repo, $version) = @_;
  my $prefix = $version;
  $prefix =~ s/^v//;
  $prefix = "$repo-$prefix/";
  my $cmd = "$git -C tmp.git archive --format=tar.gz" .
            " --prefix=" . quotemeta($prefix) .
            " " . quotemeta($version) .
            " | sha256sum";
  my $hash = `$cmd`;
  chomp $hash;
  $hash =~ s/\s*-$//;
  return $hash;
}

while (<>) {
  if (m{https://github.com/(.*?)/(.*?)/archive/(.*?).tar.gz}) {
        system(qw(rm -rf tmp.git));
        system(qw(git clone --bare), "https://github.com/$1/$2.git", "tmp.git");
        $? and next; # skip clone failures

        my $old = hash("git.without", $2, $3);
        my $new = hash("git.with", $2, $3);
        if ($old ne $new) {
          print "$old $new $1/$2\n";
          print STDERR "$1/$2\n  $old\n  $new\n";
        }
  }
}

That script generated 94 entries. With that output saved to the file "map", I was then able to adjust the hashes in place:

#!/bin/sh

git ls-files Formula | xargs perl -i -pe '
  BEGIN {
	  open(my $fh, "<map");
	  while (<$fh>) {
		  my ($from, $to, $repo) = split;
		  $map{$from} = $to;
	  }
  }

  s{sha256 "(.*?)"}
  {
	  my $hash = $1;
	  if (exists $map{$hash}) {
		  print STDERR "replacing $hash with $map{$hash}\n";
		  $hash = $map{$hash};
	  }
	  qq(sha256 "$hash")
  }e;
'

and commit the result. Note that there aren't 94 updates in this commit, because the previous commits had already picked up most of these changes.

/cc @ilovezfs #18044

[ilovezfs]

Thanks @peff! 🙇‍♂️

Do you mind splitting this into one commit per formula?

[peff]

@ilovezfs Done.

[ilovezfs]

@peff thanks. It looks like the osquery commit took teleport along for the ride :)

[ilovezfs]

May need to rebase your local repo since teleport was fixed already in 447ae95.

[peff]

Whoops, apparently I'm incompetent at using Git. Should be fixed now.

[ilovezfs]

Whoops, apparently I'm incompetent at using Git

Hehe. You made me think of https://xkcd.com/1597/

[ilovezfs]

Thanks for the great scripts and your first contribution to Homebrew, @peff!

[peff]

@ilovezfs Let me know if you'd like me to run the same scripts on another set of formulas. I wrote them in such a way that anybody could run and reproduce, but obviously they run a lot faster from inside GitHub's datacenter.

[ilovezfs]

@peff it would be great if you could run them on

https://github.com/Homebrew/homebrew-science/
https://github.com/Homebrew/homebrew-php/
https://github.com/Homebrew/homebrew-apache/

[peff]

@ilovezfs Sorry, for some reason I totally missed your response earlier.

I just ran it over those other repositories. homebrew-science has only the rstudio case covered by https://github.com/Homebrew/homebrew-science/pull/6315. homebrew-php has one case, for which I've opened https://github.com/Homebrew/homebrew-php/pull/4484. And there were none in homebrew-apache.