changelog: infer date from slug if not in metadata

The date is present in 2 places: in the slug and in the yaml metadata.
This is redundant and creates extra work for contributors.
This makes the yaml metadata optional; in that case the date is inferred
from the slug.

Author: emillon

tool/ood-gen/lib/changelog.ml

@@ -1,6 +1,6 @@
 type metadata = {
   title : string;
-  date : string;
+  date : string option;
   tags : string list;
   authors : string list option;
   description : string option;
@@ -20,9 +20,23 @@ type t = {
 [@@deriving
   stable_record ~version:metadata
     ~add:[ authors; changelog; description ]
-    ~remove:[ slug; changelog_html; body_html; body ],
+    ~remove:[ slug; changelog_html; body_html; body ]
+    ~modify:[ date ],
     show { with_path = false }]
 
+let re_date_slug =
+  let open Re in
+  compile
+    (seq
+       [
+         bos;
+         group (seq [ rep1 digit; char '-'; rep1 digit; char '-'; rep1 digit ]);
+         char '-';
+       ])
+
+let parse_date_from_slug s =
+  Option.map (fun g -> Re.Group.get g 1) (Re.exec_opt re_date_slug s)
+
 let decode (fname, (head, body)) =
   let slug = Filename.basename (Filename.remove_extension fname) in
   let metadata =
@@ -45,7 +59,17 @@ let decode (fname, (head, body)) =
               |> Hilite.Md.transform
               |> Cmarkit_html.of_doc ~safe:false)
       in
-      of_metadata ~slug ~changelog_html ~body ~body_html metadata)
+      let modify_date = function
+        | Some x -> x
+        | None -> (
+            match parse_date_from_slug slug with
+            | Some x -> x
+            | None ->
+                failwith
+                  "date is not present in metadata and could not be parsed \
+                   from slug")
+      in
+      of_metadata ~slug ~changelog_html ~body ~body_html ~modify_date metadata)
     metadata
 
 let all () =

tool/ood-gen/lib/dune

@@ -16,7 +16,8 @@
   lambdasoup
   fpath
   ppx_stable
-  hilite)
+  hilite
+  re)
  (preprocess
   (pps ppx_deriving_yaml ppx_stable ppx_show)))
 

tool/ood-gen/test/dune

@@ -0,0 +1,3 @@
+(test
+  (name test_ood_gen)
+  (libraries alcotest ood_gen))

tool/ood-gen/test/test_ood_gen.ml

@@ -0,0 +1,15 @@
+let test_parse_date_from_slug =
+  let test ~name ~expected s =
+    ( name,
+      `Quick,
+      fun () ->
+        let got = Ood_gen.Changelog.parse_date_from_slug s in
+        Alcotest.check (Alcotest.option Alcotest.string) __LOC__ expected got )
+  in
+  [
+    test ~name:"ok" "2020-03-02-something.md" ~expected:(Some "2020-03-02");
+    test ~name:"no date" "something.md" ~expected:None;
+  ]
+
+let tests = [ ("parse_date_from_slug", test_parse_date_from_slug) ]
+let () = Alcotest.run __FILE__ tests