Add Switch Weapon context menu actions for infantry (#520)

* Add context menu actions under Loadout to switch an AI unit's current weapon

* Disabled on players, and AI which are currently holding their single available weapon

* https://youtu.be/5hq_pCK9_UM

Co-authored-by: mharis001 <[email protected]>

Author: ampersand38

addons/common/XEH_postInit.sqf

@@ -173,6 +173,11 @@
     _vehicle engineOn _state;
 }] call CBA_fnc_addEventHandler;
 
+[QGVAR(selectWeapon), {
+    params ["_unit", "_muzzle"];
+    _unit selectWeapon _muzzle;
+}] call CBA_fnc_addEventHandler;
+
 [QGVAR(setPilotLight), {
     params ["_vehicle", "_lights"];
     _vehicle setPilotLight _lights;

addons/context_actions/CfgContext.hpp

@@ -250,6 +250,28 @@ class EGVAR(context_menu,actions) {
             statement = QUOTE(_hoveredEntity setUnitLoadout configOf _hoveredEntity);
             icon = "\a3\3den\Data\Displays\Display3DEN\ToolBar\undo_ca.paa";
         };
+        class SwitchWeapon {
+            displayName = "$STR_A3_Switch1";
+            icon = "\a3\ui_f\data\IGUI\Cfg\Actions\reammo_ca.paa";
+            class Primary {
+                displayName = "$STR_A3_RSCDisplayArsenal_Tab_PrimaryWeapon";
+                condition = QUOTE([ARR_2(_hoveredEntity,_args)] call FUNC(canSwitchWeapon));
+                statement = QUOTE([ARR_2(_hoveredEntity,_args)] call FUNC(switchWeapon));
+                modifierFunction = QUOTE(call FUNC(switchWeaponModifier));
+                icon = "\a3\ui_f\data\GUI\Rsc\RscDisplayArsenal\primaryWeapon_ca.paa";
+                args = 0;
+            };
+            class Handgun: Primary {
+                displayName = "$STR_A3_RSCDisplayArsenal_Tab_Handgun";
+                icon = "\a3\ui_f\data\GUI\Rsc\RscDisplayArsenal\handgun_ca.paa";
+                args = 1;
+            };
+            class Binoculars: Primary {
+                displayName = "$STR_A3_RSCDisplayArsenal_Tab_Binoculars";
+                icon = "\a3\ui_f\data\GUI\Rsc\RscDisplayArsenal\binoculars_ca.paa";
+                args = 2;
+            };
+        };
     };
     class Inventory {
         displayName = "$STR_A3_Gear1";

addons/context_actions/XEH_PREP.hpp

@@ -6,6 +6,7 @@ PREP(canPasteVehicleAppearance);
 PREP(canRearmVehicles);
 PREP(canRefuelVehicles);
 PREP(canRepairVehicles);
+PREP(canSwitchWeapon);
 PREP(canToggleSurrender);
 PREP(canUnloadViV);
 PREP(copyVehicleAppearance);
@@ -25,6 +26,8 @@ PREP(setCombatMode);
 PREP(setFormation);
 PREP(setSpeedMode);
 PREP(setStance);
+PREP(switchWeaponModifier);
+PREP(switchWeapon);
 PREP(teleportPlayers);
 PREP(teleportZeus);
 PREP(toggleCaptive);

addons/context_actions/functions/fnc_canSwitchWeapon.sqf

@@ -0,0 +1,26 @@
+#include "script_component.hpp"
+/*
+ * Author: Ampersand
+ * Checks if the given unit can switch to the selected weapon.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ * 1: Weapon Index <NUMBER>
+ *
+ * Return Value:
+ * Can Switch Weapon <BOOL>
+ *
+ * Example:
+ * [_unit, 0] call zen_context_actions_fnc_canSwitchWeapon
+ *
+ * Public: No
+ */
+
+params ["_unit", "_weaponIndex"];
+
+private _weapon = [primaryWeapon _unit, handgunWeapon _unit, binocular _unit] select _weaponIndex;
+
+alive _unit
+&& {!isPlayer _unit}
+&& {_weapon != ""}
+&& {_weapon != currentWeapon _unit}

addons/context_actions/functions/fnc_switchWeapon.sqf

@@ -0,0 +1,22 @@
+#include "script_component.hpp"
+/*
+ * Author: Ampersand
+ * Switches the given unit's weapon to the selected one.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ * 1: Weapon Index <NUMBER>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [_unit, _weaponIndex] call zen_context_actions_fnc_switchWeapon
+ *
+ * Public: No
+ */
+
+params ["_unit", "_weaponIndex"];
+
+private _weapon = [primaryWeapon _unit, handgunWeapon _unit, binocular _unit] select _weaponIndex;
+[QEGVAR(common,selectWeapon), [_unit, _weapon], _unit] call CBA_fnc_targetEvent;

addons/context_actions/functions/fnc_switchWeaponModifier.sqf

@@ -0,0 +1,41 @@
+#include "script_component.hpp"
+/*
+ * Author: Ampersand
+ * Modifies the switch weapon action based on the hovered entity.
+ *
+ * Arguments:
+ * 0: Action <ARRAY>
+ * 1: Action Parameters <ARRAY>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [_action, _actionParams] call zen_context_actions_fnc_switchWeaponModifier
+ *
+ * Public: No
+ */
+
+params ["_action", "_actionParams"];
+_action params ["", "", "", "", "", "", "_args"];
+_actionParams params ["", "", "", "", "", "_hoveredEntity"];
+
+private _weapon = [
+    primaryWeapon _hoveredEntity,
+    handgunWeapon _hoveredEntity,
+    binocular _hoveredEntity
+] select _args;
+
+private _cfgWeapons = configFile >> "CfgWeapons" >> _weapon;
+
+private _displayName = getText (_cfgWeapons >> "displayName");
+
+if (_displayName != "") then {
+    _action set [1, _displayName];
+};
+
+private _picture = getText (_cfgWeapons >> "picture");
+
+if (_picture != "") then {
+    _action set [2, _picture];
+};

docs/user_guide/context_actions.md

@@ -57,6 +57,7 @@ The main action acts as a shortcut for the "Edit" sub-action.
 
 Opens the preferred arsenal type (specified in CBA settings) on the hovered unit.
 Sub-actions allow for copying and pasting the hovered unit's loadout onto another and resetting the unit's loadout to the config defined one.
+Furthermore, the unit's current weapon can be switched between their rifle, handgun, or binoculars.
 The main action acts as a shortcut for the "Edit" sub-action.
 
 ## Remote Control