build.gradle.kts

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    kotlin("jvm") apply false
    `maven-publish`
    signing

}



subprojects {
    version = extra["project.version"]!!.toString()
    group = extra["project.group"]!!.toString()

    tasks.withType<JavaCompile> {
        sourceCompatibility = "1.8"
    }

    tasks.withType<KotlinCompile> {
        kotlinOptions {
            freeCompilerArgs += "-Xjsr305=strict"
            jvmTarget = "1.8"
        }
    }

    apply(plugin = "org.gradle.maven-publish")
    apply(plugin = "org.gradle.signing")
    apply(plugin = "java")

    tasks.withType<Jar> {
        archiveClassifier.set("")
    }

    extensions.getByType<JavaPluginExtension>().run {
        withSourcesJar()
        withJavadocJar()
    }

    val projectUrl = extra["project.url"]!!.toString()
    val projectDescription = extra["project.description"]!!.toString()
    val projectLicense = extra["project.license"]!!.toString()
    val projectLicenseUrl = extra["project.license.url"]!!.toString()
    val projectDeveloperId = extra["project.developer.id"]!!.toString()
    val projectDeveloperName = extra["project.developer.name"]!!.toString()
    val projectDeveloperEmail = extra["project.developer.email"]!!.toString()
    val projectUrlScm = extra["project.url.scm"]!!.toString()

    fun setupPom(mavenPom: MavenPom) {
        with(mavenPom) {
            name.set(project.rootProject.name)
            url.set(projectUrl)
            description.set(projectDescription)

            licenses {
                license {
                    name.set(projectLicense)
                    url.set(projectLicenseUrl)
                }
            }
            developers {
                developer {
                    id.set(projectDeveloperId)
                    name.set(projectDeveloperName)
                    email.set(projectDeveloperEmail)
                }
                scm {
                    url.set(projectUrlScm)
                }
            }
        }
    }
    publishing {
        publications {
            create<MavenPublication>("mavenCentral") {
                this.groupId = extra["project.group"]!!.toString()
                this.version = extra["project.version"]!!.toString()
                this.artifactId = project.name.lowercase()
                from(components["java"])

                setupPom(pom)

                signing {
                    sign(this@publications)
                }
            }
        }
        repositories {
            maven {
                name = "sonatype"
                setUrl("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/")
                credentials {
                    username = System.getenv("OSSRH_USERNAME")
                    password = System.getenv("OSSRH_PASSWORD")
                }
            }
        }
    }

    signing {
        setRequired {
            !project.version.toString()
                .contains("-SNAPSHOT") && gradle.taskGraph.allTasks.any { it is PublishToMavenRepository }
        }
        if (!extra.has("signing.keyId")) {
            extra["signing.keyId"] = System.getenv("SIGNING_KEY_ID")
        }
        if (!extra.has("signing.password")) {
            extra["signing.password"] = System.getenv("SIGNING_PASSPHRASE")
        }
        if (!extra.has("signing.secretKeyRingFile")) {
            extra["signing.secretKeyRingFile"] =
                if (System.getenv("SIGNING_SECRET_KEY_RING_FILE_ABSOLUTE") != null) {
                    System.getenv("SIGNING_SECRET_KEY_RING_FILE_ABSOLUTE")
                } else {
                    System.getenv("HOME") + "/" + System.getenv("SIGNING_SECRET_KEY_RING_FILE")
                }
        }
        sign(extensions.getByType(PublishingExtension::class).publications)
    }

    tasks.withType(GenerateMavenPom::class.java) {
        doFirst {
            setupPom(pom)
        }
    }

    tasks.withType(PublishToMavenRepository::class.java) {
        dependsOn(tasks.withType<Sign>())
    }
}