-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
151 lines (148 loc) · 4.58 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
{
inputs = {
nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
flake-utils.url = "github:numtide/flake-utils/v1.0.0";
home-manager = {
url = "github:nix-community/home-manager";
inputs.nixpkgs.follows = "nixpkgs";
};
impermanence.url = "github:nix-community/impermanence";
sops-nix = {
url = "github:Mic92/sops-nix";
inputs.nixpkgs.follows = "nixpkgs";
inputs.nixpkgs-stable.follows = "nixpkgs";
};
disko = {
url = "github:nix-community/disko";
inputs.nixpkgs.follows = "nixpkgs";
};
colmena = {
url = "github:zhaofengli/colmena";
inputs.stable.follows = "nixpkgs";
inputs.nixpkgs.follows = "nixpkgs";
inputs.flake-utils.follows = "flake-utils";
};
arion = {
url = "github:hercules-ci/arion";
inputs.nixpkgs.follows = "nixpkgs";
};
devenv = {
url = "github:cachix/devenv";
inputs.nixpkgs.follows = "nixpkgs";
};
nixos-images = {
url = "github:nix-community/nixos-images";
inputs.nixos-unstable.follows = "nixpkgs";
};
nixos-anywhere = {
url = "github:nix-community/nixos-anywhere";
inputs.nixpkgs.follows = "nixpkgs";
};
nix-minecraft = {
url = "github:Infinidoge/nix-minecraft";
inputs.nixpkgs.follows = "nixpkgs";
inputs.flake-utils.follows = "flake-utils";
};
dream2nix = {
url = "github:nix-community/dream2nix";
inputs.nixpkgs.follows = "nixpkgs";
};
};
outputs = { self, flake-utils, nixpkgs, devenv, dream2nix, ... }@inputs:
let
lib = nixpkgs.lib;
modules = import ./modules;
hive = {
meta = {
specialArgs = {
inherit self inputs;
data.keys = [
"ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIAamaMcCAc7DhTJjDqBwXTWhewX0OI8vAuXLvc17yqK/"
"ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIBIO4wL3BzfaMDOpbT/U/99MVQERjtzH2YxA6KAs7lwM"
];
};
nixpkgs = import nixpkgs {
system = "x86_64-linux";
overlays = [
self.overlays.default
inputs.colmena.overlay
inputs.nix-minecraft.overlay
];
};
};
} //
(
lib.pipe (lib.importJSON ./infra/generated/nodes.json) [
(lib.lists.map (node:
lib.nameValuePair node.hostname {
deployment = {
targetHost = node.ssh.host or null;
targetUser = node.ssh.user or "root";
targetPort = node.ssh.port or null;
};
imports = [ ./nixos/${node.config or node.hostname} ];
nixpkgs.system = "${node.arch}-linux";
networking.hostName = node.hostname;
}
))
lib.listToAttrs
]
);
this = import ./pkgs;
in
(
flake-utils.lib.eachSystem [ "x86_64-linux" "aarch64-linux" ]
(
system:
let
pkgs = import nixpkgs {
inherit system;
overlays = [
self.overlays.default
inputs.colmena.overlay
inputs.nix-minecraft.overlay
];
};
in
rec {
legacyPackages = pkgs;
devShells.default = devenv.lib.mkShell {
inherit inputs pkgs;
modules = [
./devenv.nix
];
};
packages = {
devenv-up = devShells.default.config.procfileScript;
kexec-installer-nixos-unstable-noninteractive = inputs.nixos-images.packages.${system}.kexec-installer-nixos-unstable-noninteractive;
nixos-anywhere = inputs.nixos-anywhere.packages.${system}.nixos-anywhere;
} // this.packages pkgs;
}
)
) //
{
hydraJobs = {
desktop = self.nixosConfigurations.desktop.config.system.build.toplevel;
};
nixosModules = modules.nixosModules;
homeManagerModules = modules.homeManagerModules;
overlays.default = lib.composeExtensions this.overlay (self: super:
dream2nix.lib.importPackages {
projectRoot = ./.;
projectRootFile = "flake.nix";
packagesDir = ./dream-pkgs;
packageSets.nixpkgs = super;
}
);
nixosConfigurations =
{
desktop = import ./nixos/desktop {
system = "x86_64-linux";
hostname = "desktop";
inherit self inputs;
};
} //
self.colmenaHive.nodes;
colmenaHive = inputs.colmena.lib.makeHive hive;
};
}