-
Notifications
You must be signed in to change notification settings - Fork 0
/
alien.inf
10701 lines (9599 loc) · 356 KB
/
alien.inf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!% -~S
!% -G
!% $MAX_STATIC_DATA=20000
!% $MAX_PROP_TABLE_SIZE=63840
!% $MAX_VERBS=200
!% $MAX_ZCODE_SIZE=45000
!% $MAX_VERBSPACE=4500
!
! "A·L·I·E·N" - Edición Especial
!
! Copyright (c) 2008-2018 Ricardo Pérez López (Alpha Aventuras)
!
! This program is free software: you can redistribute it and/or modify
! it under the terms of the GNU General Public License as published by
! the Free Software Foundation, either version 3 of the License, or
! (at your option) any later version.
!
! This program is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
! GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License
! along with this program. If not, see <http://www.gnu.org/licenses/>.
! ====================================================================
!
! CONSTANTES
!
! ====================================================================
Constant Story "~A·L·I·E·N~: La aventura - Edición Especial";
Constant Headline "^(c) 2008-2018 Alpha Aventuras^^
Teclea CRÉDITOS si quieres saber más acerca de la aventura, o
AYUDA cuando estés bloqueado.^";
Release 1;
Serial "180720";
! Queremos usar el comando 'Salidas'
Constant ADMITIR_COMANDO_SALIDAS;
! No queremos usar los comandos 'Lugares' y 'Objetos'
Constant NO_PLACES;
! No queremos usar puntuación
Constant NO_SCORE;
! Queremos que se muestren las deducciones del parser
!Constant IMPRIMIR_DEDUCCIONES;
! Hay curiosidades al final del juego
Constant AMUSING_PROVIDED;
!Constant IMPRIMIR_DESCRIPCION_MAPA;
! Rutas de los móviles:
!Constant RUTA_NINGUNA = 0;
!Constant RUTA_ALEATORIA = 1;
!Constant RUTA_SEGUIR_JUGADOR = 2;
! Máximo nivel de carga para la batería:
Constant MAX_NIVEL_CARGA = 600;
! Alturas de los gráficos:
Constant GRAFICOS_MINUSCULOS = 200;
Constant GRAFICOS_PEQUENOS = 250;
Constant GRAFICOS_MEDIANOS = 350;
Constant GRAFICOS_GRANDES = 500;
! Canales de sonido y sus volúmenes:
Constant CANAL_DETECTOR = 1; Constant VOLUMEN_DETECTOR = 70;
Constant CANAL_TELETIPO = 2; Constant VOLUMEN_TELETIPO = 100;
Constant CANAL_TICTAC = 3; Constant VOLUMEN_TICTAC = 100;
Constant CANAL_SIRENA = 4; Constant VOLUMEN_SIRENA = 20;
! El canal de la música de fondo siempre tiene que ser
! DAMUSIX_NCANALMAX - 1 = 10 - 1 = 9:
Constant CANAL_FONDO = 9; Constant VOLUMEN_FONDO = 50;
! Vamos a usar Damusix junto con SGW+DMX
Constant SGW_CON_DAMUSIX;
Constant SONIDO_BUCLE_INFINITO = -1;
! El color de fondo de la ventana gráfica es negro:
Constant CLR_GG_PERSBACK = CLR_GG_BLACK;
! Es importante que todos los timers tengan duración distinta, porque
! esa es la forma que tengo de distinguirlos (es muy cutre, pero va):
Constant TIMER_TICK = 1000;
! El timer a aplicar para el trueno:
Constant TIMER_DURACION_TRUENO = 3;
! El timer para el laberinto es más largo:
Constant TIMER_DURACION_LABERINTO = 7;
! El timer para cuando el alien está en la misma localidad:
Constant TIMER_DURACION_ALIEN = 6;
! Tiempo de espera desde que sale el rayo hasta que desaparece:
Constant TIMER_DURACION_ESPERA_TRUENO = 1;
! Timer de la autodestruccion:
Constant TIMER_DURACION_AUTODESTRUCCION = 4;
! Timer de la batería de la linterna:
Constant TIMER_DURACION_BATERIA = 5;
! ====================================================================
!
! VARIABLES GLOBALES
!
! ====================================================================
! Alto de la ventana gráfica:
Global altoVentanaGrafica = GRAFICOS_MEDIANOS;
! Hay gráficos o no:
Global hayGraficos = true;
! Hay sonidos:
Global haySonido = true;
Global haySonidoFondo = true;
Global haySonidoDetector = true;
! Hay eventos en tiempo real:
Global hayTiempoReal = true;
! Hay efecto de teletipo:
Global hayTeletipo = true;
! Si se ha activado el listado automático de salidas:
Global mostrarSalidas = true;
! Se pone a true y false en la rutina PermitirEmpujarDir, y luego se consulta en
! MensajesLibreria:
Global estoyEmpujando = false;
! Interruptor de pistas:
Global hayPistas = 0;
! Interruptor para indicar si hay que dibujar o no la línea de estado
! (ver rutina Inicializar):
Global dibujarEstado = false;
! La imagen que representa la oscuridad:
Global SGW_IMAGEN_OSCURIDAD = Oscuridad_jpg;
! ====================================================================
!
! INCLUDES Y REPLACES
!
! ====================================================================
! Nuestra versión de esta rutina sólo redibuja la línea de estado cuando
! la variable global dibujarEstado está a true:
Replace DrawStatusLine;
! En este juego no se usa el BuscarEn (MIRA EN, BUSCA EN/DENTRO/DE/SOBRE, REGISTRA...)
Replace SearchSub;
! En este juego no se usa el Consultar (CONSULTA, LEE, BUSCA EN x SOBRE y...)
Replace ConsultSub;
! En este juego no se habla, ni se responde, ni se dice:
Replace TellSub;
Replace AnswerSub;
Replace DecirSub;
! Con el siguiente Replace conseguimos que el objeto empujado hacia una dirección
! aparezca en la descripción de la localidad de destino del "empuje":
Replace AllowPushDir;
! Ponemos nuestra propia versión de ZIPI_RunMenu y ZIPI_RunOtro,
! para el menú principal y las pistas:
Replace ZIPI_RunMenu;
Replace ZIPI_RunOtro;
! Nuestra versión elimina también los signos de admiración e interrogación:
Replace QuitarAcentos;
Replace EncenderGraficos;
! ====================================================================
Replace KeyDelay;
Include "Parser";
Replace InitGlkWindow;
Replace HandleGlkEvent;
Replace IdentifyGlkObject;
Include "SGW+DMX_NG"; ! Entre EParser y Acciones
Include "alien.bli"; ! Los recursos gráficos de la aventura
[ Amusing;
print "- La aventura está basada en una idea original de Manolo (nuestro grafista).^^";
KeyDelay();
print "- La primera versión de A·L·I·E·N fue desarrollada hace más de quince años.^^";
KeyDelay();
print "- Esa primera versión la escribió Manolo en Spectrum usando el PAWS original^";
print " comprado a AD.^^";
KeyDelay();
print "- Inicialmente, esta aventura iba a ser un remake de ese ~clásico~, pero durante^";
print " el proceso decidimos ampliar bastante más la historia.^^";
KeyDelay();
print "- Hay una segunda parte de la versión original en Spectrum perdida en una casette^";
print " olvidada dentro de alguna caja extraviada en casa de Manolo.^^";
KeyDelay();
print "- El ~laberinto~ inicial estaba formado sólo por cinco localidades, para después^";
print " pasar a tener más de 70, y finalmente acabar teniendo alrededor de 30.^^";
KeyDelay();
print "- Esta Edición Especial es una versión muy, muy mejorada de la versión original^";
print " que se publicó en 2008.^^";
KeyDelay();
print "- La versión original de A·L·I·E·N publicada en 2008 recibió los siguientes^";
print " galardones:^^";
print " * La Comp Más Monstruosa (2008):^";
print " - Premio al relato más espeluznante^^";
print " * Premios Hispanos (2008):^";
print " - Nominada en las siguientes categorías: Mejor aventura, Aventura con^";
print " mejores puzzles, Mejor puzzle (pulsar los dos botones a la vez) y^";
print " Mejor PSI (el Alien y Jason, siendo la única aventura nominada dos^";
print " veces en la misma categoría)^";
print " - Premiada en las siguientes categorías: Interactividad, Jugabilidad,^";
print " Mejores PSIs y Mejor PSI (por Jason)^^";
KeyDelay();
print "- Todos las imágenes del juego son dibujos originales de Manolo, diseñados para^";
print " la ocasión.^^";
KeyDelay();
print "- ¿Has visto ya el documento ~", (s_b) "Holocubo.pdf", "~ usando la contraseña
apropiada?^";
print " Contiene información muy interesante sobre el xenoforme.^^";
KeyDelay();
print "- Si te estás preguntado para qué sirve la palanca... Efectivamente: no sirve^";
print " para nada en absoluto.^^";
];
[ ImprimirPrompt;
print (s_in) "^> ";
];
Object LibraryMessages
with
before [;
Look:
! Copiamos el código de Mensajes.h. Sólo cambiamos el segundo
! EscribirListaDesde, para que cuando se deje en el suelo la
! linterna, no diga: "Puedes ver una linterna (en la que ves una batería)."
switch (lm_n) {
1: print " (sobre ", (the) lm_o, ")";
2: print " (en ", (the) lm_o, ")";
3: print " (como ", (object) lm_o, ")";
4: print "^Sobre ", (the) lm_o;
WriteListFrom(child(lm_o), ENGLISH_BIT + RECURSE_BIT +
PARTINV_BIT + TERSE_BIT + ISARE_BIT + CONCEAL_BIT);
".";
default:
if (lm_o ~= location) {
if (lm_o has supporter)
print "^Sobre ";
else
print "^En ";
print (the) lm_o;
print " puedes ver ";
} else
print "^También puedes ver ";
if (n == 5) print "también "; ! ?????
! Quitamos RECURSIVO_BIT y INFOPARCIAL_BIT:
WriteListFrom(child(lm_o), ENGLISH_BIT + WORKFLAG_BIT +
TERSE_BIT + CONCEAL_BIT);
if (lm_o ~= location) ".";
".";
}
Prompt:
if (location == procesador) {
procesador.comprobar_segunda_parte();
}
ImprimirPrompt();
rtrue;
Go:
switch (lm_n) {
2: if (estoyEmpujando) {
"^No puedes seguir empujando porque no hay salida hacia ",
(the) noun, ".";
} else {
"No puedes ir por ahí, porque no hay salida hacia ",
(the) noun, ".";
}
5: if (estoyEmpujando) {
"^No puedes empujar nada a través ", (del) lm_o, ".";
} else {
"No puedes pasar a través ", (del) lm_o, ".";
}
}
Take:
if (lm_n == 1) {
print "Recoges ";
! Corrige fallo de la librería: no se puede usar lm_o aquí, no sé por qué.
! En su lugar, hay que usar noun.
! Ver INFSP6/Spanish.h línea 3908.
if (noun has moved) {
print (the) noun;
} else {
print (a) noun;
}
".";
}
Drop:
if (lm_n == 4) {
"Dejas ", (the) lm_o, ".";
}
Remove:
if (lm_n == 3) {
if (verb_word == 'quita') {
"Quitas ", (the) lm_o, " ", (del) second, ".";
} else {
"Sacas ", (the) lm_o, " ", (del) second, ".";
}
}
Miscellany:
switch (lm_n) {
4: TextoLlamativo(" ¡Enhorabuena! Has acabado la aventura ");
rtrue;
10: rtrue;
13: ! Reactivamos timer en caso de UNDO:
! ControlTimer.ReactivarTick();
"[Retrocediendo al turno anterior.]";
17: switch (random(4)) {
1: "Está muy oscuro y no puedes ver nada.";
2: "Todo está demasiado oscuro y no aprecias nada con claridad.";
3: "La oscuridad te impide ver dónde te encuentras.";
4: "Te mueves a tientas a través de una oscuridad que te impide
ver nada.";
}
19: "Has tenido días mejores...";
30: switch (random(3)) {
1: "No encuentro eso que dices.";
2: "No veo nada parecido por aquí.";
3: "Parece que no hay nada de eso.";
};
27: "Las palabras se te agolpan en los labios.";
38: switch (random(5)) {
1: "¿Qué quieres decir con eso?";
2: "Lo siento, no te entiendo.";
3: "Intenta ser un poco más preciso.";
4: "No comprendo eso que dices.";
5: "¿Qué intentas decir?";
}
}
];
! ====================================================================
Include "VerbLib";
[ InScope actor;
! Ponemos a Jason al alcance para hablar, ya que tenemos comunicador:
if (scope_reason == TALKING_REASON or EACH_TURN_REASON &&
comunicador in player && comunicador has worn) {
if (jason has absent) {
PlaceInScope(jason_inerte);
} else if (jason notin LugarReal() || location == thedark) {
PlaceInScope(jason);
}
}
! Ya no la ponemos al alcance. En su lugar, decimos que está en todas partes
! (ver su propiedad esta_en). El motivo es que así ya podemos pedirle a
! Madre que abra puertas cuando estemos delante de ellas:
! ! Ponemos a Madre al alcance para hablar y para que se ejecute su
! ! rutina cada_turno:
! if (razon_alcance == RAZON_HABLAR or RAZON_CADA_TURNO &&
! comunicador in jugador && comunicador has puesto) {
! PonerAlAlcance(computadora);
! }
!
! ! Madre está físicamente en nave1 y en nave2. Aquí no preguntamos por
! ! razon_al_alcance, por lo que Madre estará al alcance para cualquier
! ! acción, como si se pusiera 'esta_en nave1, nave2'. Pero no uso la
! ! propiedad esta_en porque entonces se ejecutaría dos veces su rutina
! ! cada_turno:
! if (LugarReal() == nave1 or nave2) {
! PonerAlAlcance(computadora);
! }
! Ponemos la compuerta de la nave al alcance de la computadora, para que pueda abrirla
! aunque no estemos físicamente delante de la puerta:
if (actor == computadora) {
PlaceInScope(nave);
PlaceInScope(puerta_nave);
PlaceInScope(compartimento_trajes);
}
! Así le puedes decir "jason, sigueme" o "jason, quedate" incluso aunque no esté en la
! misma localidad que tú:
if (action_to_be == ##Seguir or ##Quedar or ##Wait && actor == jason) {
PlaceInScope(player);
}
rfalse;
];
Include "Rastros_NG"; ! Mis rastros son: sangre del alien, cable blanco y cable negro
Include "Barra"; ! Para cambiar la barra de estado
Object barra_estado
class objeto_barra_estado
with
modo BE_COMPUESTO,
disposicion
1 1 true BE_LOCALIDAD
29 1 true BE_TEXTO
45 1 true BE_TEXTO
65 1 true BE_TEXTO
68 1 true BE_TURNOS,
texto [ x;
switch (x) {
1: if (linterna has on && bateria in linterna) {
print_ret " | Linterna: ", bateria.nivel_carga(), "%";
}
2: if (alien.comportamiento == 4 && autodestruccion.falta_en_barra > 0) {
print " | Autodestruc: ", autodestruccion.falta_en_barra, " ";
if (autodestruccion hasnt general) {
"min.";
} else {
"seg.";
}
} else if (rifle in player && detector_movimiento has on &&
alien.distancia > 0 && alien.distancia < 6 && alien hasnt absent) {
if (parent(alien) == LugarReal()) {
print_ret " | Detector: 0 m.";
} else {
print " | Detector: ", 10 * alien.distancia, " m. ";
switch (alien.sentido) {
n_obj: "N";
s_obj: "S";
e_obj: "E";
w_obj: "O";
u_obj: "AR";
d_obj: "AB";
}
}
rtrue;
}
3: print " |";
}
],
lineas_inv
BE_INV_TOTAL;
[ DrawStatusLine;
if (dibujarEstado) {
barra_estado.dibujar();
}
];
! Hay que definirla antes de incluir Moviles_NG:
Class Lugar
class LugarConRastro
with
sgw_mus Estancia_ogg,
sgw_vol VOLUMEN_FONDO,
describe [;
PrintOrRun(self, description);
if (mostrarSalidas) {
print "^";
glk_set_style(style_Emphasized);
<Salidas>;
style roman;
rtrue;
} else {
rtrue;
}
],
number,
dibujado false,
before [;
Examine, Touch:
if (noun == d_obj) { ! Examinamos el suelo
if (EsExterior(self)) {
! Si estamos en el exterior...
"Una superficie de polvo y arena en forma de barro que se acumula en las suelas
de tus botas. Además, la lluvia se encharca con relativa frecuencia.";
} else {
"Una superficie metálica y sólida.";
}
} else if (noun == u_obj && self ~= hueco_techo) { ! Examinamos el techo
if (EsExterior(self)) {
! Si estamos en el exterior...
if (tu_traje in self && tu_traje has worn) {
"La intensa lluvia baña tu casco.";
} else {
"La intensa lluvia ciega tus ojos.";
}
} else {
"Tuberías y estructuras metálicas recorren el techo.";
}
}
],
after [;
Go:
! Si no está el alien presente, se resetea su oportunidad a cero y
! su capricho a 50:
if (alien notin LugarReal()) {
if (alien.oportunidad ~= 0) {
alien.oportunidad = 0;
}
if (alien.comportamiento == 1 or 3 && alien.capricho == 0) {
alien.capricho = 50;
}
}
],
each_turn [;
! Así conseguimos que el alien vaya el doble de lento que nosotros cuando nos
! persiga (alternamos persecución con detención). Pero irá igual de rápido cuando
! estemos dentro de la zona de emergencia con la puerta cerrada (para que no deje
! de decir que hay algo intentando abrir la puerta):
if (alien.comportamiento == 3) {
if (alien.tipo_de_movimiento == MOVIMIENTO_PERSEGUIR &&
(puerta_emergencia has open ||
(puerta_emergencia hasnt open &&
(LugarReal() ofclass ZonaEmergencia && parent(alien) ofclass ZonaEmergencia) ||
(~~(LugarReal() ofclass ZonaEmergencia) &&
~~(parent(alien) ofclass ZonaEmergencia))))) {
PNJ_Ruta(alien, MOVIMIENTO_NINGUNO);
} else {
PNJ_Ruta(alien, MOVIMIENTO_PERSEGUIR, player);
}
}
],
has
~light;
Include "Moviles_NG"; ! La librería Moviles retocada por mí
Include "PnjPuertas_NG"; ! La librería PnjPuertas retocada por mí (muy poco)
Include "PNJactor_NG"; ! Librerías que hacen que un PNJ pueda coger y dejar
Include "PNJacciones_NG"; ! objetos como el PJ (poner detrás de Moviles y PnjPuertas)
Include "Etemas"; ! Los temas de conversación
Include "Decorado_NG"; ! Objetos de decorado
Include "ExaminarFalso"; ! Poder examinar objetos sólo con su nombre
Include "Teletipo"; ! Teletipo para sacar mensajes letra a letra
Include "Pistas"; ! Las pistas creadas con ZIPI
Include "Timer"; ! Mi librería de eventos temporizados
Include "IntNombre"; ! Poder usar adjetivos como en InformATE
class EscenarioAbrible
with
when_open [; print (The) self, " está abiert", (o) self, ".^"; rtrue; ],
when_closed [; print (The) self, " está cerrad", (o) self, ".^"; rtrue; ],
! Cuando está abierto, pasa de ser escenario a ser estático. Esto se hace para que
! se muestre cuando está abierto, usando la propiedad si_abierto. En realidad, la
! propiedad si_cerrado no se usa, porque cuando está cerrado es un escenario, y por
! tanto no se describe.
abrir [;
self.sonido_abrir_cerrar();
give self open;
give self ~scenery;
give self static;
],
cerrar [;
self.sonido_abrir_cerrar();
give self ~open;
give self scenery;
give self ~static;
],
sonido_abrir_cerrar [ snd;
if (self notin LugarReal()) rfalse;
snd = 0;
switch (self) {
puerta_nave: snd = Puerta2_ogg;
puerta_procesador: snd = Puerta2_ogg;
puerta_emergencia: snd = Puerta2_ogg;
compartimento_trajes: snd = Puerta1_ogg;
}
if (snd ~= 0) Damusix.TocarV(snd);
],
after [;
Open:
self.abrir();
Close:
self.cerrar();
],
has
scenery openable;
! Un contenedor que, cuando se examina, describe su contenido. Un objeto de esta clase
! debe usar la propiedad descripcion_real en lugar de descripcion:
class Contenedor
with
descripcion_real "",
description [;
print (string) self.descripcion_real, " ";
if (self has open) {
if (children(self) == 0) {
"Está abiert", (o) self, ", pero vací", (o) self, ".";
} else {
print "Está abiert", (o) self, ", y en su interior puedes ver ";
WriteListFrom(child(self), ENGLISH_BIT);
print ".^";
}
} else {
if (self has transparent) {
print "Está cerrad", (o) self, ", pero al ser transparente puedes ver ";
if (children(self) == 0) {
"que está vacío.";
} else {
print "que en su interior hay ";
WriteListFrom(child(self), ENGLISH_BIT);
print ".^";
}
} else {
"Está cerrad", (o) self, ".";
}
}
],
has
container;
! ====================================================================
!
! HABITACIONES
!
! ====================================================================
! El atributo general indica si no es la primera vez que se sale de la nave. Se usa para
! explicar (o no) lo de la zona intermedia de descompresión
Object nave1 "Interior de la nave"
class Lugar
with
description "La nave de exploración Alpha dispone de todo lo necesario para satisfacer
los requisitos más básicos en cuanto a soporte vital y contención. Los
instrumentos brillan y parpadean de forma insana, y frente a ellos se
disponen los dos únicos asientos del vehículo. Sus angostas paredes
aumentan la sensación de claustrofobia y los enormes ventanales ofrecen
una vista desoladora del exterior.",
w_to nave2,
out_to puerta_nave,
sgw_img Nave1_jpg,
sgw_mus Nave_ogg,
Close [;
puerta_nave.cerrar();
HablaMadre("Cerrando compuerta de la nave.");
],
before [ i k t;
Examine:
if (noun == out_obj) {
PrintOrRun(decorado_nave1, desc_ventanales);
rtrue;
}
Sentarse:
"No es necesario sentarse para poder operar con los controles de la nave, ni
para hablar con su computadora.";
! Exit:
! <<Go out_obj>>;
Go:
if (noun == out_obj) {
! Si el procesador atmosférico funciona, no hay que entrar a mirar si llevan trajes
if (procesador.arreglado()) {
! self.mostrar_quien_sale(jason in self &&
! jason.tipo_de_movimiento == MOVIMIENTO_PERSEGUIR &&
! jason.perseguido == jugador);
rfalse;
}
if (puerta_nave hasnt open) {
rfalse;
}
k = 0;
! Comprueba si el jugador lleva puesto el traje. Para ello, recorre todos los
! objetos del jugador en busca de uno que sea de la clase TrajeAtmosferico y
! que además lo lleve puesto encima.
objectloop (i in player) {
if (i ofclass TrajeAtmosferico && i has worn)
k++;
}
if (k == 0) {
HablaMadre("No debería salir sin llevar puesto su traje atmosférico.");
"^Decides seguir sus sabios consejos.";
}
! Comprobar si Jason está aquí, y sigue al jugador, y lleva puesto el traje.
! Si no lo lleva puesto, se lo pone antes de salir.
if (jason in self && jason.tipo_de_movimiento == MOVIMIENTO_PERSEGUIR &&
jason.perseguido == player) {
t = 0;
objectloop (i in jason) {
if (i ofclass TrajeAtmosferico)
t = i;
}
! Si no lleva ningún traje atmosférico, intenta cogerlo:
if (t == 0) {
! PNJ_Ruta(jason, MOVIMIENTO_NINGUNO);
if (traje_jason notin jason) {
if (PuedeVer(jason, traje_jason)) {
HablaJason("De acuerdo, pero antes cogeré el traje atmosférico.");
if (~~(jason.intentar_coger(traje_jason))) {
PNJ_Ruta(jason, MOVIMIENTO_NINGUNO);
! rfalse;
} else {
give traje_jason worn;
move jason to exterior1;
}
print "^";
} else {
HablaJason("No puedo salir de la nave. No llevo puesto mi traje, y
no lo veo por aquí.");
! rfalse;
}
} else {
if (traje_jason hasnt worn) {
give traje_jason worn;
HablaJason("De acuerdo, pero antes me pondré el traje atmosférico.");
print "^";
move jason to exterior1;
}
}
! print "[Jason se queda dentro, al no disponer de protección vital para
! el exterior.]^^";
} else {
! Si lo tiene, sale o se lo pone antes.
if (t hasnt worn) {
give t worn;
! jason.precamino = RUTA_SEGUIR_JUGADOR;
PNJ_Ruta(jason, MOVIMIENTO_PERSEGUIR, player);
print "[Jason se pone el traje antes de salir.]^^";
} else {
print "[Jason sale de la nave con su traje puesto.]^^";
}
move jason to exterior1;
}
self.mostrar_quien_sale(traje_jason in jason && traje_jason has worn); ! t ~= 0
rfalse;
}
self.mostrar_quien_sale(0);
rfalse;
}
],
mostrar_quien_sale [ c;
! El parámetro c indica si el jugador sale solo de la nave, o Jason va con él
! c = true: Salen juntos ; c = false: El jugador sale solo
Damusix.TocarV(Descompresion_ogg, 100);
! Si es la primera vez que se sale:
if (self hasnt general) {
give self general;
if (c) {
! Salen juntos:
print "Ataviados con vuestros trajes atmosféricos, Jason y tú cruzais la
compuerta de la nave y os introducís en un reducido habitáculo destinado
a la descompresión y aislamiento del exterior. Madre cierra la puerta que
acabais de pasar, se observan chorros de aire y vapor saliendo de todas
los rincones del cubículo y, tras varios segundos, la compuerta exterior
se abre, dejando vía libre para que podáis salir de la nave.^";
KeyDelay();
"^Lentamente vais bajando por la rampa de acceso. La lluvia impregna vuestros
trajes, y vuestros pies tocan finalmente el barro de la superficie." ;
} else {
! Sólo sale el jugador:
print "Ataviado con tu traje atmosférico, cruzas la
compuerta de la nave y te introduces en un reducido habitáculo destinado
a la descompresión y aislamiento del exterior. Madre cierra la puerta que
acabas de pasar, se observan chorros de aire y vapor saliendo de todas
los rincones del cubículo y, tras varios segundos, la compuerta exterior
se abre, dejando vía libre para que puedas salir de la nave.^";
KeyDelay();
"^Lentamente vas bajando por la rampa de acceso. La lluvia impregna tu
traje, y tus pies tocan finalmente el barro de la superficie." ;
}
} else {
if (~~(procesador.arreglado())) {
if (c) {
"Jason y tú salís al exterior sin problemas, protegidos por vuestros trajes
atmosféricos.";
} else {
"Sales al exterior sin problemas, protegido por tu traje atmosférico.";
}
}
! print " A continuación, Madre cierra la compuerta de la nave.^";
}
],
after [ jason_viene;
Go:
! Si venimos de fuera:
if (noun == in_obj) {
jason_viene = jason in exterior1 &&
jason.tipo_de_movimiento == MOVIMIENTO_PERSEGUIR &&
jason.perseguido == player;
Damusix.TocarV(Descompresion_ogg);
if (jason_viene) {
print "Entráis ";
} else {
print "Entras ";
}
print "al interior de la nave a través del compartimento de descompresión.^";
puerta_nave.cerrar();
if (jason in self && jason.tipo_de_movimiento ~= MOVIMIENTO_PERSEGUIR) {
PNJ_Ruta(jason, MOVIMIENTO_PERSEGUIR, player);
} else {
if (jason_viene) {
move jason to nave1;
PNJ_Ruta(jason, MOVIMIENTO_PERSEGUIR, player);
}
}
}
],
! Comprueba si se ha llegado al final del juego. Para ello, comprueba que
! Jason está aquí, y que la vaina está abierta. Esto último significará que
! lo hemos sacado de la vaina, y por tanto, si hemos llegado hasta aquí, es
! que hemos acabado la aventura:
each_turn [ t;
if (jason in self && vaina has open) {
Bandera_Fin(2);
t = false;
if (hayGraficos) {
t = true;
ApagarGraficosSub(true);
}
KeyDelay();
clearMainWindow();
tt_final.visualiza();
Damusix.TocarV(Grito_Jason_ogg);
if (t) {
EncenderGraficosSub(true);
viewImageCenter(Logo_Alien_jpg);
}
}
],
has
light;
Object decorado_nave1 nave1
class Decorado
with
desc_instrumentos "Los paneles de instrumentación están llenos de indicadores y
botones por todas partes. En un lateral también se aprecia
un cargador de baterías.",
desc_ventanales "A través de las ventanas que dan al exterior únicamente se
aprecia una densa luz blanco-amarillenta, proveniente de los
focos que iluminan el lugar de aterrizaje con un fulgor
fantasmagórico de un tono uniforme ocasionalmente roto por el
tintinear de la lluvia impactando en el cristal y la cegadora
luminiscencia de los relámpagos.",
desc_asientos "Son unos asientos mullidos y cómodos. Algo que contrasta mucho con
la deshumanización del resto del decorado.",
desc_paredes "En una de las paredes puedes observar un compartimento destinado a
almacenar los trajes atmosféricos.",
before [;
Touch:
switch (self.number) {
'ventanales', 'ventanal',
'cristales', 'cristal',
'ventanas', 'ventana': "Una superficie lisa que, sin embargo, traspasa la
humedad del exterior.";
'paneles', 'panel',
'instrumentos', 'instrumento',
'indicadores', 'indicador': "La mayoría de las funciones de la nave están
gobernadas por Madre, así que lo mejor será
tocar lo menos posible.";
'asientos', 'asiento': "Son mullidos y confortables, pero ahora no es el
momento de sentarse.";
'paredes', 'pared': "Son frías y sólidas al tacto.";
}
],
describe
'paneles' [; return self.desc_instrumentos; ] G_PLURAL
'panel' [; return self.desc_instrumentos; ] 0
'instrumentos' [; return self.desc_instrumentos; ] G_PLURAL
'instrumento' [; return self.desc_instrumentos; ] 0
'indicadores' [; return self.desc_instrumentos; ] G_PLURAL
'indicador' [; return self.desc_instrumentos; ] 0
'botones' [; return self.desc_instrumentos; ] G_PLURAL
'boton' [; return self.desc_instrumentos; ] 0
'ventanales' [; return self.desc_ventanales; ] G_PLURAL
'ventanal' [; return self.desc_ventanales; ] 0
'ventanas' [; return self.desc_ventanales; ] G_FEMENINO + G_PLURAL
'ventana' [; return self.desc_ventanales; ] G_FEMENINO
'cristales' [; return self.desc_ventanales; ] G_PLURAL
'cristal' [; return self.desc_ventanales; ] 0
'lluvia' [; return self.desc_ventanales; ] G_FEMENINO
'asientos' [; return self.desc_asientos; ] G_PLURAL
'asiento' [; return self.desc_asientos; ] 0
'paredes' [; return self.desc_paredes; ] G_FEMENINO + G_PLURAL
'pared' [; return self.desc_paredes; ] G_FEMENINO;
Object nave "nave"
class EscenarioAbrible
with
name_m 'vehiculo',
name_f 'nave' 'alpha',
adjectives 'exploracion',
gender G_FEMENINO,
found_in nave1 nave2 exterior1,
before [;
Open:
<<Open puerta_nave>>;
Close:
<<Close puerta_nave>>;
Examine:
switch (LugarReal()) {
nave1, nave2: PrintOrRun(LugarReal(), description);
exterior1: "Parece más grande por fuera...";
}
rtrue;
];
Object descompresion "cámara de descompresión"
with
name_m 'habitaculo',
name_f 'camara' 'cabina' 'descompresion' 'despresurizacion',
gender G_FEMENINO,
description "Es el recinto intermedio entre la nave y el exterior. Se usa para
acomodar la presión y la atmósfera al salir o entrar en la nave.",
before [;
GoIn, Enter:
<<Exit>>;
],
has
scenery;
Object puerta_nave "compuerta de la nave" nave1
class PNJPuerta
class EscenarioAbrible
with
! La librería PnjPuertas ya incluye la palabra 'puerta' como nombre
name 'compuerta',
adjectives 'nave' 'vehiculo',
description [;
if (self hasnt open) {
print "La puerta está cerrada, impidiendo el acceso al ";
if (LugarReal() == nave1) {
"exterior.";
} else {
"interior.";
}
} else {
print "La puerta está abierta y permite acceder al ";
if (LugarReal() == nave1) {
print "exterior";
} else {
print "interior";
}
" de la nave.";
}
],
pnj_abrir [ act;
if (self hasnt open) {
if (act == jason) {
HablaJason("¡No puedo entrar! ¡La compuerta de la nave está cerrada!");
rfalse;
}
print "^Alguien intenta entrar en la nave, pero la compuerta está cerrada.^";
rfalse;
} else {
return 2;
}
],
out_to exterior1,