multiplierConfig.cmake.in

#
# Copyright (c) 2021-present, Trail of Bits, Inc.
#
# This source code is licensed in accordance with the terms specified in
# the LICENSE file found in the root directory of this source tree.
#

@PACKAGE_INIT@

include(CMakeFindDependencyMacro)

set(MX_INSTALL_LIB_DIR @MX_INSTALL_LIB_DIR@)
set(MX_INSTALL_BIN_DIR @MX_INSTALL_BIN_DIR@)
set(MX_INSTALL_INCLUDE_DIR @MX_INSTALL_INCLUDE_DIR@)
set(MX_INSTALL_SHARE_DIR @MX_INSTALL_SHARE_DIR@)

set(MX_ENABLE_RE2 @MX_ENABLE_RE2@)
set(MX_ENABLE_PYTHON_BINDINGS @MX_ENABLE_PYTHON_BINDINGS@)

if(NOT TARGET @PROJECT_NAME@::multiplier)
  if(NOT TARGET Threads::Threads)
    find_dependency(Threads REQUIRED)
  endif()

  if(NOT TARGET gap::gap)
    find_dependency(gap CONFIG REQUIRED)
  endif()

  if(MX_ENABLE_PYTHON_BINDINGS AND NOT TARGET Python3::Python)
    find_dependency(Python3 REQUIRED COMPONENTS Interpreter Development.Embed)
  endif()
  
  include("${CMAKE_CURRENT_LIST_DIR}/@PROJECT_NAME@Targets.cmake")
  check_required_components("@PROJECT_NAME@")
endif()

if(NOT DEFINED MX_FIND_QUIETLY)
  message(STATUS "Found Multiplier: ${CMAKE_CURRENT_LIST_DIR}")
endif()