-
Notifications
You must be signed in to change notification settings - Fork 1
/
GateauAddTest.cmake
163 lines (138 loc) · 5.46 KB
/
GateauAddTest.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
# Copyright Pierre-Antoine LACAZE 2018 - 2020.
# Distributed under the Boost Software License, Version 1.0.
# (See accompanying file LICENSE_1_0.txt or copy at
# https://www.boost.org/LICENSE_1_0.txt)
# This module encapsulates add_test in order to ensure proper execution with
# Windows and linux-mingw plateforms
include_guard()
include(GateauHelpers)
include(GateauAddTarget)
# register a test
function(_gateau_register_test target wd)
cmake_parse_arguments(_O "" "" "PROPERTIES;ARGUMENTS" ${ARGN})
add_test(
NAME test_${target}
COMMAND ${target} ${_O_ARGUMENTS}
WORKING_DIRECTORY "${wd}"
)
if (_O_PROPERTIES)
set_tests_properties(test_${target} PROPERTIES ${_O_PROPERTIES})
endif()
endfunction()
# register a google test
function(_gateau_register_gtest_test target wd)
cmake_parse_arguments(_O "NO_MAIN" "" "PROPERTIES;ARGUMENTS" ${ARGN})
if (_O_ARGUMENTS)
set(args EXTRA_ARGS ${_O_ARGUMENTS})
endif()
if (_O_PROPERTIES)
set(props PROPERTIES ${_O_PROPERTIES})
endif()
target_link_libraries(${target} PRIVATE GTest::gtest GTest::gmock)
if (NOT _O_NO_MAIN)
target_link_libraries(${target} PRIVATE GTest::gtest_main)
endif()
include(GoogleTest)
gtest_discover_tests(${target} WORKING_DIRECTORY "${wd}" ${args} ${props})
endfunction()
# register a doctest test
function(_gateau_register_doctest_test target wd)
cmake_parse_arguments(_O "NO_MAIN" "" "PROPERTIES;ARGUMENTS" ${ARGN})
if (_O_ARGUMENTS)
set(args EXTRA_ARGS ${_O_ARGUMENTS})
endif()
if (_O_PROPERTIES)
set(props PROPERTIES ${_O_PROPERTIES})
endif()
target_link_libraries(${target} PRIVATE doctest::doctest)
include(doctest)
doctest_discover_tests(${target} WORKING_DIRECTORY "${wd}" ${args} ${props})
endfunction()
# register a catch test
function(_gateau_register_catch_test target wd)
cmake_parse_arguments(_O "NO_MAIN" "" "PROPERTIES;ARGUMENTS" ${ARGN})
if (_O_ARGUMENTS)
set(args EXTRA_ARGS ${_O_ARGUMENTS})
endif()
if (_O_PROPERTIES)
set(props PROPERTIES ${_O_PROPERTIES})
endif()
target_link_libraries(${target} PRIVATE Catch2::Catch2)
include(Catch)
catch_discover_tests(${target} WORKING_DIRECTORY "${wd}" ${args} ${props})
endfunction()
# register a QtTest test
function(_gateau_register_qttest_test target wd)
target_link_libraries(${target} PRIVATE Qt5::Test)
_gateau_register_test(${target} "${wd}" ${ARGN})
endfunction()
# Setup tests with optional test provider
macro(gateau_setup_testing tests_target)
set(bool_options CATCH DOCTEST GTEST QTTEST)
cmake_parse_arguments(_O "${bool_options}" "" "" ${ARGN})
enable_testing()
add_custom_target(${tests_target}
COMMAND "${CMAKE_CTEST_COMMAND}" --output-on-failure
COMMENT "Build and run all the unit tests."
)
define_property(DIRECTORY PROPERTY gateau_tests_target INHERITED
BRIEF_DOCS "tests target"
FULL_DOCS "name of the main target to run all the tests"
)
define_property(DIRECTORY PROPERTY gateau_tests_provider INHERITED
BRIEF_DOCS "tests provider"
FULL_DOCS "name of the library used to write the tests"
)
set_directory_properties(PROPERTIES gateau_tests_target ${tests_target})
# unit tests are provided by Catch2
if (_O_CATCH)
gateau_find_package(Catch2 BUILD_ONLY_DEP)
set_directory_properties(PROPERTIES gateau_test_provider CATCH)
elseif (_O_DOCTEST)
gateau_find_package(doctest BUILD_ONLY_DEP)
set_directory_properties(PROPERTIES gateau_test_provider DOCTEST)
elseif (_O_GTEST)
gateau_find_package(GTest BUILD_ONLY_DEP)
set_directory_properties(PROPERTIES gateau_test_provider GTEST)
elseif (_O_QTTEST)
gateau_find_package(Qt5 COMPONENTS Test)
set_directory_properties(PROPERTIES gateau_test_provider QTTEST)
else()
set_directory_properties(PROPERTIES gateau_test_provider UNKNOWN)
endif()
gateau_cleanup_parsed(_O "${bool_options}" "" "")
unset(bool_options)
endmacro()
# Add a test, this is the same as calling gateau_add_executable,
# then performs auto-registration of the test
function(gateau_add_test name)
cmake_parse_arguments(_O "NO_MAIN" "WORKING_DIRECTORY" "TEST_PROPERTIES;ARGUMENTS" ${ARGN})
gateau_add_executable(${name} ${_O_UNPARSED_ARGUMENTS} NO_INSTALL)
get_directory_property(tests_target gateau_tests_target)
add_dependencies(${tests_target} ${name})
if (NOT _O_WORKING_DIRECTORY)
set(_O_WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}")
endif()
set(args)
if (_O_NO_MAIN)
list(APPEND args NO_MAIN)
endif()
if (_O_ARGUMENTS)
list(APPEND args ARGUMENTS ${_O_ARGUMENTS})
endif()
if (_O_TEST_PROPERTIES)
list(APPEND args PROPERTIES ${_O_TEST_PROPERTIES})
endif()
get_directory_property(provider gateau_test_provider)
if (provider STREQUAL CATCH)
_gateau_register_catch_test(${name} "${_O_WORKING_DIRECTORY}" ${args})
elseif(provider STREQUAL DOCTEST)
_gateau_register_doctest_test(${name} "${_O_WORKING_DIRECTORY}" ${args})
elseif(provider STREQUAL GTEST)
_gateau_register_gtest_test(${name} "${_O_WORKING_DIRECTORY}" ${args})
elseif(provider STREQUAL QTTEST)
_gateau_register_qttest_test(${name} "${_O_WORKING_DIRECTORY}" ${args})
else()
_gateau_register_test(${name} "${_O_WORKING_DIRECTORY}" ${args})
endif()
endfunction()