-
Notifications
You must be signed in to change notification settings - Fork 4
/
rugged-box-library.scad
1918 lines (1767 loc) · 58.2 KB
/
rugged-box-library.scad
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* Customizable and Parametric Rugged Storage Box
* By smkent (GitHub) / bulbasaur0 (Printables)
*
* Rugged storage box library
*
* Licensed under Creative Commons (4.0 International License) Attribution-ShareAlike
*/
module __end_customizer_options__() { }
// Constants
$fa = $preview ? $fa : 2;
$fs = $preview ? $fs / 2 : 0.2;
// Attachment screw diameter
screw_diameter = 3; // M3
// Decrease screw hole diameter just slightly for better thread-forming fit
screw_hole_diameter_size_tolerance = -0.1;
// Widen angle of box plain ribs
plain_ribs_angle = 8;
// Extra space between box body and hinge for clearance
hinge_extra_setback = 0.2; // [0:0.1:2]
hinge_size_tolerance = 0.1;
// Screw eyelet diameter as a proportion of screw diameter
screw_eyelet_size_proportion = 3.0; // [1.5:0.1:5]
// Depth and maximum width of lip grip
top_grip_depth = 6;
top_grip_width = 100;
// Latch size
latch_edge_radius = 0.8;
latch_body_size_proportion = 3.0; // [1.5:0.1:5]
// Stacking latch size
stacking_latch_catch_offset = -10;
stacking_latch_grip_length = 8;
stacking_latch_screw_separation = 20;
// Handle size
handle_thickness = 10;
handle_min_height = 16;
handle_max_height = 35;
handle_radius = 5;
// Public modules
/*
* Setup module
*
* Use this module to configure box sizing and features before rendering a part
*
* Arguments:
* - width: Interior side-to-side size
* - length: Interior front-to-back size
* - top_height: Interior top height
* - bottom_height: Interior bottom height
* - corner_radius: Interior corner radius (Reduces interior storage space)
* - edge_chamfer_proportion: Proportion of corner_radius to chamfer outer
* top/bottom edges (Reduces interior storage space)
* - lip_seal_type: Type of shape of seal to use, if desired:
* - "none": No seal
* - "wedge": Wedge-shaped seal
* - "square": Square-shaped seal
* - "filament-1.75mm": Seal cutout on both top and bottom for
* 1.75mm filament
* - reinforced_corners: Make the corners as thick as the box lip
* - latch_count: Number of latches (1 or 2). The default of 0 determines the
* number of latches automatically.
*
* Example:
*
* box(width=100, length=50, top_height=15, bottom_height=30) {
* // Render box top
* translate([120, 0, 0])
* rbox_top();
*
* // Render box bottom
* rbox_bottom();
* }
*/
module rbox(
width,
length,
bottom_height=0,
top_height=0,
corner_radius=5,
edge_chamfer_proportion=0.4,
lip_seal_type="wedge",
reinforced_corners=false,
latch_type="draw",
latch_count=0,
top_grip=false,
hinge_end_stops=false
) {
// Set base dimensions
$b_inner_width = width;
$b_inner_length = length;
$b_top_inner_height = top_height;
$b_bottom_inner_height = bottom_height;
$b_corner_radius = corner_radius;
$b_edge_chamfer_proportion = edge_chamfer_proportion;
$b_lip_seal_type = lip_seal_type;
$b_reinforced_corners = reinforced_corners;
$b_latch_type = latch_type;
$b_latch_count = latch_count;
$b_top_grip = top_grip;
$b_hinge_end_stops = hinge_end_stops;
// Set defaults
$b_preview_assembled = false;
$b_preview_box_open = false;
rbox_size_adjustments()
_box_rib_angle(0)
// Render modules
children();
}
/*
* Advanced size adjustments setup module
*
* Use this module to configure advanced box sizing adjustments before rendering a part
*
* Arguments:
* - wall_thickness: Base wall thickness for most of the box
* - lip_thickness: Thickness to add to the wall thickness for the box lip
* - rib_width: Base thickness of the support ribs. The latch ribs are this
* thick, while the hinge and side ribs are twice this thick.
* - latch_width: Latch side-to-side width
* - latch_screw_separation: Distance between the latch hinge and catch screws
* which determines the latch vertical size
* - latch_amount_on_top: Vertical size of the latch measured from the latch
* hinge screw hole overlapping the top of the box, with the remainder
* overlapping the bottom. Set to 0 to determine automatically.
* - third_hinge_width: Add a third, center hinge if the box's interior is at
* least as wide as this value. Set to 0 to disable (default).
* - stacking_separation: The vertical distance between two stacked boxes.
* Used for stacking latch attachment placement.
* - size_tolerance: Size subtracted from latch and upper hinge widths for fit
*
* Example:
*
* box(width=100, length=50, top_height=15, bottom_height=30) {
* rbox_size_adjustments(wall_thickness=3.0, lip_thickness=3.0) {
* // Render box top
* translate([120, 0, 0])
* rbox_top();
*
* // Render box bottom
* rbox_bottom();
* }
* }
*/
module rbox_size_adjustments(
wall_thickness=2.4,
lip_thickness=2.0,
rib_width=4.0,
latch_width=22,
latch_screw_separation=20,
latch_amount_on_top=0,
third_hinge_width=0,
stacking_separation=0,
size_tolerance=0.05
) {
$b_wall_thickness = wall_thickness;
$b_lip_thickness = lip_thickness;
$b_rib_width = rib_width;
$b_size_tolerance = size_tolerance;
$b_latch_width = latch_width;
$b_latch_screw_separation = latch_screw_separation;
$b_latch_amount_on_top = _init_latch_amount_on_top(latch_amount_on_top);
$b_third_hinge_width = third_hinge_width;
$b_stacking_separation = stacking_separation;
// Set computed values
$b_total_lip_thickness = wall_thickness + lip_thickness;
$b_lip_height = lip_thickness * 2;
$b_edge_radius = wall_thickness / 5;
// Set dependent values
$b_top_outer_height = $b_top_inner_height + wall_thickness;
$b_bottom_outer_height = $b_bottom_inner_height + wall_thickness;
$b_outer_width = $b_inner_width + $b_total_lip_thickness * 2;
$b_outer_length = $b_inner_length + $b_total_lip_thickness * 2;
$b_curved_inner_width = $b_inner_width + $b_edge_radius * 2;
$b_curved_inner_length = $b_inner_length + $b_edge_radius * 2;
$b_outer_chamfer_horizontal = $b_edge_chamfer_proportion * $b_corner_radius;
$b_outer_chamfer_vertical = $b_outer_chamfer_horizontal * 1.5;
$b_hinge_screw_offset = _attachment_screw_offset();
$b_latch_screw_offset = _attachment_screw_offset();
children();
}
// Part modules
module rbox_top() { _box_part_setup("top") { rbox_body(); children(); } }
module rbox_bottom() { _box_part_setup("bottom") { rbox_body(); children(); } }
module rbox_for_top() { _box_part_setup("top") children(); }
module rbox_for_bottom() { _box_part_setup("bottom") children(); }
module rbox_for_interior() { translate([0, 0, $b_wall_thickness]) children(); }
module rbox_latch(placement="print") { _latch(placement); }
module rbox_stacking_latch(placement="print") { _stacking_latch(placement); }
module rbox_handle(placement="print") { _handle(placement); }
module rbox_body() {
_box_color()
_box_body();
}
module rbox_interior() {
_box_color()
render(convexity=4) {
_box_extrude()
_box_interior_shape();
rbox_for_interior()
_box_center_base($b_inner_height);
}
}
module rbox_part(part) {
module _place_apart(x_amount) {
for (ch = [0:1:1]) {
mirror([ch, 0, 0])
translate([x_amount, 0, 0])
children(ch);
}
}
if (part == "side-by-side") {
_place_apart($b_inner_width / 2 + $b_wall_thickness * 8) {
if ($children > 0) { rbox_for_bottom() children(0); } else { rbox_bottom(); };
if ($children > 1) { rbox_for_top() children(1); } else { rbox_top(); };
}
rbox_bom();
} else if (part == "assembled_open") {
$b_preview_assembled = true;
$b_preview_box_open = true;
if ($children > 0) { rbox_for_bottom() children(0); } else { rbox_bottom(); };
rbox_for_bottom() {
rbox_handle(placement="box-preview-open");
if (_stacking_latches_enabled())
_box_stacking_latch_ribs_placement()
translate([0, 0, stacking_latch_screw_separation * 0.5])
translate([0, -$b_latch_screw_offset, 0])
rotate([180, 0, 0])
rbox_stacking_latch(placement="box-preview");
if ($b_latch_type == "draw") {
translate([
0,
-$b_latch_screw_offset,
$b_outer_height - ($b_latch_screw_separation - $b_latch_amount_on_top)
])
mirror([0, 1, 0])
_box_attachment_placement()
rbox_latch(placement="box-preview");
}
}
translate([
0,
$b_inner_length / 2 + $b_hinge_screw_offset,
$b_bottom_outer_height
])
rotate([270, 0, 0])
translate([
0,
-($b_inner_length / 2 + $b_hinge_screw_offset),
$b_top_outer_height
])
mirror([0, 0, 1]) {
if ($children > 1) { rbox_for_top() children(1); } else { rbox_top(); };
rbox_for_top() {
if ($b_latch_type == "clip") {
translate([
0,
-$b_latch_screw_offset,
$b_outer_height - $b_latch_amount_on_top
])
mirror([0, 1, 0])
_box_attachment_placement()
rotate([-135, 0, 0])
rbox_latch(placement="box-preview");
}
}
}
rbox_bom();
} else if (part == "assembled_closed") {
$b_preview_assembled = true;
if ($children > 0) { rbox_for_bottom() children(0); } else { rbox_bottom(); };
rbox_for_bottom() {
rbox_handle(placement="box-preview");
if (_stacking_latches_enabled())
_box_stacking_latch_ribs_placement()
translate([0, 0, stacking_latch_screw_separation * 0.5])
translate([0, -$b_latch_screw_offset, 0])
rbox_stacking_latch(placement="box-preview");
if ($b_latch_type == "draw") {
translate([
0,
-$b_latch_screw_offset,
$b_outer_height - ($b_latch_screw_separation - $b_latch_amount_on_top)
])
mirror([0, 1, 0])
_box_attachment_placement()
rbox_latch(placement="box-preview");
}
}
translate([0, 0, $b_top_outer_height + $b_bottom_outer_height])
mirror([0, 0, 1]) {
if ($children > 1) { rbox_for_top() children(1); } else { rbox_top(); };
rbox_for_top() {
if ($b_latch_type == "clip") {
translate([
0,
-$b_latch_screw_offset,
$b_outer_height - $b_latch_amount_on_top
])
mirror([0, 1, 0])
_box_attachment_placement()
rbox_latch(placement="box-preview");
}
}
}
rbox_bom();
} else if (part == "bottom") {
if ($children > 0) { rbox_for_bottom() children(0); } else { rbox_bottom(); };
rbox_bom();
} else if (part == "top") {
if ($children > 1) { rbox_for_top() children(1); } else { rbox_top(); };
rbox_bom();
} else if (part == "latch") {
rbox_latch(placement="print");
} else if (part == "stacking_latch") {
rbox_stacking_latch(placement="print");
} else if (part == "handle") {
rbox_handle(placement="print");
}
}
// Echo non-printable bill of materials needed for the configured box
module rbox_bom() {
function _sstr(count, length) = (
str(count, " M", screw_diameter, "x", length)
);
rbox_for_bottom() {
screw_length_base = $b_latch_width + $b_rib_width * 2;
screw_count_base = (
// 2 for each latch, 1 for each hinge
_compute_latch_count() * (2 + 1)
+ (
(
$b_third_hinge_width > 0
&& $b_inner_width >= $b_third_hinge_width
) ? 1 : 0
)
// stacking latches, 2 sides
+ len(rb_stacking_latch_positions()) * 2 * (
// 2 attachment points
2
// Stow point if box is tall enough for a stacking latch
+ (_stacking_latches_enabled() ? 1 : 0)
)
);
echo(str(
"Box total screws needed: ",
_sstr(screw_count_base, screw_length_base),
_handle_enabled() ? (
str(
" without handle, or ",
_sstr(screw_count_base - 2, screw_length_base),
" + ",
_sstr(
2,
screw_length_base + $b_rib_width + handle_thickness
),
" with handle"
)
) : ""
));
}
};
// Overridable functions and modules
/*
* Part colors
*
* Box colors used in the preview render
*
* Arguments:
* - part: Part being rendered. Possible values: "top", "bottom"
*
* Example:
*
* function rb_color(part) = (part == "top" ? "yellow" : "orange");
*/
function rb_color(part) = (part == "top" ? "YellowGreen" : "OliveDrab");
// Side rib positions, by offset from center in millimeters
function rb_side_rib_positions() = [for (i = [-1/4, 1/4]) i * $b_inner_length];
// Rear rib positions, by offset from center in millimeters
function rb_rear_rib_positions() = [];
// Latch and hinge positions, by offset from center in millimeters
function rb_latch_hinge_position() = (
($b_inner_width - $b_corner_radius + $b_wall_thickness) / 2 - $b_latch_width
);
// Side stacking latch positions, by offset from center in millimeters
function rb_stacking_latch_positions() = [];
// Internal constants
screw_hole_diameter = screw_diameter;
screw_eyelet_radius = screw_hole_diameter * screw_eyelet_size_proportion / 2;
screw_hole_diameter_fit = screw_hole_diameter * 0.2;
latch_base_size = screw_diameter * (latch_body_size_proportion / 2);
draw_latch_body_angle = 25;
draw_latch_body_curve_radius = 10;
draw_latch_grip_angle = 45;
draw_latch_grip_curve_radius = 16;
draw_latch_thickness = latch_base_size / 2;
draw_latch_handle_length = latch_base_size * 3.25;
draw_latch_screw_eyelet_radius = screw_hole_diameter * 1.1;
draw_latch_pin_handle_radius = screw_hole_diameter * 1.6;
draw_latch_pin_radius = draw_latch_pin_handle_radius - 2.2;
draw_latch_sep = 0.4;
draw_latch_vsep = 0.6;
draw_latch_body_width = latch_base_size - screw_hole_diameter / 2;
draw_latch_pin_offset = [
(
draw_latch_screw_eyelet_radius
- draw_latch_pin_handle_radius
- screw_hole_diameter * 0.1
),
-draw_latch_handle_length,
0
];
draw_latch_poly_div = 10;
// For _box_extrude and _box_corners_extrude
corners_data = [
// Rotate angle, X direction, Y direction
[0, -1, -1],
[90, 1, -1],
[180, 1, 1],
[270, -1, 1],
];
// Functions
function _vec_add(vec, add) = [for (v = vec) v + add];
function _vec_append_each(vec, append) = [for(i=vec) concat(i, append)];
function _vec_reverse(vec) = [for (i = [len(vec) - 1:-1:0]) vec[i]];
function _cumulative_sum(v) = [
for (
now_sum = v[0], i = 1;
i <= len(v) - 1;
next_sum = now_sum + v[i], ni = i + 1, now_sum = next_sum, i = ni
)
now_sum
];
function _attachment_screw_offset() = (
$b_total_lip_thickness + screw_eyelet_radius + hinge_extra_setback
);
function _compute_latch_count(latch_count) = (
let (outer_radius = $b_corner_radius + $b_wall_thickness)
($b_latch_count == 1 || $b_latch_count == 2)
? $b_latch_count
: (($b_inner_width >= (outer_radius * 2 + $b_latch_width * 4))
? 2
: 1
)
);
function _init_latch_amount_on_top(latch_amount_on_top) = (
latch_amount_on_top > 0
? latch_amount_on_top
: min(
($b_top_inner_height + $b_wall_thickness) / 2,
($b_latch_type == "draw"
? $b_latch_screw_separation - screw_eyelet_radius * 1.25
: min(
screw_eyelet_radius * 2.0,
$b_latch_screw_separation / 2
)
)
)
);
function _latch_offset_from_base() = (
$b_outer_height - (
$b_part == "top"
? $b_latch_amount_on_top
: $b_latch_screw_separation - $b_latch_amount_on_top
)
);
function _latch_width() = ($b_latch_width - $b_size_tolerance * 2);
function _stacking_latches_enabled() = (
$b_outer_height > stacking_latch_screw_separation * 2.0
);
function _handle_dimensions() = [
// Width
(
rb_latch_hinge_position() * 2
- $b_rib_width * 2
- $b_latch_width
- $b_size_tolerance * 2
),
// Height
min(
handle_max_height,
_latch_offset_from_base() - handle_thickness - 2
)
];
function _handle_enabled() = (
let (dimensions = _handle_dimensions())
(
_compute_latch_count() == 2
&& dimensions[0] > ((handle_thickness + handle_radius) * 2 * 1.75)
&& dimensions[1] >= handle_min_height
)
);
function _edge_chamfer_enabled() = (!($preview && $b_preview_assembled));
// Basic shape modules
module _round_shape(radius) {
offset(-radius)
offset(radius * 2)
offset(-radius)
children();
}
module _rounded_square(dimensions, radius, center=false) {
offset(radius)
offset(-radius)
square(dimensions, center=center);
}
module _rounded_cylinder(h, r1, r2=0, angle=360, center=false) {
r = $b_edge_radius;
translate([0, 0, center ? -h / 2 : 0])
rotate_extrude(angle=angle)
difference() {
_round_shape(r)
polygon(points=[
[-r * 2, 0],
[r1, 0],
[r2 > 0 ? r2 : r1, h],
[-r * 2, h],
]);
translate([-r * 4, -h / 2])
square([r * 4, h * 2]);
}
}
module _chamfer_edges(r, rotation=[0, 0, 0]) {
if (_edge_chamfer_enabled()) {
minkowski() {
children();
union() {
$fs = $preview ? $fs : $fs / 5;
if (r > 0)
rotate(rotation)
for (mz = [0:1:1])
mirror([0, 0, mz])
cylinder(d1=r, d2=0, h=r);
}
}
} else {
children();
}
}
module _linear_extrude_with_chamfer(height, r, center=false) {
if (_edge_chamfer_enabled()) {
_chamfer_edges(r)
translate([0, 0, center ? 0 : r])
linear_extrude(height=height - r * 2, center=center)
offset(r=-r / 2)
children();
} else {
linear_extrude(height=height, center=center)
children();
}
}
module _hull_in_order() {
for (ch = [0:1:$children - 2])
hull() {
children(ch);
children(ch + 1);
}
}
module _hull_pair(height) {
slop = 0.001;
hull() {
for (child_obj = [
// Child index, height offset
[0, 0],
[1, height - slop]
]) {
translate([0, 0, child_obj[1]])
linear_extrude(height=slop)
children(child_obj[0]);
}
}
}
module _hull_stack(heights=[]) {
cheights = _cumulative_sum(heights);
for (ch = [1:1:len(heights)]) {
hi = ch - 1;
if (ch < $children) {
translate([0, 0, hi > 0 ? cheights[hi - 1] : 0])
_hull_pair(heights[hi]) {
children(ch - 1);
children(ch);
}
} else {
echo("Warning: ignoring extra height value at index", ch);
}
}
}
// Box body modules
module _box_color() {
color(rb_color($b_part), 0.8)
children();
}
module _box_part_setup(part) {
$b_part = part;
$b_inner_height = (
($b_part == "top") ? $b_top_inner_height : $b_bottom_inner_height
);
$b_outer_height = (
($b_part == "top") ? $b_top_outer_height : $b_bottom_outer_height
);
children();
}
module _box_body() {
_box_add_seal() {
render(convexity=4) {
_box_sides();
_box_center_base(min($b_outer_height, $b_wall_thickness));
}
_box_ribs();
_box_latch_ribs();
_box_hinge_ribs();
_box_stacking_latch_ribs();
_box_top_grip();
}
}
module _box_corners_extrude_linear_extension(length) {
rotate([90, 0, 90])
linear_extrude(height=length)
_box_wall_shape(reinforced=true);
}
module _box_corners_extrude(
width=$b_inner_width,
length=$b_inner_length,
radius=$b_corner_radius,
extend=false
) {
for (i = [0:1:len(corners_data) - 1]) {
translate([
corners_data[i][1] * (width - radius * 2) / 2,
corners_data[i][2] * (length - radius * 2) / 2,
0
])
rotate([0, 0, 180 + corners_data[i][0]])
union() {
rotate_extrude(angle=90)
children();
if (extend) {
for (rz = [0:1:1]) {
mirror([rz, 0, 0])
rotate([0, 0, rz ? 0 : -90])
if (_compute_latch_count() == 2 && ((i % 2) != rz)) {
// Front/rear extensions to attachments
is_rear = (i == 2 || i == 3);
_box_corners_extrude_linear_extension(
(
($b_inner_width - $b_corner_radius * 2)
- ($b_latch_width + $b_rib_width)
) / 2
- rb_latch_hinge_position()
// On the box top hinge, extension needs to rear
// the inner hinge position
+ (
$b_part == "top" && is_rear
? $b_rib_width * 2
: 0
)
);
} else if (_compute_latch_count() == 2 && len(rb_side_rib_positions()) >= 2 && ((i % 2) == rz)) {
// Side extensions to ribs
idx = ((i == 0 || i == 1) ? 0 : len(rb_side_rib_positions()) - 1);
// idx is 0 for front-side, or last rib index for rear-side
_box_corners_extrude_linear_extension(
(
($b_inner_length - $b_corner_radius * 2)
- ($b_rib_width * (2 - 1))
) / 2
+ rb_side_rib_positions()[idx] * (idx == 0 ? 1 : -1)
);
} else {
difference() {
scale([
(tan(15) * $b_corner_radius) / $b_corner_radius,
1
])
rotate_extrude(angle=90)
children();
translate([0, 0, $b_wall_thickness])
linear_extrude(height=$b_outer_height)
square($b_corner_radius + $b_wall_thickness / 2);
}
}
}
}
}
}
}
module _box_extrude(size_offset=0) {
width = $b_inner_width + size_offset;
length = $b_inner_length + size_offset;
radius = $b_corner_radius + size_offset / 2;
// Corners
_box_corners_extrude(width, length, radius)
children();
// Sides
for (i = [0:1:len(corners_data) - 1]) {
extrude_length = (
(corners_data[i][0] % 180 == 0 ? width : length) - radius * 2
);
translate([
corners_data[i][1] * (width - radius * 2) / 2,
corners_data[i][2] * (length - radius * 2) / 2,
0
])
rotate([0, 0, corners_data[i][0]])
translate([extrude_length, 0, 0])
rotate([90, 0, -90])
linear_extrude(height=extrude_length)
children();
}
}
module _box_wall_inner_chamfer_shape() {
translate([-$b_wall_thickness, 0])
difference() {
translate([0, $b_wall_thickness])
square([$b_corner_radius + $b_wall_thickness, $b_outer_height]);
translate([0, $b_wall_thickness * 0.1])
_box_wall_outer_chamfer_shape();
}
}
module _box_wall_outer_chamfer_shape() {
vertical_chamfer = $b_outer_chamfer_vertical;
horizontal_chamfer = $b_outer_chamfer_horizontal;
translate([
$b_corner_radius + $b_wall_thickness - horizontal_chamfer,
-(vertical_chamfer - min(
vertical_chamfer,
$b_outer_height - $b_lip_height - $b_lip_thickness * 1.5
))
])
polygon(points=[
[0, 0],
[horizontal_chamfer, 0],
[horizontal_chamfer, vertical_chamfer]
]);
}
module _box_wall_interior_shape() {
translate([-$b_wall_thickness, 0])
difference() {
translate([0, $b_wall_thickness])
square([$b_corner_radius + $b_wall_thickness, $b_outer_height]);
translate([0, $b_wall_thickness * 0.1])
_box_wall_outer_chamfer_shape();
}
}
module _box_wall_shape(reinforced=false) {
_round_shape($b_edge_radius)
difference() {
square([$b_corner_radius + $b_total_lip_thickness, $b_outer_height]);
translate([reinforced ? $b_lip_thickness : 0, 0, 0]) {
translate([$b_corner_radius, 0])
polygon(points=[
[$b_wall_thickness, $b_outer_height - $b_lip_thickness * 3.5],
[$b_wall_thickness, 0],
[$b_total_lip_thickness, 0],
[$b_total_lip_thickness, $b_outer_height - $b_lip_height],
]);
_box_wall_outer_chamfer_shape();
}
_box_wall_interior_shape();
}
// Square inner floor edge
square([$b_wall_thickness * 2/3, min($b_outer_height, $b_wall_thickness)]);
}
module _box_interior_shape() {
intersection() {
difference() {
translate([$b_wall_thickness / 2, -$b_wall_thickness / 2])
_box_wall_inner_chamfer_shape();
_box_wall_shape(reinforced=true);
}
translate([0, $b_wall_thickness])
square([
$b_corner_radius + $b_edge_radius * 2,
$b_outer_height - $b_wall_thickness
]);
}
}
module _box_center_base(height) {
radius_inset = $b_corner_radius * 2;
linear_extrude(height=height)
square(
[
$b_inner_width - radius_inset,
$b_inner_length - radius_inset
],
center=true
);
}
module _box_seal_shape() {
seal_thickness = (
$b_lip_seal_type == "filament-1.75mm"
? 1.75
: $b_total_lip_thickness / 3
);
translate([$b_corner_radius + $b_total_lip_thickness / 2, 0]) {
if ($b_lip_seal_type == "filament-1.75mm") {
circle(seal_thickness / 2);
} else if ($b_lip_seal_type == "square") {
translate([0, -seal_thickness / 2])
square(seal_thickness, center=true);
} else if ($b_lip_seal_type == "wedge") {
translate([0, -seal_thickness])
polygon(points=[
[-seal_thickness / 4, 0],
[seal_thickness / 4, 0],
[seal_thickness / 2, seal_thickness],
[-seal_thickness / 2, seal_thickness],
]);
}
}
}
module _box_seal(delta=0) {
translate([0, 0, $b_outer_height])
mirror([0, 0, $b_part == "top" ? 1 : 0])
// Improve seal / lip overlap preview rendering
translate([0, 0, $preview ? 0.01 : 0])
scale([1, 1, $preview ? 1.01 : 1])
_box_extrude(size_offset=$b_total_lip_thickness)
offset(delta=delta)
_box_seal_shape();
}
module _box_add_seal() {
is_seal_top_inset = (
$b_lip_seal_type == "filament-1.75mm" ? true : false
);
delta = is_seal_top_inset ? 0 : 0.2;
difference() {
union() {
children();
if (
$b_lip_seal_type != "none"
&& ($b_part == "top" && !is_seal_top_inset)
) {
translate([0, 0, -delta])
_box_seal(delta=-delta);
}
}
if (
$b_lip_seal_type != "none"
&& ($b_part == "bottom" || is_seal_top_inset)
) {
translate([0, 0, delta])
_box_seal();
}
}
}
module _box_sides() {
_box_extrude()
_box_wall_shape();
if ($b_reinforced_corners) {
_box_corners_extrude(extend=true)
_box_wall_shape(reinforced=true);
}
}
// Box ribs
module _box_rib_angle(ang=0) {
$br_angle = ang;
children();
}
module _box_rib_shape(x=$b_total_lip_thickness, y=$b_rib_width) {
x0 = $b_edge_radius;
angle_add = tan($br_angle) * y;
_round_shape(x0)
for (my = [0:1:1]) {
mirror([0, my])
polygon(points=[
[x0, 0],
[x, 0],
[x, y / 2],
[x0, y / 2 + angle_add],
]);
}
}
module _box_rib(width=$b_rib_width) {
lip_position = $b_outer_height - $b_lip_height;
vertical_chamfer = min(
$b_outer_chamfer_vertical,
max(0, lip_position - $b_lip_thickness - $b_wall_thickness)
);
horizontal_chamfer = vertical_chamfer * 2/3;
// Bottom angled part
if (vertical_chamfer > 0) {
_hull_stack([vertical_chamfer]) {
translate([-horizontal_chamfer, 0])
_box_rib_shape(y=width);
_box_rib_shape(y=width);
}
}
if (lip_position > 0) {
// Vertical rib body
translate([0, 0, vertical_chamfer])
linear_extrude(height=(
$b_outer_height - vertical_chamfer - $b_edge_radius * 1.5
))
_box_rib_shape(y=width);
}
}
module _box_plain_rib() {
_box_rib_angle(plain_ribs_angle)
_box_rib($b_rib_width * 2);
}
module _box_ribs() {
// Side ribs
for (mx = [0:1:1], py = rb_side_rib_positions()) {
mirror([mx, 0, 0])
translate([$b_inner_width / 2, py, 0])
_box_plain_rib();
}
// Rear ribs
for (px = rb_rear_rib_positions()) {
translate([px, $b_inner_length / 2, 0])
rotate([0, 0, 90])
_box_plain_rib();
}
}
// Box attachments (latch and hinge ribs)
module _box_attachment_rib_cut(width=0) {
translate([-$b_corner_radius, 0, 0])