build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id 'org.springframework.boot' version '2.5.8'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
}

allprojects {
    repositories {
        mavenCentral()
    }
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'

    group = 'dev.ncns.sns'
    version = '0.0.1'
    sourceCompatibility = '11'

    ext {
        set('springCloudVersion', "2020.0.5")
    }

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    dependencies {
        List.of("auth", "user", "post", "feed", "search").stream()
                .filter(p -> project.name.contains(p))
                .forEach({
                    project.dependencies {
                        implementation 'org.springframework.boot:spring-boot-starter-web'
                        developmentOnly 'org.springframework.boot:spring-boot-devtools'
                        implementation 'org.springframework.boot:spring-boot-starter-cache'
                        implementation 'org.springframework.boot:spring-boot-starter-actuator'

                        implementation 'org.springframework.cloud:spring-cloud-starter-netflix-eureka-client'
                        implementation 'org.springframework.cloud:spring-cloud-starter-openfeign'
                        implementation 'org.springframework.cloud:spring-cloud-starter-config'

                        implementation 'org.springframework.kafka:spring-kafka'

                        implementation 'io.springfox:springfox-boot-starter:3.0.0'

                        implementation 'com.github.ben-manes.caffeine:caffeine'
                    }
                })

        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        runtimeOnly 'org.glassfish.jaxb:jaxb-runtime'

        testImplementation 'org.springframework.boot:spring-boot-starter-test'
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
        }
    }

    test {
        useJUnitPlatform()
    }
}