PHP injection inside :attribute="php_only"

[EmranMR]

Add support for php injection inside :attribute directives
see Passing Data

[calebdw]

The way I look at this, there's two ways to go about this:

1. Duplicate a lot of the html parser to add support for blade / livewire components (<x-foo>)
2. Extend the html injections to inject php_only into :attribute attributes inside elements matching a certain predicate

2. would be the easiest (I've already done this for AlpineJS), but wouldn't be self contained in this parser

[EmranMR]

@calebdw I had your option 2 in mind myself.

Basically define ::attribute #34 and :attributeusing a regex grammar. Then of course injecting JavaScript for one, and the php_only for the other.

In terms of highlighting, users then having the freedom to either paint them as attributes or framework.tag or whatever that works.

I haven't had a chance to give it a shot yet. It might be easier said than done when it comes to regex haha. But we shall see! I have a feeling the : and :: acting up once defined!

I had the same idea for #28 but I think it would be easier for that, because it's just a simple regex, I am not aware of any other framework using a similar syntax?

[calebdw]

Basically define ::attribute and :attribute using a regex grammar. Then of course injecting JavaScript for one, and the php_only for the other.

It's not that simple---those injections are only valid inside a blade component element which you would have no way of knowing without copying a lot of the html parser to determine what's an element, attribute, etc.

The simplest thing to do is to just extend the default html injections, the below html injections solves this issue, #28, and #34 without any changes needed to the blade parser:

nvim/after/queries/html/injections.scm

;; extends

; AlpineJS attributes
(attribute
  (attribute_name) @_attr
    (#lua-match? @_attr "^x%-%l")
  (quoted_attribute_value
    (attribute_value) @injection.content)
  (#set! injection.language "javascript"))

; Blade escaped JS attributes
; <x-foo ::bar="baz" />
(element
  (_
    (tag_name) @_tag
      (#lua-match? @_tag "^x%-%l")
  (attribute
    (attribute_name) @_attr
      (#lua-match? @_attr "^::%l")
    (quoted_attribute_value
      (attribute_value) @injection.content)
    (#set! injection.language "javascript"))))

; Blade PHP attributes
; <x-foo :bar="$baz" />
(element
  (_
    (tag_name) @_tag
      (#lua-match? @_tag "^x%-%l")
    (attribute
      (attribute_name) @_attr
        (#lua-match? @_attr "^:%l")
      (quoted_attribute_value
        (attribute_value) @injection.content)
      (#set! injection.language "php_only"))))