feature(cram): allow overriding default alias

Introduce a [(default_aliases ..)] that allows to set the default alias
for a cram test.

Unlike, the existing [alias] field, we're only allowed to set the
default once. If the default isn't set, it's just [runtest].

Signed-off-by: Rudi Grinberg <[email protected]>

<!-- ps-id: 23568b34-517f-464d-93e2-ac2c0f05f885 -->

Author: rgrinberg

doc/changes/8887.md

@@ -0,0 +1,2 @@
+- Introduce the `default_aliases` to the `cram` stanza. This allows overriding
+  the `runtest` default we currently have. (@rgrinberg, #8887)

src/dune_rules/cram/cram_rules.ml

@@ -14,7 +14,7 @@ module Spec = struct
 
   let empty =
     { loc = Loc.none
-    ; alias = Alias.Name.Set.singleton Alias0.runtest
+    ; alias = Alias.Name.Set.empty
     ; enabled_if = [ Blang.true_ ]
     ; locks = Path.Set.empty
     ; deps = []
@@ -149,51 +149,96 @@ let rules ~sctx ~expander ~dir tests =
         | Error (Source_tree.Dir.Missing_run_t test) -> Cram_test.name test
       in
       let init =
-        let alias = Alias.Name.of_string name |> Alias.Name.Set.add Spec.empty.alias in
-        { Spec.empty with alias }
+        ( None
+        , let alias = Alias.Name.of_string name |> Alias.Name.Set.add Spec.empty.alias in
+          { Spec.empty with alias } )
       in
-      Memo.List.fold_left
-        stanzas
-        ~init
-        ~f:(fun (acc : Spec.t) (dir, (stanza : Cram_stanza.t)) ->
-          match
-            match stanza.applies_to with
-            | Whole_subtree -> true
-            | Files_matching_in_this_dir pred ->
-              Predicate_lang.Glob.test pred ~standard:Predicate_lang.true_ name
-          with
-          | false -> Memo.return acc
-          | true ->
-            let+ deps, sandbox =
-              match stanza.deps with
-              | None -> Memo.return (acc.deps, acc.sandbox)
-              | Some deps ->
-                let+ (deps : unit Action_builder.t), _, sandbox =
-                  let+ expander = Super_context.expander sctx ~dir in
-                  Dep_conf_eval.named ~expander deps
-                in
-                deps :: acc.deps, Sandbox_config.inter acc.sandbox sandbox
-            and+ locks =
-              (* Locks must be relative to the cram stanza directory and not
-                 the individual tests directories *)
-              let base = `This (Path.build dir) in
-              Expander.expand_locks ~base expander stanza.locks
-              >>| Path.Set.of_list
-              >>| Path.Set.union acc.locks
-            in
-            let enabled_if = stanza.enabled_if :: acc.enabled_if in
-            let alias =
-              match stanza.alias with
-              | None -> acc.alias
-              | Some a -> Alias.Name.Set.add acc.alias a
-            in
-            let packages =
-              match stanza.package with
-              | None -> acc.packages
-              | Some (p : Package.t) ->
-                Package.Name.Set.add acc.packages (Package.Id.name p.id)
-            in
-            { acc with enabled_if; locks; deps; alias; packages; sandbox })
+      let+ default_aliases, acc =
+        Memo.List.fold_left
+          stanzas
+          ~init
+          ~f:(fun (default_aliases, (acc : Spec.t)) (dir, (stanza : Cram_stanza.t)) ->
+            match
+              match stanza.applies_to with
+              | Whole_subtree -> true
+              | Files_matching_in_this_dir pred ->
+                Predicate_lang.Glob.test pred ~standard:Predicate_lang.true_ name
+            with
+            | false -> Memo.return (default_aliases, acc)
+            | true ->
+              let+ deps, sandbox =
+                match stanza.deps with
+                | None -> Memo.return (acc.deps, acc.sandbox)
+                | Some deps ->
+                  let+ (deps : unit Action_builder.t), _, sandbox =
+                    let+ expander = Super_context.expander sctx ~dir in
+                    Dep_conf_eval.named ~expander deps
+                  in
+                  deps :: acc.deps, Sandbox_config.inter acc.sandbox sandbox
+              and+ locks =
+                (* Locks must be relative to the cram stanza directory and not
+                   the individual tests directories *)
+                let base = `This (Path.build dir) in
+                Expander.expand_locks ~base expander stanza.locks
+                >>| Path.Set.of_list
+                >>| Path.Set.union acc.locks
+              in
+              let default_aliases =
+                match stanza.default_aliases with
+                | None -> default_aliases
+                | Some (loc, names) ->
+                  (match default_aliases with
+                   | None -> Some (loc, names)
+                   | Some (loc', _) ->
+                     let main_message =
+                       Pp.concat
+                         ~sep:Pp.newline
+                         [ Pp.text
+                             "the default alias for a cram test may only be set once."
+                         ; Pp.textf "It's already set for the test %S" name
+                         ]
+                     in
+                     let annots =
+                       let main = User_message.make ~loc:loc' [ main_message ] in
+                       let related =
+                         [ User_message.make ~loc [ Pp.text "Already defined here" ] ]
+                       in
+                       User_message.Annots.singleton
+                         Compound_user_error.annot
+                         [ Compound_user_error.make ~main ~related ]
+                     in
+                     User_error.raise
+                       ~annots
+                       ~loc
+                       [ main_message
+                       ; Pp.text "The first definition is at:"
+                       ; Pp.text (Loc.to_file_colon_line loc')
+                       ])
+              in
+              let enabled_if = stanza.enabled_if :: acc.enabled_if in
+              let alias =
+                match stanza.alias with
+                | None -> acc.alias
+                | Some a -> Alias.Name.Set.add acc.alias a
+              in
+              let packages =
+                match stanza.package with
+                | None -> acc.packages
+                | Some (p : Package.t) ->
+                  Package.Name.Set.add acc.packages (Package.Id.name p.id)
+              in
+              ( default_aliases
+              , { acc with enabled_if; locks; deps; alias; packages; sandbox } ))
+      in
+      let alias =
+        let to_add =
+          match default_aliases with
+          | None -> Alias.Name.Set.singleton Alias0.runtest
+          | Some (_loc, aliases) -> Alias.Name.Set.of_list aliases
+        in
+        Alias.Name.Set.union to_add acc.alias
+      in
+      { acc with alias }
     in
     with_package_mask spec.packages (fun () -> test_rule ~sctx ~expander ~dir spec test))
 ;;

src/dune_rules/cram/cram_stanza.ml

@@ -28,6 +28,7 @@ type t =
   ; enabled_if : Blang.t
   ; locks : Locks.t
   ; package : Package.t option
+  ; default_aliases : (Loc.t * Alias.Name.t list) option
   }
 
 type Stanza.t += T of t
@@ -42,6 +43,11 @@ let decode =
      and+ locks = Locks.field ~check:(Dune_lang.Syntax.since Stanza.syntax (2, 9)) ()
      and+ package =
        Stanza_common.Pkg.field_opt ~check:(Dune_lang.Syntax.since Stanza.syntax (2, 8)) ()
+     and+ default_aliases =
+       field_o
+         "default_aliases"
+         (Dune_lang.Syntax.since Stanza.syntax (3, 11)
+          >>> located (repeat Dune_lang.Alias.decode))
      in
-     { loc; alias; deps; enabled_if; locks; applies_to; package })
+     { loc; alias; deps; enabled_if; locks; applies_to; package; default_aliases })
 ;;

src/dune_rules/cram/cram_stanza.mli

@@ -12,6 +12,7 @@ type t =
   ; enabled_if : Blang.t
   ; locks : Locks.t
   ; package : Package.t option
+  ; default_aliases : (Loc.t * Alias.Name.t list) option
   }
 
 type Stanza.t += T of t

test/blackbox-tests/test-cases/cram/default-aliases.t

@@ -0,0 +1,48 @@
+Set the default aliases for cram test. This allows us to define tests without
+attaching them to the runtest alias.
+
+  $ cat >dune-project <<EOF
+  > (lang dune 3.11)
+  > EOF
+
+  $ cat >dune <<EOF
+  > (cram
+  >  (default_aliases blah)
+  >  (alias this))
+  > EOF
+
+  $ cat >foo.t <<EOF
+  >   $ echo foo
+  > EOF
+
+This shouldn't run the test
+
+  $ dune runtest
+
+This should run the test
+
+  $ dune build @this
+  File "foo.t", line 1, characters 0-0:
+  Error: Files _build/default/foo.t and _build/default/foo.t.corrected differ.
+  [1]
+  $ dune build @blah
+  File "foo.t", line 1, characters 0-0:
+  Error: Files _build/default/foo.t and _build/default/foo.t.corrected differ.
+  [1]
+
+Now we try setting the defualt aliases twice. This should be impossible:
+
+  $ cat >dune <<EOF
+  > (cram (default_aliases a))
+  > (cram (default_aliases b))
+  > EOF
+
+  $ dune build @a
+  File "dune", line 2, characters 23-24:
+  2 | (cram (default_aliases b))
+                             ^
+  Error: the default alias for a cram test may only be set once.
+  It's already set for the test "foo"
+  The first definition is at:
+  dune:1
+  [1]