build.gradle

group 'ink.abb'
version '0.5.0'

buildscript {
    ext {
        kotlin_version = '1.0.3'
        springBootVersion = '1.3.6.RELEASE'
        jacksonVersion = '2.8.0'
    }

    repositories {
        mavenCentral()
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion"
    }
}

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'application'
apply plugin: 'spring-boot'

mainClassName = 'ink.abb.pogo.scraper.MainKt'

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
    jcenter()
    maven { url "https://jitpack.io" }
}

def generatedResourcesFolder = "$projectDir/build/resources/main"

sourceSets {
    main {
        kotlin {
            srcDir 'src/main/kotlin'
        }
        java {
            srcDir 'lib/com.google.guava'
        }
        resources.srcDirs generatedResourcesFolder
    }
}

configurations {
    compile.exclude module: "spring-boot-starter-tomcat"
}

dependencies {
    //compile files('../PokeGOAPI-Java/library/build/libs/PokeGOAPI-library-all-0.3.0.jar')
    compile 'com.github.Grover-c13:PokeGOAPI-Java:ef1f52f1f0621f94b97125975c961a8ad8129e92'

    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    compile "com.corundumstudio.socketio:netty-socketio:1.7.7"

    compile 'org.springframework.boot:spring-boot-starter'
    compile 'org.springframework.boot:spring-boot-starter-web'
    compile 'org.springframework.boot:spring-boot-starter-undertow'

    compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: jacksonVersion
    compile group: 'com.fasterxml.jackson.core', name: 'jackson-core', version: jacksonVersion
    compile group: 'com.fasterxml.jackson.core', name: 'jackson-annotations', version: jacksonVersion
    compile group: 'com.fasterxml.jackson.module', name: 'jackson-module-kotlin', version: jacksonVersion

    testCompile group: 'junit', name: 'junit', version: '4.11'
    testCompile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
}

jar {
    manifest {
        attributes(
                'Class-Path': configurations.compile.collect { it.getName() }.join(' '),
                'Main-Class': mainClassName
        )
    }
}

task createProperties(dependsOn: processResources) << {
    String versionDir = "$buildDir/resources/main/ink/abb/pogo/scraper"
    new File(versionDir).mkdirs()
    new File("$versionDir/version.properties").withWriter { w ->
        Properties p = new Properties()
        p['version'] = project.version.toString()
        p.store w, null
    }
}

classes {
    dependsOn createProperties
}