-
Notifications
You must be signed in to change notification settings - Fork 0
/
mul256x256_256_64bitlimbs_adc.x86_64.s
199 lines (153 loc) · 3.47 KB
/
mul256x256_256_64bitlimbs_adc.x86_64.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
.globl mul256x256_256
# note: xchg swaps two registers
/*
nameing convention:
riscv64 x86_64 aarch
r0 a0 rdi x0
r1 a1 rsi x1
r2 a2 rdx x2
r3 a3 rcx x3
r4 a4 r8 x4
r5 a5 r9 x5
r6 a6 rax x6
r7 a7 rbx x7
r8 t0 rbp x8
r9 t1 rsp x9
r10 t2 r10 x10
r11 t3 r11 x11
r12 t4 r12 x12
r13 t5 r13 x13
r14 t6 r14 x14
r15 s0 r15 x15
*/
.text
mul256x256_256: # computes mul256x256->256, where pointers: out in rdi, a in rsi, b in rdx
# following C calling conventions, save registers
push %rbx
push %rbp
push %r12
push %r13
push %r14
push %r15
# save the stack pointer
# note: stack pointer may be needed to handle interrupts on some systems
#mov %rsp, stack_pointer_saved_in_data_section
# zero registers which are not args
/*
xor %eax, %eax
xor %ebx, %ebx
*/
xor %ecx, %ecx # zero registers, use 32-bit version since it is recommended
/*
xor %ebp, %ebp
xor %esp, %esp
xor %r8d, %r8d
xor %r9d, %r9d
xor %r10d, %r10d
xor %r11d, %r11d
xor %r12d, %r12d
xor %r13d, %r13d
xor %r14d, %r14d
xor %r15d, %r15d
//*/
# end of setup, now can start arbitrary user code
# fill registers with a and b to free registers rsi and rdx for us to use
mov (%rsi), %r8 # move a to registers r8, r9, r10, r11
mov 8(%rsi), %r9
mov 16(%rsi), %r10
mov 24(%rsi), %r11
mov (%rdx), %r12 # move b to registers r12, r13, r14, r15
mov 8(%rdx), %r13
mov 16(%rdx), %r14
mov 24(%rdx), %r15
# set arg rsi to zero
xor %esi, %esi # zero rsi, use 32-bit version since it is recommended
# done initializing, now let's compute something
# note: will use rcx=low_limb, rdx=high_limb, rsi=carry
# a0*b0 + carry
# a0*b0
mov %r8, %rax
mul %r12
# write result for this limb, prepare for next limb
mov %rax, 0(%rdi) # write result for this 64-bit limb
mov %rdx, %rbx
# a0*b1 + a1*b0 + carry
# a0*b1
mov %r8, %rax
mul %r13
clc
add %rax, %rbx
adc %rdx, %rcx
adc $0, %rsi
# a1*b0
mov %r9, %rax
mul %r12
clc
add %rax, %rbx
adc %rdx, %rcx
adc $0, %rsi
# write result for this limb, prepare for next limb
mov %rbx, 8(%rdi) # write result for this 64-bit limb
mov %rcx, %rbx
mov %rsi, %rcx
xor %esi, %esi # zero rsi, use 32-bit version since it is recommended
# a0*b2 + a1*b1 + a2*b0 + carry
# a0*b2
mov %r8, %rax
mul %r14
clc
add %rax, %rbx
adc %rdx, %rcx
adc $0, %rsi
# a1*b1
mov %r9, %rax
mul %r13
clc
add %rax, %rbx
adc %rdx, %rcx
adc $0, %rsi
# a2*b0
mov %r10, %rax
mul %r12
clc
add %rax, %rbx
adc %rdx, %rcx
adc $0, %rsi
# write result for this limb, prepare for next limb
mov %rbx, 16(%rdi) # write result for this 64-bit limb
mov %rcx, %rbx
mov %rsi, %rcx
xor %esi, %esi # zero rsi, use 32-bit version since it is recommended
# a0*b3 + a1*b2 + a2*b1 + a3*b0 + carry
# a0*b3
movq %r8, %rax
imul %r15,%rax
addq %rax, %rbx
# a1*b2
movq %r9, %rax
imul %r14,%rax
addq %rax, %rbx
# a2*b1
movq %r10, %rax
imul %r13,%rax
addq %rax, %rbx
# a3*b0
movq %r11, %rax
imul %r12,%rax
addq %rax, %rbx
# write result for this limb, prepare for next limb
movq %rbx, 24(%rdi) # write result for this 64-bit limb
# done computing stuff
# recover the stack pointer
#mov stack_pointer_saved_in_data_section, %rsp
# as callee, return saved registers to original
pop %r15
pop %r14
pop %r13
pop %r12
pop %rbp
pop %rbx
# finally, return
ret
.data
stack_pointer_saved_in_data_section: .quad 0