diff --git a/docs/literate/src/files/first_steps/changing_trixi.jl b/docs/literate/src/files/first_steps/changing_trixi.jl
new file mode 100644
index 0000000000..551377a6a7
--- /dev/null
+++ b/docs/literate/src/files/first_steps/changing_trixi.jl
@@ -0,0 +1,77 @@
+#src # Changing Trixi.jl itself
+
+# If you plan on editing Trixi.jl itself, you can download Trixi.jl locally and run it from
+# the cloned directory.
+
+
+# ## Cloning Trixi.jl
+
+
+# ### Windows
+
+# If you are using Windows, you can clone Trixi.jl by using the GitHub Desktop tool:
+# - If you do not have a GitHub account yet, create it on
+#   the [GitHub website](https://github.com/join).
+# - Download and install [GitHub Desktop](https://desktop.github.com/) and then log in to
+#   your account.
+# - Open GitHub Desktop, press `Ctrl+Shift+O`.
+# - In the opened window, paste `trixi-framework/Trixi.jl` and choose the path to the folder where
+#   you want to save Trixi.jl. Then click `Clone` and Trixi.jl will be cloned to your computer. 
+
+# Now you cloned Trixi.jl and only need to tell Julia to use the local clone as the package sources:
+# - Open a terminal using `Win+r` and `cmd`. Navigate to the folder with the cloned Trixi.jl using `cd`.
+# - Create a new directory `run`, enter it, and start Julia with the `--project=.` flag:
+#   ```shell
+#   mkdir run 
+#   cd run
+#   julia --project=.
+#   ```
+# - Now run the following commands to install all relevant packages:
+#   ```julia
+#   using Pkg; Pkg.develop(PackageSpec(path="..")) # Tell Julia to use the local Trixi.jl clone
+#   Pkg.add(["OrdinaryDiffEq", "Plots"])  # Install additional packages
+#   ```
+
+# Now you already installed Trixi.jl from your local clone. Note that if you installed Trixi.jl
+# this way, you always have to start Julia with the `--project` flag set to your `run` directory,
+# e.g.,
+# ```shell
+# julia --project=.
+# ```
+# if already inside the `run` directory.
+
+
+# ### Linux
+
+# You can clone Trixi.jl to your computer by executing the following commands:
+# ```shell
+# git clone git@github.com:trixi-framework/Trixi.jl.git 
+# # If an error occurs, try the following:
+# # git clone https://github.com/trixi-framework/Trixi.jl
+# cd Trixi.jl
+# mkdir run 
+# cd run
+# julia --project=. -e 'using Pkg; Pkg.develop(PackageSpec(path=".."))' # Tell Julia to use the local Trixi.jl clone
+# julia --project=. -e 'using Pkg; Pkg.add(["OrdinaryDiffEq", "Plots"])' # Install additional packages
+# ```
+# Note that if you installed Trixi.jl this way,
+# you always have to start Julia with the `--project` flag set to your `run` directory, e.g.,
+# ```shell
+# julia --project=.
+# ```
+# if already inside the `run` directory.
+
+
+# ## Additional reading
+
+# To further delve into Trixi.jl, you may have a look at the following introductory tutorials.
+# - [Introduction to DG methods](@ref scalar_linear_advection_1d) will teach you how to set up a
+#   simple way to approximate the solution of a hyperbolic partial differential equation. It will
+#   be especially useful to learn about the 
+#   [Discontinuous Galerkin method](https://en.wikipedia.org/wiki/Discontinuous_Galerkin_method)
+#   and the way it is implemented in Trixi.jl.
+# - [Adding a new scalar conservation law](@ref adding_new_scalar_equations) and
+#   [Adding a non-conservative equation](@ref adding_nonconservative_equation)
+#   describe how to add new physics models that are not yet included in Trixi.jl.
+# - [Callbacks](@ref callbacks-id) gives an overview of how to regularly execute specific actions
+#   during a simulation, e.g., to store the solution or adapt the mesh.
diff --git a/docs/literate/src/files/first_steps/create_first_setup.jl b/docs/literate/src/files/first_steps/create_first_setup.jl
new file mode 100644
index 0000000000..906a6f9346
--- /dev/null
+++ b/docs/literate/src/files/first_steps/create_first_setup.jl
@@ -0,0 +1,268 @@
+#src # Create first setup
+
+# In this part of the introductory guide, we will create a first Trixi.jl setup as an extension of
+# [`elixir_advection_basic.jl`](https://github.com/trixi-framework/Trixi.jl/blob/main/examples/tree_2d_dgsem/elixir_advection_basic.jl).
+# Since Trixi.jl has a common basic structure for the setups, you can create your own by extending
+# and modifying the following example.
+
+# Let's consider the linear advection equation for a state ``u = u(x, y, t)`` on the two-dimensional spatial domain
+# ``[-1, 1] \times [-1, 1]`` with a source term
+# ```math
+# \frac{\partial}{\partial t}u + \frac{\partial}{\partial x} (0.2 u) - \frac{\partial}{\partial y} (0.7 u) = - 2 e^{-t}
+# \sin\bigl(2 \pi (x - t) \bigr) \sin\bigl(2 \pi (y - t) \bigr),
+# ```
+# with the initial condition
+# ```math
+# u(x, y, 0) = \sin\bigl(\pi x \bigr) \sin\bigl(\pi y \bigr),
+# ```
+# and periodic boundary conditions.
+
+# The first step is to create and open a file with the .jl extension. You can do this with your
+# favorite text editor (if you do not have one, we recommend [VS Code](https://code.visualstudio.com/)).
+# In this file you will create your setup.
+
+# To be able to use functionalities of Trixi.jl, you always need to load Trixi.jl itself
+# and the [OrdinaryDiffEq.jl](https://github.com/SciML/OrdinaryDiffEq.jl) package.
+
+using Trixi
+using OrdinaryDiffEq
+
+# The next thing to do is to choose an equation that is suitable for your problem. To see all the
+# currently implemented equations, take a look at
+# [`src/equations`](https://github.com/trixi-framework/Trixi.jl/tree/main/src/equations).
+# If you are interested in adding a new physics model that has not yet been implemented in
+# Trixi.jl, take a look at the tutorials
+# [Adding a new scalar conservation law](@ref adding_new_scalar_equations) or
+# [Adding a non-conservative equation](@ref adding_nonconservative_equation).
+
+# The linear scalar advection equation in two spatial dimensions
+# ```math
+# \frac{\partial}{\partial t}u + \frac{\partial}{\partial x} (a_1 u) + \frac{\partial}{\partial y} (a_2 u) = 0
+# ```
+# is already implemented in Trixi.jl as
+# [`LinearScalarAdvectionEquation2D`](@ref), for which we need to define a two-dimensional parameter
+# `advection_velocity` describing the parameters ``a_1`` and ``a_2``. Appropriate for our problem is `(0.2, -0.7)`.
+
+advection_velocity = (0.2, -0.7)
+equations = LinearScalarAdvectionEquation2D(advection_velocity)
+
+# To solve our problem numerically using Trixi.jl, we have to discretize the spatial
+# domain, for which we set up a mesh. One of the most used meshes in Trixi.jl is the
+# [`TreeMesh`](@ref). The spatial domain used is ``[-1, 1] \times [-1, 1]``. We set an initial number
+# of elements in the mesh using `initial_refinement_level`, which describes the initial number of
+# hierarchical refinements. In this simple case, the total number of elements is `2^initial_refinement_level`
+# throughout the simulation. The variable `n_cells_max` is used to limit the number of elements in the mesh,
+# which cannot be exceeded when using [adaptive mesh refinement](@ref Adaptive-mesh-refinement).
+
+# All minimum and all maximum coordinates must be combined into `Tuples`.
+
+coordinates_min = (-1.0, -1.0)
+coordinates_max = ( 1.0,  1.0)
+mesh = TreeMesh(coordinates_min, coordinates_max,
+                initial_refinement_level = 4,
+                n_cells_max = 30_000)
+
+# To approximate the solution of the defined model, we create a [`DGSEM`](@ref) solver.
+# The solution in each of the recently defined mesh elements will be approximated by a polynomial
+# of degree `polydeg`. For more information about discontinuous Galerkin methods,
+# check out the [Introduction to DG methods](@ref scalar_linear_advection_1d) tutorial.
+
+solver = DGSEM(polydeg=3)
+
+# Now we need to define an initial condition for our problem. All the already implemented
+# initial conditions for [`LinearScalarAdvectionEquation2D`](@ref) can be found in
+# [`src/equations/linear_scalar_advection_2d.jl`](https://github.com/trixi-framework/Trixi.jl/blob/main/src/equations/linear_scalar_advection_2d.jl).
+# If you want to use, for example, a Gaussian pulse, it can be used as follows:
+# ```julia
+# initial_conditions = initial_condition_gauss
+# ```
+# But to show you how an arbitrary initial condition can be implemented in a way suitable for
+# Trixi.jl, we define our own initial conditions.
+# ```math
+# u(x, y, 0) = \sin\bigl(\pi x \bigr) \sin\bigl(\pi y \bigr).
+# ```
+# The initial conditions function must take spatial coordinates, time and equation as arguments
+# and returns an initial condition as a statically sized vector `SVector`. Following the same structure, you
+# can define your own initial conditions. The time variable `t` can be unused in the initial
+# condition, but might also be used to describe an analytical solution if known. If you use the
+# initial condition as analytical solution, you can analyze your numerical solution by computing
+# the error, see also the
+# [section about analyzing the solution](https://trixi-framework.github.io/Trixi.jl/stable/callbacks/#Analyzing-the-numerical-solution).
+
+function initial_condition_sinpi(x, t, equations::LinearScalarAdvectionEquation2D)
+    scalar = sinpi(x[1]) * sinpi(x[2])
+    return SVector(scalar)
+end
+initial_condition = initial_condition_sinpi
+
+# The next step is to define a function of the source term corresponding to our problem.
+# ```math
+# f(u, x, y, t) = - 2 e^{-t} \sin\bigl(2 \pi (x - t) \bigr) \sin\bigl(2 \pi (y - t) \bigr)
+# ```
+# This function must take the state variable, the spatial coordinates, the time and the
+# equation itself as arguments and returns the source term as a static vector `SVector`.
+
+function source_term_exp_sinpi(u, x, t, equations::LinearScalarAdvectionEquation2D)
+    scalar = - 2 * exp(-t) * sinpi(2*(x[1] - t)) * sinpi(2*(x[2] - t))
+    return SVector(scalar)
+end
+
+# Now we collect all the information that is necessary to define a spatial discretization,
+# which leaves us with an ODE problem in time with a span from 0.0 to 1.0.
+# This approach is commonly referred to as the method of lines. 
+
+semi = SemidiscretizationHyperbolic(mesh, equations, initial_condition, solver;
+                                    source_terms = source_term_exp_sinpi)
+tspan = (0.0, 1.0)
+ode = semidiscretize(semi, tspan);
+
+# At this point, our problem is defined. We will use the `solve` function defined in
+# [OrdinaryDiffEq.jl](https://github.com/SciML/OrdinaryDiffEq.jl) to get the solution.
+# OrdinaryDiffEq.jl gives us the ability to customize the solver
+# using callbacks without actually modifying it. Trixi.jl already has some implemented
+# [Callbacks](@ref callbacks-id). The most widely used callbacks in Trixi.jl are
+# [step control callbacks](https://docs.sciml.ai/DiffEqCallbacks/stable/step_control/) that are
+# activated at the end of each time step to perform some actions, e.g. to print statistics.
+# We will show you how to use some of the common callbacks.
+
+# To print a summary of the simulation setup at the beginning
+# and to reset timers we use the [`SummaryCallback`](@ref).
+# When the returned callback is executed directly, the current timer values are shown.
+
+summary_callback = SummaryCallback()
+
+# We also want to analyze the current state of the solution in regular intervals.
+# The [`AnalysisCallback`](@ref) outputs some useful statistical information during the solving process
+# every `interval` time steps.
+
+analysis_callback = AnalysisCallback(semi, interval = 5)
+
+# It is also possible to control the time step size using the [`StepsizeCallback`](@ref) if the time
+# integration method isn't adaptive itself. To get more details, look at
+# [CFL based step size control](@ref CFL-based-step-size-control).
+
+stepsize_callback = StepsizeCallback(cfl = 1.6)
+
+# To save the current solution in regular intervals we use the [`SaveSolutionCallback`](@ref).
+# We would like to save the initial and final solutions as well. The data
+# will be saved as HDF5 files located in the `out` folder. Afterwards it is possible to visualize
+# a solution from saved files using Trixi2Vtk.jl and ParaView, which is described below in the
+# section [Visualize the solution](@ref Visualize-the-solution).
+
+save_solution = SaveSolutionCallback(interval = 5,
+                                     save_initial_solution = true,
+                                     save_final_solution = true)
+
+# Alternatively, we have the option to print solution files at fixed time intervals. 
+# ```julua
+# save_solution = SaveSolutionCallback(dt = 0.1,
+#                                      save_initial_solution = true,
+#                                      save_final_solution = true)
+# ```
+
+# Another useful callback is the [`SaveRestartCallback`](@ref). It saves information for restarting
+# in regular intervals. We are interested in saving a restart file for the final solution as
+# well. To perform a restart, you need to configure the restart setup in a special way, which is
+# described in the section [Restart simulation](@ref restart).
+
+save_restart = SaveRestartCallback(interval = 100, save_final_restart = true)
+
+# Create a `CallbackSet` to collect all callbacks so that they can be passed to the `solve`
+# function.
+
+callbacks = CallbackSet(summary_callback, analysis_callback, stepsize_callback, save_solution,
+                        save_restart)
+
+# The last step is to choose the time integration method. OrdinaryDiffEq.jl defines a wide range of
+# [ODE solvers](https://docs.sciml.ai/DiffEqDocs/latest/solvers/ode_solve/), e.g.
+# `CarpenterKennedy2N54(williamson_condition = false)`. We will pass the ODE
+# problem, the ODE solver and the callbacks to the `solve` function. Also, to use
+# `StepsizeCallback`, we must explicitly specify the initial trial time step `dt`, the selected
+# value is not important, because it will be overwritten by the `StepsizeCallback`. And there is no
+# need to save every step of the solution, we are only interested in the final result.
+
+sol = solve(ode, CarpenterKennedy2N54(williamson_condition = false), dt = 1.0,
+            save_everystep = false, callback = callbacks);
+
+# Finally, we print the timer summary.
+
+summary_callback()
+
+# Now you can plot the solution as shown below, analyze it and improve the stability, accuracy or
+# efficiency of your setup.
+
+
+# ## Visualize the solution
+
+# In the previous part of the tutorial, we calculated the final solution of the given problem, now we want
+# to visualize it. A more detailed explanation of visualization methods can be found in the section
+# [Visualization](@ref visualization).
+
+
+# ### Using Plots.jl
+
+# The first option is to use the [Plots.jl](https://github.com/JuliaPlots/Plots.jl) package
+# directly after calculations, when the solution is saved in the `sol` variable. We load the
+# package and use the `plot` function.
+
+using Plots
+plot(sol)
+
+# To show the mesh on the plot, we need to extract the visualization data from the solution as
+# a [`PlotData2D`](@ref) object. Mesh extraction is possible using the [`getmesh`](@ref) function.
+# Plots.jl has the `plot!` function that allows you to modify an already built graph.
+
+pd = PlotData2D(sol)
+plot!(getmesh(pd))
+
+
+# ### Using Trixi2Vtk.jl
+
+# Another way to visualize a solution is to extract it from a saved HDF5 file. After we used the
+# `solve` function with [`SaveSolutionCallback`](@ref) there is a file with the final solution.
+# It is located in the `out` folder and is named as follows: `solution_index.h5`. The `index`
+# is the final time step of the solution that is padded to 6 digits with zeros from the beginning.
+# With [Trixi2Vtk](@ref) you can convert the HDF5 output file generated by Trixi.jl into a VTK file.
+# This can be used in visualization tools such as [ParaView](https://www.paraview.org) or
+# [VisIt](https://visit.llnl.gov) to plot the solution. The important thing is that currently
+# Trixi2Vtk.jl supports conversion only for solutions in 2D and 3D spatial domains.
+
+# If you haven't added Trixi2Vtk.jl to your project yet, you can add it as follows.
+# ```julia
+# import Pkg
+# Pkg.add(["Trixi2Vtk"])
+# ```
+# Now we load the Trixi2Vtk.jl package and convert the file `out/solution_000018.h5` with
+# the final solution using the [`trixi2vtk`](@ref) function saving the resulting file in the
+# `out` folder.
+
+using Trixi2Vtk
+trixi2vtk(joinpath("out", "solution_000018.h5"), output_directory="out")
+
+# Now two files `solution_000018.vtu` and `solution_000018_celldata.vtu` have been generated in the
+# `out` folder. The first one contains all the information for visualizing the solution, the
+# second one contains all the cell-based or discretization-based information.
+
+# Now let's visualize the solution from the generated files in ParaView. Follow this short
+# instruction to get the visualization.
+# - Download, install and open [ParaView](https://www.paraview.org/download/).
+# - Press `Ctrl+O` and select the generated files `solution_000018.vtu` and
+#   `solution_000018_celldata.vtu` from the `out` folder.
+# - In the upper-left corner in the Pipeline Browser window, left-click on the eye-icon near
+#   `solution_000018.vtu`.
+# - In the lower-left corner in the Properties window, change the Coloring from Solid Color to
+#   scalar. This already generates the visualization of the final solution.
+# - Now let's add the mesh to the visualization. In the upper-left corner in the
+#   Pipeline Browser window, left-click on the eye-icon near `solution_000018_celldata.vtu`.
+# - In the lower-left corner in the Properties window, change the Representation from Surface
+#   to Wireframe. Then a white grid should appear on the visualization.
+# Now, if you followed the instructions exactly, you should get a similar image as shown in the
+# section [Using Plots.jl](@ref Using-Plots.jl):
+
+# ![paraview_trixi2vtk_example](https://github.com/trixi-framework/Trixi.jl/assets/119304909/0c29139b-6c5d-4d5c-86e1-f4ebc95aca7e)
+
+# After completing this tutorial you are able to set up your own simulations with
+# Trixi.jl. If you have an interest in contributing to Trixi.jl as a developer, refer to the third
+# part of the introduction titled [Changing Trixi.jl itself](@ref changing_trixi).
+
+Sys.rm("out"; recursive=true, force=true) #hide #md
\ No newline at end of file
diff --git a/docs/literate/src/files/first_steps/getting_started.jl b/docs/literate/src/files/first_steps/getting_started.jl
new file mode 100644
index 0000000000..2bfaf33b5f
--- /dev/null
+++ b/docs/literate/src/files/first_steps/getting_started.jl
@@ -0,0 +1,242 @@
+#src # Getting started
+
+# Trixi.jl is a numerical simulation framework for conservation laws and
+# is written in the [Julia programming language](https://julialang.org/).
+# This tutorial is intended for beginners in Julia and Trixi.jl.
+# After reading it, you will know how to install Julia and Trixi.jl on your computer,
+# and you will be able to download setup files from our GitHub repository, modify them,
+# and run simulations.
+
+# The contents of this tutorial:
+# - [Julia installation](@ref Julia-installation)
+# - [Trixi.jl installation](@ref Trixi.jl-installation)
+# - [Running a simulation](@ref Running-a-simulation)
+# - [Getting an existing setup file](@ref Getting-an-existing-setup-file)
+# - [Modifying an existing setup](@ref Modifying-an-existing-setup)
+
+
+# ## Julia installation
+
+# Trixi.jl is compatible with the latest stable release of Julia. Additional details regarding Julia
+# support can be found in the [`README.md`](https://github.com/trixi-framework/Trixi.jl#installation)
+# file. The current default Julia installation is managed through `juliaup`. You may follow our
+# concise installation guidelines for Windows, Linux, and MacOS provided below. In the event of any
+# issues during the installation process, please consult the official
+# [Julia installation instruction](https://julialang.org/downloads/).
+
+
+# ### Windows
+
+# - Open a terminal by pressing `Win+r` and entering `cmd` in the opened window.
+# - To install Julia, execute the following command in the terminal:
+#   ```shell
+#   winget install julia -s msstore
+#   ```
+# - Verify the successful installation of Julia by executing the following command in the terminal:
+#   ```shell
+#   julia
+#   ```
+#   To exit Julia, execute `exit()` or press `Ctrl+d`.
+
+
+# ### Linux and MacOS
+
+# - To install Julia, run the following command in a terminal:
+#   ```shell
+#   curl -fsSL https://install.julialang.org | sh
+#   ```
+#   Follow the instructions displayed in the terminal during the installation process.
+# - If an error occurs during the execution of the previous command, you may need to install
+#   `curl`. On Ubuntu-type systems, you can use the following command:
+#   ```shell
+#   sudo apt install curl
+#   ```
+#   After installing `curl`, repeat the first step once more to proceed with Julia installation.
+# - Verify the successful installation of Julia by executing the following command in the terminal:
+#   ```shell
+#   julia
+#   ```
+#   To exit Julia, execute `exit()` or press `Ctrl+d`.
+
+
+# ## Trixi.jl installation
+
+# Trixi.jl and its related tools are registered Julia packages, thus their installation
+# happens inside Julia.
+# For a smooth workflow experience with Trixi.jl, you need to install 
+# [Trixi.jl](https://github.com/trixi-framework/Trixi.jl),
+# [OrdinaryDiffEq.jl](https://github.com/SciML/OrdinaryDiffEq.jl), and 
+# [Plots.jl](https://github.com/JuliaPlots/Plots.jl).
+
+# - Open a terminal and start Julia.
+# - Execute following commands:
+#   ```julia
+#   import Pkg
+#   Pkg.add(["OrdinaryDiffEq", "Plots", "Trixi"])
+#   ```
+
+# Now you have installed all these 
+# packages. [OrdinaryDiffEq.jl](https://github.com/SciML/OrdinaryDiffEq.jl) provides time
+# integration schemes used by Trixi.jl and [Plots.jl](https://github.com/JuliaPlots/Plots.jl)
+# can be used to directly visualize Trixi.jl results from the Julia REPL.
+
+
+# ## Usage
+
+
+# ### Running a simulation
+
+# To get you started, Trixi.jl has a large set
+# of [example setups](https://github.com/trixi-framework/Trixi.jl/tree/main/examples), that can be
+# taken as a basis for your future investigations. In Trixi.jl, we call these setup files
+# "elixirs", since they contain Julia code that takes parts of Trixi.jl and combines them into
+# something new.
+
+# Any of the examples can be executed using the [`trixi_include`](@ref)
+# function. `trixi_include(...)` expects
+# a single string argument with a path to a file containing Julia code.
+# For convenience, the [`examples_dir`](@ref) function returns a path to the
+# [`examples`](https://github.com/trixi-framework/Trixi.jl/tree/main/examples)
+# folder, which has been locally downloaded while installing Trixi.jl.
+# `joinpath(...)` can be used to join path components into a full path. 
+
+# Let's execute a short two-dimensional problem setup. It approximates the solution of
+# the compressible Euler equations in 2D for an ideal gas ([`CompressibleEulerEquations2D`](@ref))
+# with a weak blast wave as the initial condition.
+
+# Start Julia in a terminal and execute the following code:
+
+# ```julia
+# using Trixi, OrdinaryDiffEq
+# trixi_include(joinpath(examples_dir(), "tree_2d_dgsem", "elixir_euler_ec.jl"))
+# ```
+using Trixi, OrdinaryDiffEq #hide #md
+trixi_include(@__MODULE__,joinpath(examples_dir(), "tree_2d_dgsem", "elixir_euler_ec.jl")) #hide #md
+
+# To analyze the result of the computation, we can use the Plots.jl package and the function 
+# `plot(...)`, which creates a graphical representation of the solution. `sol` is a variable
+# defined in the executed example and it contains the solution at the final moment of the simulation.
+
+using Plots
+plot(sol)
+
+# To obtain a list of all Trixi.jl elixirs execute
+# [`get_examples`](@ref). It returns the paths to all example setups.
+
+get_examples()
+
+# Editing an existing elixir is the best way to start your first own investigation using Trixi.jl.
+
+
+# ### Getting an existing setup file
+
+# To edit an existing elixir, you first have to find a suitable one and then copy it to a local
+# folder. Let's have a look at how to download the `elixir_euler_ec.jl` elixir used in the previous
+# section from the [Trixi.jl GitHub repository](https://github.com/trixi-framework/Trixi.jl).
+
+# - All examples are located inside
+#   the [`examples`](https://github.com/trixi-framework/Trixi.jl/tree/main/examples) folder.
+# - Navigate to the
+#   file [`elixir_euler_ec.jl`](https://github.com/trixi-framework/Trixi.jl/blob/main/examples/tree_2d_dgsem/elixir_euler_ec.jl).
+# - Right-click the `Raw` button on the right side of the webpage and choose `Save as...`
+#   (or `Save Link As...`).
+# - Choose a folder and save the file.
+
+
+# ### Modifying an existing setup
+
+# As an example, we will change the initial condition for calculations that occur in
+# `elixir_euler_ec.jl`. In this example we consider the compressible Euler equations in two spatial
+# dimensions,
+# ```math
+# \frac{\partial}{\partial t}
+# \begin{pmatrix}
+# \rho \\ \rho v_1 \\ \rho v_2 \\ \rho e
+# \end{pmatrix}
+# +
+# \frac{\partial}{\partial x}
+# \begin{pmatrix}
+# \rho v_1 \\ \rho v_1^2 + p \\ \rho v_1 v_2 \\ (\rho e + p) v_1
+# \end{pmatrix}
+# +
+# \frac{\partial}{\partial y}
+# \begin{pmatrix}
+# \rho v_2 \\ \rho v_1 v_2 \\ \rho v_2^2 + p \\ (\rho e + p) v_2
+# \end{pmatrix}
+# =
+# \begin{pmatrix}
+# 0 \\ 0 \\ 0 \\ 0
+# \end{pmatrix},
+# ```
+# for an ideal gas with the specific heat ratio ``\gamma``.
+# Here, ``\rho`` is the density, ``v_1`` and ``v_2`` are the velocities, ``e`` is the specific
+# total energy, and
+# ```math
+# p = (\gamma - 1) \left( \rho e - \frac{1}{2} \rho (v_1^2 + v_2^2) \right)
+# ```
+# is the pressure.
+# Initial conditions consist of initial values for ``\rho``, ``\rho v_1``,
+# ``\rho v_2`` and ``\rho e``.
+# One of the common initial conditions for the compressible Euler equations is a simple density
+# wave. Let's implement it.
+
+# - Open the downloaded file `elixir_euler_ec.jl` with a text editor.
+# - Go to the line with the following code:
+#   ```julia
+#   initial_condition = initial_condition_weak_blast_wave
+#   ```
+#   Here, [`initial_condition_weak_blast_wave`](@ref) is used as the initial condition.
+# - Comment out the line using the `#` symbol:
+#   ```julia
+#   # initial_condition = initial_condition_weak_blast_wave
+#   ```
+# - Now you can create your own initial conditions. Add the following code after the
+#   commented line:
+
+function initial_condition_density_waves(x, t, equations::CompressibleEulerEquations2D)
+    v1 = 0.1 # velocity along x-axis
+    v2 = 0.2 # velocity along y-axis
+    rho = 1.0 + 0.98 * sinpi(sum(x) - t * (v1 + v2)) # density wave profile
+    p = 20 # pressure
+    rho_e = p / (equations.gamma - 1) + 1/2 * rho * (v1^2 + v2^2)
+    return SVector(rho, rho*v1, rho*v2, rho_e)
+end
+initial_condition = initial_condition_density_waves
+
+# - Execute the following code one more time, but instead of `path/to/file` paste the path to the
+#   `elixir_euler_ec.jl` file that you just edited.
+#   ```julia
+#   using Trixi
+#   trixi_include(path/to/file)
+#   using Plots
+#   plot(sol)
+#   ```
+# Then you will obtain a new solution from running the simulation with a different initial
+# condition.
+
+trixi_include(@__MODULE__,joinpath(examples_dir(), "tree_2d_dgsem", "elixir_euler_ec.jl"), #hide #md
+ initial_condition=initial_condition) #hide #md
+pd = PlotData2D(sol) #hide #md
+p1 = plot(pd["rho"]) #hide #md
+p2 = plot(pd["v1"], clim=(0.05, 0.15)) #hide #md
+p3 = plot(pd["v2"], clim=(0.15, 0.25)) #hide #md
+p4 = plot(pd["p"], clim=(10, 30)) #hide #md
+plot(p1, p2, p3, p4) #hide #md
+
+# To get exactly the same picture execute the following.
+# ```julia
+# pd = PlotData2D(sol)
+# p1 = plot(pd["rho"])
+# p2 = plot(pd["v1"], clim=(0.05, 0.15))
+# p3 = plot(pd["v2"], clim=(0.15, 0.25))
+# p4 = plot(pd["p"], clim=(10, 30))
+# plot(p1, p2, p3, p4)
+# ```
+
+# Feel free to make further changes to the initial condition to observe different solutions.
+
+# Now you are able to download, modify and execute simulation setups for Trixi.jl. To explore
+# further details on setting up a new simulation with Trixi.jl, refer to the second part of
+# the introduction titled [Create first setup](@ref create_first_setup).
+
+Sys.rm("out"; recursive=true, force=true) #hide #md
\ No newline at end of file
diff --git a/docs/literate/src/files/index.jl b/docs/literate/src/files/index.jl
index 26637e5b24..1fc025d84d 100644
--- a/docs/literate/src/files/index.jl
+++ b/docs/literate/src/files/index.jl
@@ -14,20 +14,27 @@
 
 # There are tutorials for the following topics:
 
-# ### [1 Introduction to DG methods](@ref scalar_linear_advection_1d)
+# ### [1 First steps in Trixi.jl](@ref getting_started)
+#-
+# This tutorial provides guidance for getting started with Trixi.jl, and Julia as well. It outlines
+# the installation procedures for both Julia and Trixi.jl, the execution of Trixi.jl elixirs, the
+# fundamental structure of a Trixi.jl setup, the visualization of results, and the development
+# process for Trixi.jl.
+
+# ### [2 Introduction to DG methods](@ref scalar_linear_advection_1d)
 #-
 # This tutorial gives an introduction to discontinuous Galerkin (DG) methods with the example of the
 # scalar linear advection equation in 1D. Starting with some theoretical explanations, we first implement
 # a raw version of a discontinuous Galerkin spectral element method (DGSEM). Then, we will show how
 # to use features of Trixi.jl to achieve the same result.
 
-# ### [2 DGSEM with flux differencing](@ref DGSEM_FluxDiff)
+# ### [3 DGSEM with flux differencing](@ref DGSEM_FluxDiff)
 #-
 # To improve stability often the flux differencing formulation of the DGSEM (split form) is used.
 # We want to present the idea and formulation on a basic 1D level. Then, we show how this formulation
 # can be implemented in Trixi.jl and analyse entropy conservation for two different flux combinations.
 
-# ### [3 Shock capturing with flux differencing and stage limiter](@ref shock_capturing)
+# ### [4 Shock capturing with flux differencing and stage limiter](@ref shock_capturing)
 #-
 # Using the flux differencing formulation, a simple procedure to capture shocks is a hybrid blending
 # of a high-order DG method and a low-order subcell finite volume (FV) method. We present the idea on a
@@ -35,20 +42,20 @@
 # explained and added to an exemplary simulation of the Sedov blast wave with the 2D compressible Euler
 # equations.
 
-# ### [4 Non-periodic boundary conditions](@ref non_periodic_boundaries)
+# ### [5 Non-periodic boundary conditions](@ref non_periodic_boundaries)
 #-
 # Thus far, all examples used periodic boundaries. In Trixi.jl, you can also set up a simulation with
 # non-periodic boundaries. This tutorial presents the implementation of the classical Dirichlet
 # boundary condition with a following example. Then, other non-periodic boundaries are mentioned.
 
-# ### [5 DG schemes via `DGMulti` solver](@ref DGMulti_1)
+# ### [6 DG schemes via `DGMulti` solver](@ref DGMulti_1)
 #-
 # This tutorial is about the more general DG solver [`DGMulti`](@ref), introduced [here](@ref DGMulti).
 # We are showing some examples for this solver, for instance with discretization nodes by Gauss or
 # triangular elements. Moreover, we present a simple way to include pre-defined triangulate meshes for
 # non-Cartesian domains using the package [StartUpDG.jl](https://github.com/jlchan/StartUpDG.jl).
 
-# ### [6 Other SBP schemes (FD, CGSEM) via `DGMulti` solver](@ref DGMulti_2)
+# ### [7 Other SBP schemes (FD, CGSEM) via `DGMulti` solver](@ref DGMulti_2)
 #-
 # Supplementary to the previous tutorial about DG schemes via the `DGMulti` solver we now present
 # the possibility for `DGMulti` to use other SBP schemes via the package
@@ -56,7 +63,7 @@
 # For instance, we show how to set up a finite differences (FD) scheme and a continuous Galerkin
 # (CGSEM) method.
 
-# ### [7 Upwind FD SBP schemes](@ref upwind_fdsbp)
+# ### [8 Upwind FD SBP schemes](@ref upwind_fdsbp)
 #-
 # General SBP schemes can not only be used via the [`DGMulti`](@ref) solver but
 # also with a general `DG` solver. In particular, upwind finite difference SBP
@@ -64,42 +71,42 @@
 # schemes in the `DGMulti` framework, the interface is based on the package
 # [SummationByPartsOperators.jl](https://github.com/ranocha/SummationByPartsOperators.jl).
 
-# ### [8 Adding a new scalar conservation law](@ref adding_new_scalar_equations)
+# ### [9 Adding a new scalar conservation law](@ref adding_new_scalar_equations)
 #-
 # This tutorial explains how to add a new physics model using the example of the cubic conservation
 # law. First, we define the equation using a `struct` `CubicEquation` and the physical flux. Then,
 # the corresponding standard setup in Trixi.jl (`mesh`, `solver`, `semi` and `ode`) is implemented
 # and the ODE problem is solved by OrdinaryDiffEq's `solve` method.
 
-# ### [9 Adding a non-conservative equation](@ref adding_nonconservative_equation)
+# ### [10 Adding a non-conservative equation](@ref adding_nonconservative_equation)
 #-
 # In this part, another physics model is implemented, the nonconservative linear advection equation.
 # We run two different simulations with different levels of refinement and compare the resulting errors.
 
-# ### [10 Parabolic terms](@ref parabolic_terms)
+# ### [11 Parabolic terms](@ref parabolic_terms)
 #-
 # This tutorial describes how parabolic terms are implemented in Trixi.jl, e.g.,
 # to solve the advection-diffusion equation.
 
-# ### [11 Adding new parabolic terms](@ref adding_new_parabolic_terms)
+# ### [12 Adding new parabolic terms](@ref adding_new_parabolic_terms)
 #-
 # This tutorial describes how new parabolic terms can be implemented using Trixi.jl.
 
-# ### [12 Adaptive mesh refinement](@ref adaptive_mesh_refinement)
+# ### [13 Adaptive mesh refinement](@ref adaptive_mesh_refinement)
 #-
 # Adaptive mesh refinement (AMR) helps to increase the accuracy in sensitive or turbolent regions while
 # not wasting resources for less interesting parts of the domain. This leads to much more efficient
 # simulations. This tutorial presents the implementation strategy of AMR in Trixi.jl, including the use of
 # different indicators and controllers.
 
-# ### [13 Structured mesh with curvilinear mapping](@ref structured_mesh_mapping)
+# ### [14 Structured mesh with curvilinear mapping](@ref structured_mesh_mapping)
 #-
 # In this tutorial, the use of Trixi.jl's structured curved mesh type [`StructuredMesh`](@ref) is explained.
 # We present the two basic option to initialize such a mesh. First, the curved domain boundaries
 # of a circular cylinder are set by explicit boundary functions. Then, a fully curved mesh is
 # defined by passing the transformation mapping.
 
-# ### [14 Unstructured meshes with HOHQMesh.jl](@ref hohqmesh_tutorial)
+# ### [15 Unstructured meshes with HOHQMesh.jl](@ref hohqmesh_tutorial)
 #-
 # The purpose of this tutorial is to demonstrate how to use the [`UnstructuredMesh2D`](@ref)
 # functionality of Trixi.jl. This begins by running and visualizing an available unstructured
@@ -108,26 +115,26 @@
 # software in the Trixi.jl ecosystem, and then run a simulation using Trixi.jl on said mesh.
 # In the end, the tutorial briefly explains how to simulate an example using AMR via `P4estMesh`.
 
-# ### [15 P4est mesh from gmsh](@ref p4est_from_gmsh)
+# ### [16 P4est mesh from gmsh](@ref p4est_from_gmsh)
 #-
 # This tutorial describes how to obtain a [`P4estMesh`](@ref) from an existing mesh generated
 # by [`gmsh`](https://gmsh.info/) or any other meshing software that can export to the Abaqus
 # input `.inp` format. The tutorial demonstrates how edges/faces can be associated with boundary conditions based on the physical nodesets.
 
-# ### [16 Explicit time stepping](@ref time_stepping)
+# ### [17 Explicit time stepping](@ref time_stepping)
 #-
 # This tutorial is about time integration using [OrdinaryDiffEq.jl](https://github.com/SciML/OrdinaryDiffEq.jl).
 # It explains how to use their algorithms and presents two types of time step choices - with error-based
 # and CFL-based adaptive step size control.
 
-# ### [17 Differentiable programming](@ref differentiable_programming)
+# ### [18 Differentiable programming](@ref differentiable_programming)
 #-
 # This part deals with some basic differentiable programming topics. For example, a Jacobian, its
 # eigenvalues and a curve of total energy (through the simulation) are calculated and plotted for
 # a few semidiscretizations. Moreover, we calculate an example for propagating errors with Measurement.jl
 # at the end.
 
-# ### [18 Custom semidiscretization](@ref custom_semidiscretization)
+# ### [19 Custom semidiscretization](@ref custom_semidiscretization)
 #-
 # This tutorial describes the [semidiscretiations](@ref overview-semidiscretizations) of Trixi.jl
 # and explains how to extend them for custom tasks.
diff --git a/docs/make.jl b/docs/make.jl
index 7fce3b31e2..584f151b5f 100644
--- a/docs/make.jl
+++ b/docs/make.jl
@@ -48,6 +48,12 @@ end
 #   "title" => ["subtitle 1" => ("folder 1", "filename 1.jl"),
 #               "subtitle 2" => ("folder 2", "filename 2.jl")]
 files = [
+    # Topic: introduction
+    "First steps in Trixi.jl" => [
+        "Getting started" => ("first_steps", "getting_started.jl"),
+        "Create first setup" => ("first_steps", "create_first_setup.jl"),
+        "Changing Trixi.jl itself" => ("first_steps", "changing_trixi.jl"),
+    ],
     # Topic: DG semidiscretizations
     "Introduction to DG methods" => "scalar_linear_advection_1d.jl",
     "DGSEM with flux differencing" => "DGSEM_FluxDiff.jl",