Area Markers - Support editing all area markers (#676)

Author: mharis001

addons/area_markers/XEH_PREP.hpp

@@ -1,10 +1,17 @@
 PREP(applyProperties);
 PREP(configure);
 PREP(createIcon);
+PREP(createMarker);
 PREP(deleteIcon);
+PREP(initDisplayCurator);
+PREP(isEditable);
 PREP(module);
 PREP(onDraw);
 PREP(onKeyDown);
+PREP(onMapToggled);
+PREP(onMarkerCreated);
+PREP(onMarkerDeleted);
+PREP(onMarkerUpdated);
 PREP(onMouseButtonDown);
 PREP(onMouseButtonUp);
 PREP(onMouseDblClick);

addons/area_markers/XEH_postInit.sqf

@@ -1,82 +1,24 @@
 #include "script_component.hpp"
 
 if (isServer) then {
-    [QGVAR(create), {
-        params ["_position"];
-
-        private _marker = createMarker [format [QGVAR(%1), GVAR(nextID)], _position];
-        _marker setMarkerShape "RECTANGLE";
-        _marker setMarkerSize [50, 50];
-
-        GVAR(markers) pushBack _marker;
-        publicVariable QGVAR(markers);
-
-        GVAR(nextID) = GVAR(nextID) + 1;
-
-        [QGVAR(createIcon), _marker] call CBA_fnc_globalEvent;
-    }] call CBA_fnc_addEventHandler;
-
-    [QGVAR(delete), {
-        params ["_marker"];
-
-        private _index = GVAR(markers) find _marker;
-
-        if (_index != -1) then {
-            GVAR(markers) deleteAt _index;
-            publicVariable QGVAR(markers);
-
-            deleteMarker _marker;
-
-            [QGVAR(deleteIcon), _marker] call CBA_fnc_globalEvent;
-        };
-    }] call CBA_fnc_addEventHandler;
+    [QGVAR(createMarker), LINKFUNC(createMarker)] call CBA_fnc_addEventHandler;
 };
 
 if (hasInterface) then {
-    ["zen_curatorDisplayLoaded", {
-        params ["_display"];
-
-        // Namespace of marker names and their corresponding icon controls
-        if (isNil QGVAR(icons)) then {
-            GVAR(icons) = [] call CBA_fnc_createNamespace;
-        };
-
-        // Add EH to update area marker icon positions when the map is shown
-        private _ctrlMap = _display displayCtrl IDC_RSCDISPLAYCURATOR_MAINMAP;
-        _ctrlMap ctrlAddEventHandler ["Draw", {call FUNC(onDraw)}];
-
-        // Add EH to handle deleting area marker by pressing the DELETE key
-        _display displayAddEventHandler ["KeyDown", {call FUNC(onKeyDown)}];
-
-        // Create area marker icons for all area markers
-        {
-            {
-                [_x] call FUNC(createIcon);
-            } forEach GVAR(markers);
-        } call CBA_fnc_execNextFrame;
-
-        // Add PFH to update visibility of area marker icons
-        GVAR(visiblePFH) = [{
-            params ["_args"];
-            _args params ["_visible"];
-
-            if (_visible isEqualTo visibleMap) exitWith {};
-
-            _visible = visibleMap;
-            {
-                private _ctrlIcon = GVAR(icons) getVariable [_x, controlNull];
-                _ctrlIcon ctrlShow _visible;
-            } forEach GVAR(markers);
-
-            _args set [0, _visible];
-        }, 0, [visibleMap]] call CBA_fnc_addPerFrameHandler;
-    }] call CBA_fnc_addEventHandler;
-
-    ["zen_curatorDisplayUnloaded", {
-        GVAR(visiblePFH) call CBA_fnc_removePerFrameHandler;
-    }] call CBA_fnc_addEventHandler;
-
-    [QGVAR(createIcon), LINKFUNC(createIcon)] call CBA_fnc_addEventHandler;
-    [QGVAR(deleteIcon), LINKFUNC(deleteIcon)] call CBA_fnc_addEventHandler;
-    [QGVAR(updateIcon), LINKFUNC(updateIcon)] call CBA_fnc_addEventHandler;
+    ["zen_curatorDisplayLoaded", LINKFUNC(initDisplayCurator)] call CBA_fnc_addEventHandler;
+
+    // Add EHs to update visibility of area marker icons when the map is toggled
+    // Need both activate and deactivate to deal with issues around rapidly toggling the map
+    addUserActionEventHandler ["showMap", "Activate", {call FUNC(onMapToggled)}];
+    addUserActionEventHandler ["showMap", "Deactivate", {call FUNC(onMapToggled)}];
+
+    // Add EHs to automatically make any area markers editable
+    addMissionEventHandler ["MarkerCreated", {call FUNC(onMarkerCreated)}];
+    addMissionEventHandler ["MarkerDeleted", {call FUNC(onMarkerDeleted)}];
+    addMissionEventHandler ["MarkerUpdated", {call FUNC(onMarkerUpdated)}];
+
+    // Manually trigger event for 3DEN placed and already existent (JIP) markers
+    {
+        _x call FUNC(onMarkerCreated);
+    } forEach allMapMarkers;
 };

addons/area_markers/XEH_preInit.sqf

@@ -7,20 +7,26 @@ PREP_RECOMPILE_START;
 PREP_RECOMPILE_END;
 
 if (isServer) then {
-    GVAR(markers) = [];
-    publicVariable QGVAR(markers);
-
+    // Unique ID for creating markers
     GVAR(nextID) = 0;
 };
 
 if (hasInterface) then {
-    GVAR(colors) = [] call CBA_fnc_createNamespace;
+    GVAR(colors) = createHashMap;
 
     {
-        if (getNumber (_x >> "scope") > 0) then {
-            GVAR(colors) setVariable [configName _x, (_x >> "color") call BIS_fnc_colorConfigToRGBA];
-        };
+        GVAR(colors) set [configName _x, (_x >> "color") call BIS_fnc_colorConfigToRGBA];
     } forEach configProperties [configFile >> "CfgMarkerColors", "isClass _x"];
+
+    // List of editable area markers
+    GVAR(markers) = [];
+
+    // List of marker names that are blacklisted from being edited through Zeus
+    // A marker is blacklisted if its name contains any of strings in this list
+    GVAR(blacklist) = [];
+
+    // Map of marker names and their corresponding icon controls
+    GVAR(icons) = createHashMap;
 };
 
 ADDON = true;

addons/area_markers/functions/fnc_applyProperties.sqf

@@ -42,5 +42,3 @@ _marker setMarkerColor _color;
 private _ctrlAlphaSlider = _ctrlConfigure controlsGroupCtrl IDC_CONFIGURE_ALPHA_SLIDER;
 private _alpha = sliderPosition _ctrlAlphaSlider;
 _marker setMarkerAlpha _alpha;
-
-[QGVAR(updateIcon), [_marker, _rotation, _color]] call CBA_fnc_globalEvent;

addons/area_markers/functions/fnc_configure.sqf

@@ -162,6 +162,10 @@ private _keyDownEH = _display displayAddEventHandler ["KeyDown", {
             _display displayRemoveEventHandler ["KeyDown", _keyDownEH];
 
             ctrlDelete _ctrlConfigure;
+
+            // Despite returning true to override default handling, pressing ESCAPE
+            // appears to be hard coded to close the map
+            call FUNC(onMapToggled);
         };
 
         true // handled

addons/area_markers/functions/fnc_createIcon.sqf

@@ -24,6 +24,6 @@ private _ctrlIcon = _display ctrlCreate [QGVAR(icon), IDC_ICON_GROUP];
 _ctrlIcon setVariable [QGVAR(marker), _marker];
 _ctrlIcon ctrlShow visibleMap;
 
-GVAR(icons) setVariable [_marker, _ctrlIcon];
+GVAR(icons) set [_marker, _ctrlIcon];
 
-[_marker, markerDir _marker, markerColor _marker] call FUNC(updateIcon);
+_marker call FUNC(updateIcon);

addons/area_markers/functions/fnc_createMarker.sqf

@@ -0,0 +1,25 @@
+#include "script_component.hpp"
+/*
+ * Author: mharis001
+ * Creates an area marker.
+ * Should only be called on the server for unique marker names.
+ *
+ * Arguments:
+ * 0: Position <ARRAY>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [[0, 0, 0]] call zen_area_markers_fnc_createMarker
+ *
+ * Public: No
+ */
+
+params ["_position"];
+
+private _marker = createMarker [format [QGVAR(%1), GVAR(nextID)], _position];
+_marker setMarkerShape "RECTANGLE";
+_marker setMarkerSize [50, 50];
+
+GVAR(nextID) = GVAR(nextID) + 1;

addons/area_markers/functions/fnc_deleteIcon.sqf

@@ -17,9 +17,7 @@
 
 params ["_marker"];
 
-private _ctrlIcon = GVAR(icons) getVariable _marker;
-if (isNil "_ctrlIcon" || {isNull _ctrlIcon}) exitWith {};
-
-GVAR(icons) setVariable [_marker, nil];
-
-ctrlDelete _ctrlIcon;
+if (_marker in GVAR(icons)) then {
+    ctrlDelete (GVAR(icons) get _marker);
+    GVAR(icons) deleteAt _marker;
+};

addons/area_markers/functions/fnc_initDisplayCurator.sqf

@@ -0,0 +1,32 @@
+#include "script_component.hpp"
+/*
+ * Author: mharis001
+ * Initializes the Zeus display.
+ *
+ * Arguments:
+ * 0: Display <DISPLAY>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [DISPLAY] call zen_area_markers_fnc_initDisplayCurator
+ *
+ * Public: No
+ */
+
+params ["_display"];
+
+// Add EH to update area marker icon positions when the map is shown
+private _ctrlMap = _display displayCtrl IDC_RSCDISPLAYCURATOR_MAINMAP;
+_ctrlMap ctrlAddEventHandler ["Draw", {call FUNC(onDraw)}];
+
+// Add EH to handle deleting area marker by pressing the DELETE key
+_display displayAddEventHandler ["KeyDown", {call FUNC(onKeyDown)}];
+
+// Create area marker icons for all area markers
+{
+    {
+        [_x] call FUNC(createIcon);
+    } forEach GVAR(markers);
+} call CBA_fnc_execNextFrame;

addons/area_markers/functions/fnc_isEditable.sqf

@@ -0,0 +1,20 @@
+#include "script_component.hpp"
+/*
+ * Author: mharis001
+ * Checks if the given marker is an editable area marker.
+ *
+ * Arguments:
+ * 0: Marker <STRING>
+ *
+ * Return Value:
+ * Is Editable <BOOL>
+ *
+ * Example:
+ * ["marker_0"] call zen_area_markers_fnc_isEditable
+ *
+ * Public: No
+ */
+
+params ["_marker"];
+
+markerShape _marker in ["RECTANGLE", "ELLIPSE"] && {GVAR(blacklist) findIf {_x in _marker} == -1}

addons/area_markers/functions/fnc_onDraw.sqf

@@ -20,14 +20,10 @@ BEGIN_COUNTER(onDraw);
 params ["_ctrlMap"];
 
 {
-    private _ctrlIcon = GVAR(icons) getVariable _x;
+    (_ctrlMap ctrlMapWorldToScreen markerPos _x) params ["_posX", "_posY"];
 
-    if (!isNil "_ctrlIcon") then {
-        (_ctrlMap ctrlMapWorldToScreen markerPos _x) params ["_posX", "_posY"];
-
-        _ctrlIcon ctrlSetPosition [_posX - OFFSET_X, _posY - OFFSET_Y];
-        _ctrlIcon ctrlCommit 0;
-    };
-} forEach GVAR(markers);
+    _y ctrlSetPosition [_posX - OFFSET_X, _posY - OFFSET_Y];
+    _y ctrlCommit 0;
+} forEach GVAR(icons);
 
 END_COUNTER(onDraw);

addons/area_markers/functions/fnc_onKeyDown.sqf

@@ -23,11 +23,18 @@ if (visibleMap && {_keyCode == DIK_DELETE}) exitWith {
     ctrlMapMouseOver _ctrlMap params [["_type", ""], ["_marker", ""]];
 
     if (_type == "marker" && {_marker in GVAR(markers)}) exitWith {
-        [QGVAR(delete), _marker] call CBA_fnc_serverEvent;
+        deleteMarker _marker;
         true
     };
 
     false
 };
 
+// Map visibility can be toggled with the ESCAPE key
+// Appears to be hard coded and independent of the "ingamePause" user action
+// Also, update the icons when the interface's visibility is toggled
+if (_keyCode == DIK_ESCAPE || {_keyCode in actionKeys "curatorToggleInterface"}) then {
+    call FUNC(onMapToggled);
+};
+
 false

addons/area_markers/functions/fnc_onMapToggled.sqf

@@ -0,0 +1,28 @@
+#include "script_component.hpp"
+/*
+ * Author: mharis001
+ * Handles toggling the Zeus display's map.
+ *
+ * Arguments:
+ * None
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [] call zen_area_markers_fnc_onMapToggled
+ *
+ * Public: No
+ */
+
+if (isNull findDisplay IDD_RSCDISPLAYCURATOR) exitWith {};
+
+// Need frame delay because both the visisbleMap and the map control's
+// visibility are not updated until the next frame
+{
+    private _show = visibleMap && {!call EFUNC(common,isInScreenshotMode)};
+
+    {
+        _y ctrlShow _show;
+    } forEach GVAR(icons);
+} call CBA_fnc_execNextFrame;

addons/area_markers/functions/fnc_onMarkerCreated.sqf

@@ -0,0 +1,23 @@
+#include "script_component.hpp"
+/*
+ * Author: mharis001
+ * Handles creating a marker.
+ *
+ * Arguments:
+ * 0: Marker <STRING>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * ["marker_0"] call zen_area_markers_fnc_onMarkerCreated
+ *
+ * Public: No
+ */
+
+params ["_marker"];
+
+if (_marker call FUNC(isEditable)) then {
+    GVAR(markers) pushBack _marker;
+    _marker call FUNC(createIcon);
+};

addons/area_markers/functions/fnc_onMarkerDeleted.sqf

@@ -0,0 +1,21 @@
+#include "script_component.hpp"
+/*
+ * Author: mharis001
+ * Handles deleting a marker.
+ *
+ * Arguments:
+ * 0: Marker <STRING>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * ["marker_0"] call zen_area_markers_fnc_onMarkerDeleted
+ *
+ * Public: No
+ */
+
+params ["_marker"];
+
+GVAR(markers) deleteAt (GVAR(markers) find _marker);
+_marker call FUNC(deleteIcon);