Signature Request & JSON Format for Records

[0xc0de4c0ffee]

signed <record>.json format
a) 4+n..
"data": "0x+ <_abi.encodePacked(bytes4 __callback.selector, abi.encode(abi.encode(bytes _result), bytes signature, address signer))>"
b) 4+20+ ?8=uint64 _validity? all packed in bytes32;
"data": "0x+ <_abi.encodePacked(bytes4 __callback.selector, address signer, uint64 _validity, abi.encode(abi.encode(bytes _result), bytes signature))>"

Format/template for signature request on wallet side with crazy EIP151 validation in solidity. * not tested outside of head :p

        (result, signature, _signer) = abi.decode(response[4:], (bytes, bytes, address));
            string memory _req = string.concat(
                "Requesting signature for ENS off-chain record\n\nDomain: ",
                _domain,
                "\nRecord: ",
                _jsonPath, // short file path e.g, "_address/60:0x<abi.encode(_address)>"
                ":0x",
                bytesToString(result, 0), // long abi encoded result
                "\nSIGNED BY: eip155:1:",
                toChecksumAddress(_signer) // checksum address
            );

I'll update this in namesys-eth/ccip2-eth-resolver#3 , peek in for review to make proper sig/req formats.

Full __callback function for context;

    function __callback(bytes calldata response, bytes calldata extradata)
        external
        view
        returns (bytes memory result)
    {
        (
            uint256 _blocknumber, // block number used for extra check 
            bytes32 _node, // base domain namehash
            bytes32 _namehash, // base/sub domain namehash
            string memory _domain, // full domain.eth string
            string memory _jsonPath, // short path before .json 
            bytes32 _checkHash // timeout check
        ) = abi.decode(extradata, (uint256, bytes32, bytes32, string, string, bytes32));

        /// @dev: timeout in 3 blocks
        require(
            block.number <= _blocknumber + 3
                && _checkHash == keccak256(abi.encodePacked(THIS, blockhash(_blocknumber), msg.sender, _domain)),
            "INVALID_CHECKSUM/TIMEOUT"
        );
        if (bytes4(response[:4]) == iCCIP.__callback.selector) {
            // signed result in callback
            /// @dev ethers.js/CCIP reverts if the <result> is not ABI-encoded
            address _signer;
            bytes memory signature;
            (result, signature, _signer) = abi.decode(response[4:], (bytes, bytes, address));
            string memory _req = string.concat(
                "Requesting signature for ENS off-chain record\n\nDomain: ",
                _domain,
                "\nRecord: ",
                _jsonPath, // short file path e.g, "_address/60:0x<abi.encode(_address)>"
                ":0x",
                bytesToString(result, 0), // long abi encoded result
                "\nSIGNED BY: eip155:1:",
                toChecksumAddress(_signer) // checksum address
            );
            bytes32 _digest =
                keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", uintToString(bytes(_req).length), _req));
            if (_signer != iCCIP(THIS).signedBy(_digest, signature)) {
                revert InvalidSignature("BAD_SIGNER");
            }
            address _owner = ENS.owner(_node);
            if (_owner == address(WRAPPER)) {
                _owner = WRAPPER.ownerOf(uint256(_node));
            }
            address _sub = manager[keccak256(abi.encodePacked("manage-sub", _node, _owner, _signer))];
            if (_sub != address(0)) {
                // check if contract/ interface?
                _owner = iToken(_sub).ownerOf(uint256(_namehash));
            }
            require(
                _signer == manager[keccak256(abi.encodePacked("manage-one", _node, _owner, _signer))]
                    || _signer == manager[keccak256(abi.encodePacked("manage-all", _owner, _signer))] || _signer == _owner,
                "ONLY_OWNER/MANAGER_CAN_SIGN"
            );
        } else {
            result = response; // must be pre abi-encoded in json's data:..
        }
    }