command-update.coffee

_           = require 'lodash'
fs          = require 'fs'
path        = require 'path'
colors      = require 'colors'
commander   = require 'commander'
BaseCommand = require './base-command'

class UpdateCommand extends BaseCommand
  parseUpdate: (filename) =>
    try
      JSON.parse fs.readFileSync path.resolve(filename)
    catch error
      console.error colors.yellow error.message
      console.error colors.red '\n  Unable to open a valid updated-device.json file'
      commander.outputHelp()
      process.exit 1

  parseOptions: =>
    commander
      .option '-u, --uuid <uuid>',                        'uuid to update (defaults to meshblu.json)'
      .option '-p, --put',                                'Use PUT to send the whole device state. Enables $set, $inc, etc. operators'
      .option '-d, --data <\'{"name":"Some Device"}\'>',  'Device Data [JSON]'
      .option '-f, --file <path/to/updated-device.json>', 'Device Data [JSON FILE]'
      .usage '[options] <path/to/meshblu.json>'
      .parse process.argv

    @filename = _.first commander.args
    @data = commander.data
    @uuid = commander.uuid
    @updateFileName = commander.file

    @usePut = commander.put
    @data = @parseUpdate(@updateFileName) if @updateFileName?

    return if _.isPlainObject @data
    try
      @data = JSON.parse @data
    catch e
      commander.outputHelp()
      @die 'You must specify valid update json.'

  run: =>
    @parseOptions()
    meshbluHttp  = @getMeshbluHttp()
    @uuid        ?= @config.uuid
    updateMethod = 'update'
    updateMethod = 'updateDangerously' if @usePut

    meshbluHttp[updateMethod] @uuid, @data, (error, data) =>
      return @die error if error?
      process.exit 0

(new UpdateCommand()).run()