[new package] wasmer 4.3.5

Author: ognevny

mingw-w64-wasmer/PKGBUILD

@@ -0,0 +1,69 @@
+# Maintainer: Maksim Bondarenkov <[email protected]>
+
+_realname=wasmer
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=4.3.5
+pkgrel=1
+pkgdesc="Universal Binaries Powered by WebAssembly (mingw-w64)"
+arch=('any')
+mingw_arch=('ucrt64' 'clang64')
+url="https://github.com/wasmerio/wasmer"
+license=('spdx:MIT')
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs"
+         "${MINGW_PACKAGE_PREFIX}-sqlite3")
+makedepends=("${MINGW_PACKAGE_PREFIX}-rust"
+             "${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-pkgconf"
+             "${MINGW_PACKAGE_PREFIX}-openssl"
+             'git')
+source=("git+${url}.git#tag=v${pkgver}"
+        "tun-tap.tar.gz::https://crates.io/api/v1/crates/tun-tap/0.1.4/download"
+        "tun-tap-update-tokio.patch"
+        "mingw-build.patch"
+        "reproducible-builds.patch")
+sha256sums=('9d82eba29ea066ba762d0994b3986dcb1cf99deaefe851ccd33a12bb1a2dab37'
+            '9a477a4e9367c72ac875d23cd07ac99ffa932497d8428767fed0cfa27bbabe50'
+            '5ed51ede5cd2831399c8afced87cfe7b28bf51fa952909bd00d32f83166002da'
+            '39e6ab2fc90b9bb7c664c40291b8d6b68d7d7e99026b2d97f4856decc2d28c79'
+            '7f08b41e0077a23b16eb2e9410ac953b293d1eeeaf1b83915a596ac437f81125')
+
+prepare() {
+  cd "${_realname}"
+  rm -f rust-toolchain
+
+  patch -Np1 -i "${srcdir}/reproducible-builds.patch"
+  patch -Np1 -i "${srcdir}/mingw-build.patch"
+  # update tokio in tun-tap dependency so outdated [email protected], kerenel32-sys and ws2_32-sys are dropped
+  rm ../tun-tap-0.1.4/Cargo.lock && mv -f ../tun-tap-0.1.4/Cargo.toml.orig ../tun-tap-0.1.4/Cargo.toml
+  patch -d ../tun-tap-0.1.4 -Np1 -i "${srcdir}/tun-tap-update-tokio.patch"
+  sed -i 's|^tun-tap = { version = "0.1.3"|tun-tap = { version = "0.1.4"|' lib/cli/Cargo.toml
+  cat >> Cargo.toml <<END
+
+[patch.crates-io]
+tun-tap = { path = "../tun-tap-0.1.4" }
+END
+
+  cargo update -p tun-tap
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "${_realname}"
+
+  export WINAPI_NO_BUNDLED_LIBRARIES=1
+  export LIBSQLITE3_SYS_USE_PKG_CONFIG=1
+  make ENABLE_SINGLEPASS=1 ENABLE_CRANELIFT=0 WASMER_INSTALL_PREFIX=${MINGW_PREFIX}
+}
+
+# tests require rustup binary
+# check() {
+#   cd "${_realame}"
+#   make test-examples
+# }
+
+package() {
+  cd "${_realname}"
+
+  make DESTDIR="${pkgdir}${MINGW_PREFIX}" install
+}

mingw-w64-wasmer/mingw-build.patch

@@ -0,0 +1,74 @@
+diff --git a/Makefile b/Makefile
+index 97dc61d550..d85714db57 100644
+--- a/Makefile
++++ b/Makefile
+@@ -44,52 +44,11 @@ SHELL=/usr/bin/env bash
+ IS_DARWIN := 0
+ IS_LINUX := 0
+ IS_FREEBSD := 0
+-IS_WINDOWS := 0
+-IS_AMD64 := 0
++IS_WINDOWS := 1
++IS_AMD64 := 1
+ IS_AARCH64 := 0
+ IS_RISCV64 := 0
+ 
+-# Test Windows apart because it doesn't support `uname -s`.
+-ifeq ($(OS), Windows_NT)
+-	# We can assume it will likely be in amd64.
+-	IS_AMD64 := 1
+-	IS_WINDOWS := 1
+-else
+-	# Platform
+-	uname := $(shell uname -s)
+-
+-	ifeq ($(uname), Darwin)
+-		IS_DARWIN := 1
+-	else ifeq ($(uname), Linux)
+-		IS_LINUX := 1
+-	else ifeq ($(uname), FreeBSD)
+-		IS_FREEBSD := 1
+-	else
+-		# We use spaces instead of tabs to indent `$(error)`
+-		# otherwise it's considered as a command outside a
+-		# target and it will fail.
+-                $(error Unrecognized platform, expect `Darwin`, `Linux` or `Windows_NT`)
+-	endif
+-
+-	# Architecture
+-	uname := $(shell uname -m)
+-
+-	ifneq (, $(filter $(uname), x86_64 amd64))
+-		IS_AMD64 := 1
+-	else ifneq (, $(filter $(uname), aarch64 arm64))
+-		IS_AARCH64 := 1
+-	else ifneq (, $(filter $(uname), riscv64))
+-		IS_RISCV64 := 1
+-	else
+-		# We use spaces instead of tabs to indent `$(error)`
+-		# otherwise it's considered as a command outside a
+-		# target and it will fail.
+-                $(error Unrecognized architecture, expect `x86_64`, `aarch64`, `arm64`, 'riscv64')
+-	endif
+-
+-	# Libc
+-	LIBC ?= $(shell ldd 2>&1 | grep -o musl | head -n1)
+-endif
+ 
+ 
+ #####
+@@ -887,13 +846,7 @@ install-capi-headers:
+ 
+ # Currently implemented for linux only. TODO
+ install-capi-lib:
+-	pkgver=$$($(CARGO_BINARY) pkgid --manifest-path lib/c-api/Cargo.toml | sed 's/^.*wasmer-c-api@//') && \
+-	shortver="$${pkgver%.*}" && \
+-	majorver="$${shortver%.*}" && \
+-	install -Dm755 target/release/libwasmer.so "$(DESTDIR)/lib/libwasmer.so.$$pkgver" && \
+-	ln -sf "libwasmer.so.$$pkgver" "$(DESTDIR)/lib/libwasmer.so.$$shortver" && \
+-	ln -sf "libwasmer.so.$$pkgver" "$(DESTDIR)/lib/libwasmer.so.$$majorver" && \
+-	ln -sf "libwasmer.so.$$pkgver" "$(DESTDIR)/lib/libwasmer.so"
++	install -Dm755 target/release/libwasmer.dll "$(DESTDIR)/bin/libwasmer.dll
+ 
+ install-misc:
+ 	install -Dm644 LICENSE "$(DESTDIR)"/share/licenses/wasmer/LICENSE

mingw-w64-wasmer/reproducible-builds.patch

@@ -0,0 +1,11 @@
+--- a/lib/cli/build.rs
++++ b/lib/cli/build.rs
+@@ -21,7 +21,7 @@ pub fn main() {
+         println!("cargo:rustc-env=WASMER_BUILD_GIT_HASH_SHORT=???????");
+     }
+
+-    let utc: DateTime<Utc> = Utc::now();
++    let utc: DateTime<Utc> = DateTime::from_timestamp(0, 0).unwrap();
+     let date = utc.format("%Y-%m-%d").to_string();
+     println!("cargo:rustc-env=WASMER_BUILD_DATE={}", date);
+ }